[PATCH 2/2] useradd.bbclass: remove user/group created by the package in cleanall task

["Maxin B. John" <maxin.john@intel.com>]

At present, if a recipe is built which creates users/groups via useradd.bbclass,
those users/groups are not removed (at least from sysroot) when the
recipe/package is cleaned using cleansstate/cleanall.

This "userdel_sysroot_sstate()" provides that functionality. Please note
that this function does not affect the users/groups created in the final
root filesystem.

[YOCTO #9262]

Signed-off-by: Maxin B. John <maxin.john@intel.com>
---
 meta/classes/useradd.bbclass | 27 +++++++++++++++++++++++++++
 1 file changed, 27 insertions(+)

diff --git a/meta/classes/useradd.bbclass b/meta/classes/useradd.bbclass
index 0a6f2be..a8e4a50 100644
--- a/meta/classes/useradd.bbclass
+++ b/meta/classes/useradd.bbclass
@@ -127,6 +127,33 @@ useradd_sysroot_sstate () {
 	fi
 }
 
+userdel_sysroot_sstate () {
+if test "x${STAGING_DIR_TARGET}" != "x"; then
+    export PSEUDO="${FAKEROOTENV} PSEUDO_LOCALSTATEDIR=${STAGING_DIR_TARGET}${localstatedir}/pseudo ${STAGING_DIR_NATIVE}${bindir}/pseudo"
+    OPT="--root ${STAGING_DIR_TARGET}"
+
+    # Remove groups and users defined for package
+    GROUPADD_PARAM="${@get_all_cmd_params(d, 'groupadd')}"
+    USERADD_PARAM="${@get_all_cmd_params(d, 'useradd')}"
+
+    if test "x`echo $USERADD_PARAM | tr -d '[:space:]'`" != "x"; then
+        user=`echo "$USERADD_PARAM" | cut -d ';' -f 1 | awk '{ print $NF }'`
+        perform_userdel "${STAGING_DIR_TARGET}" "$OPT $user"
+    fi
+
+    if test "x`echo $GROUPADD_PARAM | tr -d '[:space:]'`" != "x"; then
+        group=`echo "$GROUPADD_PARAM" | cut -d ';' -f 1 | awk '{ print $NF }'`
+        perform_groupdel "${STAGING_DIR_TARGET}" "$OPT $group"
+    fi
+fi
+}
+
+do_cleansstate[prefuncs] += "${SYSROOTCLEANFUNC}"
+SYSROOTCLEANFUNC = "userdel_sysroot_sstate"
+SYSROOTCLEANFUNC_class-cross = ""
+SYSROOTCLEANFUNC_class-native = ""
+SYSROOTCLEANFUNC_class-nativesdk = ""
+
 do_install[prefuncs] += "${SYSROOTFUNC}"
 SYSROOTFUNC = "useradd_sysroot"
 SYSROOTFUNC_class-cross = ""
-- 
2.4.0