[meta-raspberrypi][PATCH 3/3] u-boot: add v2015.10 for Raspberry Pi 2 support

[Jonathan Liu <net147@gmail.com>]

Signed-off-by: Jonathan Liu <net147@gmail.com>
---
 conf/machine/include/rpi-default-providers.inc |  3 ++-
 recipes-bsp/u-boot/files/boot.cmd              |  3 +++
 recipes-bsp/u-boot/u-boot_2015.10.bb           | 28 ++++++++++++++++++++++++++
 3 files changed, 33 insertions(+), 1 deletion(-)
 create mode 100644 recipes-bsp/u-boot/files/boot.cmd
 create mode 100644 recipes-bsp/u-boot/u-boot_2015.10.bb

diff --git a/conf/machine/include/rpi-default-providers.inc b/conf/machine/include/rpi-default-providers.inc
index cabbd43..7d433a0 100644
--- a/conf/machine/include/rpi-default-providers.inc
+++ b/conf/machine/include/rpi-default-providers.inc
@@ -1,7 +1,8 @@
 # RaspberryPi BSP default providers
 
 PREFERRED_PROVIDER_virtual/kernel ?= "linux-raspberrypi"
-PREFERRED_PROVIDER_u-boot ?= "u-boot-rpi"
+PREFERRED_PROVIDER_u-boot_raspberrypi ?= "u-boot-rpi"
+PREFERRED_PROVIDER_u-boot_raspberrypi2 ?= "u-boot"
 PREFERRED_PROVIDER_virtual/xserver ?= "xserver-xorg"
 PREFERRED_PROVIDER_virtual/egl ?= "userland"
 PREFERRED_PROVIDER_virtual/libgles2 ?= "userland"
diff --git a/recipes-bsp/u-boot/files/boot.cmd b/recipes-bsp/u-boot/files/boot.cmd
new file mode 100644
index 0000000..3f7e3b6
--- /dev/null
+++ b/recipes-bsp/u-boot/files/boot.cmd
@@ -0,0 +1,3 @@
+fdt addr ${fdt_addr_r} && fdt get value bootargs /chosen bootargs
+fatload mmc 0:1 ${kernel_addr_r} uImage
+bootm ${kernel_addr_r} - ${fdt_addr_r}
diff --git a/recipes-bsp/u-boot/u-boot_2015.10.bb b/recipes-bsp/u-boot/u-boot_2015.10.bb
new file mode 100644
index 0000000..02fb39a
--- /dev/null
+++ b/recipes-bsp/u-boot/u-boot_2015.10.bb
@@ -0,0 +1,28 @@
+require recipes-bsp/u-boot/u-boot.inc
+
+DEPENDS += "dtc-native rpi-mkimage-native"
+
+SRC_URI += "file://boot.cmd"
+
+# This revision corresponds to the tag "v2015.10"
+# We use the revision in order to avoid having to fetch it from the
+# repo during parse
+SRCREV = "5ec0003b19cbdf06ccd6941237cbc0d1c3468e2d"
+
+PV = "v2015.10+git${SRCPV}"
+
+COMPATIBLE_MACHINE = "raspberrypi2"
+
+do_compile_append() {
+    ${S}/tools/mkimage -A arm -O linux -T script -C none -n boot.scr -d ${WORKDIR}/boot.cmd ${WORKDIR}/${UBOOT_ENV_BINARY}
+}
+
+do_deploy_append() {
+    # Add RPi bootloader trailer to U-Boot image to enable Device Tree support
+    ${STAGING_DIR_NATIVE}/usr/lib/rpi-mkimage/mkknlimg --dtok ${DEPLOYDIR}/${UBOOT_IMAGE} ${DEPLOYDIR}/${UBOOT_IMAGE}
+}
+
+UBOOT_ENV = "boot"
+UBOOT_ENV_SUFFIX = "scr"
+UBOOT_IMAGE = "u-boot.img"
+UBOOT_MACHINE_raspberrypi2 = "rpi_2_defconfig"
-- 
2.6.1