From: Tom Hochstein <tom.hochstein@nxp.com>
To: meta-freescale@yoctoproject.org
Subject: [PATCH v3 24/43] imx-boot: Add recipes for i.MX 8 boot partition packages.
Date: Tue, 7 Aug 2018 10:42:16 -0500 [thread overview]
Message-ID: <1533656555-8038-25-git-send-email-tom.hochstein@nxp.com> (raw)
In-Reply-To: <1533656555-8038-1-git-send-email-tom.hochstein@nxp.com>
Signed-off-by: Tom Hochstein <tom.hochstein@nxp.com>
---
recipes-bsp/imx-mkimage/imx-boot_0.2.bb | 194 ++++++++++++++++++++++++++
recipes-bsp/imx-mkimage/imx-m4-demos_1.0.1.bb | 28 ++++
recipes-bsp/imx-mkimage/imx-m4-demos_2.3.0.bb | 42 ++++++
recipes-bsp/imx-mkimage/imx-m4-demos_2.3.1.bb | 33 +++++
recipes-bsp/imx-mkimage/imx-m4-demos_2.4.0.bb | 33 +++++
recipes-bsp/imx-mkimage/imx-mkimage_git.bb | 35 +++++
recipes-bsp/imx-mkimage/imx-mkimage_git.inc | 11 ++
7 files changed, 376 insertions(+)
create mode 100644 recipes-bsp/imx-mkimage/imx-boot_0.2.bb
create mode 100644 recipes-bsp/imx-mkimage/imx-m4-demos_1.0.1.bb
create mode 100644 recipes-bsp/imx-mkimage/imx-m4-demos_2.3.0.bb
create mode 100644 recipes-bsp/imx-mkimage/imx-m4-demos_2.3.1.bb
create mode 100644 recipes-bsp/imx-mkimage/imx-m4-demos_2.4.0.bb
create mode 100644 recipes-bsp/imx-mkimage/imx-mkimage_git.bb
create mode 100644 recipes-bsp/imx-mkimage/imx-mkimage_git.inc
diff --git a/recipes-bsp/imx-mkimage/imx-boot_0.2.bb b/recipes-bsp/imx-mkimage/imx-boot_0.2.bb
new file mode 100644
index 0000000..6d2f779
--- /dev/null
+++ b/recipes-bsp/imx-mkimage/imx-boot_0.2.bb
@@ -0,0 +1,194 @@
+# Copyright 2017-2018 NXP
+
+require imx-mkimage_git.inc
+
+DESCRIPTION = "Generate Boot Loader for i.MX 8 device"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/GPL-2.0;md5=801f80980d171dd6425610833a22dbe6"
+SECTION = "BSP"
+
+IMX_FIRMWARE = "imx-sc-firmware"
+IMX_FIRMWARE_mx8mq = "firmware-imx"
+IMX_FIRMWARE_mx8qxp = "firmware-imx imx-sc-firmware"
+DEPENDS += " \
+ u-boot \
+ ${IMX_FIRMWARE} \
+ imx-atf \
+ ${@bb.utils.contains('COMBINED_FEATURES', 'optee', 'optee-os-imx', '', d)} \
+"
+DEPENDS_append_mx8mq = " dtc-native"
+BOOT_NAME = "imx-boot"
+PROVIDES = "${BOOT_NAME}"
+
+inherit deploy
+
+# Add CFLAGS with native INCDIR & LIBDIR for imx-mkimage build
+CFLAGS = "-O2 -Wall -std=c99 -static -I ${STAGING_INCDIR_NATIVE} -L ${STAGING_LIBDIR_NATIVE}"
+
+# For i.MX 8, this package aggregates the imx-m4-demos
+# output. Note that this aggregation replaces the aggregation
+# that would otherwise be done in the image build as controlled
+# by IMAGE_BOOTFILES_DEPENDS and IMAGE_BOOTFILES in image_types_fsl.bbclass
+IMX_M4_DEMOS = ""
+IMX_M4_DEMOS_mx8qm = "imx-m4-demos:do_deploy"
+IMX_M4_DEMOS_mx8qxp = "imx-m4-demos:do_deploy"
+
+# This package aggregates output deployed by other packages,
+# so set the appropriate dependencies
+do_compile[depends] += " \
+ virtual/bootloader:do_deploy \
+ ${@' '.join('%s:do_deploy' % r for r in '${IMX_FIRMWARE}'.split() )} \
+ imx-atf:do_deploy \
+ ${IMX_M4_DEMOS} \
+ ${@bb.utils.contains('COMBINED_FEATURES', 'optee', 'optee-os-imx:do_deploy', '', d)} \
+"
+
+SC_FIRMWARE_NAME ?= "scfw_tcm.bin"
+
+ATF_MACHINE_NAME ?= "bl31-imx8qm.bin"
+ATF_MACHINE_NAME_mx8qm = "bl31-imx8qm.bin"
+ATF_MACHINE_NAME_mx8qxp = "bl31-imx8qxp.bin"
+ATF_MACHINE_NAME_mx8mq = "bl31-imx8mq.bin"
+
+DCD_NAME ?= "imx8qm_dcd.cfg.tmp"
+DCD_NAME_mx8qm = "imx8qm_dcd.cfg.tmp"
+DCD_NAME_mx8qxp = "imx8qx_dcd.cfg.tmp"
+
+UBOOT_NAME = "u-boot-${MACHINE}.bin-${UBOOT_CONFIG}"
+BOOT_CONFIG_MACHINE = "${BOOT_NAME}-${MACHINE}-${UBOOT_CONFIG}.bin"
+
+TOOLS_NAME ?= "mkimage_imx8"
+
+SOC_TARGET ?= "iMX8QM"
+SOC_TARGET_mx8qm = "iMX8QM"
+SOC_TARGET_mx8qxp = "iMX8QX"
+SOC_TARGET_mx8mq = "iMX8M"
+
+DEPLOY_OPTEE = "false"
+DEPLOY_OPTEE_mx8mq = "${@bb.utils.contains('COMBINED_FEATURES', 'optee', 'true', 'false', d)}"
+
+IMXBOOT_TARGETS ?= "${@bb.utils.contains('UBOOT_CONFIG', 'fspi', 'flash_flexspi', \
+ bb.utils.contains('UBOOT_CONFIG', 'nand', 'flash_nand', \
+ 'flash_multi_cores flash flash_dcd', d), d)}"
+IMXBOOT_TARGETS_mx8qxp = "${@bb.utils.contains('UBOOT_CONFIG', 'fspi', 'flash_flexspi', \
+ bb.utils.contains('UBOOT_CONFIG', 'nand', 'flash_nand', \
+ 'flash_all flash', d), d)}"
+IMXBOOT_TARGETS_mx8qxpa0 = "${@bb.utils.contains('UBOOT_CONFIG', 'fspi', 'flash_flexspi_a0', \
+ bb.utils.contains('UBOOT_CONFIG', 'nand', 'flash_nand_a0', \
+ 'flash_multi_cores_a0 flash_a0 flash_dcd_a0', d), d)}"
+IMXBOOT_TARGETS_imx8qxpddr3arm2 = "flash_ddr3_dcd_a0"
+
+do_compile () {
+ if [ "${SOC_TARGET}" = "iMX8M" ]; then
+ echo 8MQ boot binary build
+ for ddr_firmware in ${DDR_FIRMWARE_NAME}; do
+ echo "Copy ddr_firmware: ${ddr_firmware} from ${DEPLOY_DIR_IMAGE} -> ${S}/${SOC_TARGET} "
+ cp ${DEPLOY_DIR_IMAGE}/${ddr_firmware} ${S}/${SOC_TARGET}/
+ done
+ cp ${DEPLOY_DIR_IMAGE}/signed_hdmi_imx8m.bin ${S}/${SOC_TARGET}/
+ cp ${DEPLOY_DIR_IMAGE}/u-boot-spl.bin-${MACHINE}-${UBOOT_CONFIG} ${S}/${SOC_TARGET}/u-boot-spl.bin
+ cp ${DEPLOY_DIR_IMAGE}/${BOOT_TOOLS}/${UBOOT_DTB_NAME} ${S}/${SOC_TARGET}/
+ cp ${DEPLOY_DIR_IMAGE}/${BOOT_TOOLS}/u-boot-nodtb.bin ${S}/${SOC_TARGET}/
+ cp ${DEPLOY_DIR_IMAGE}/${BOOT_TOOLS}/mkimage_uboot ${S}/${SOC_TARGET}/
+
+ cp ${DEPLOY_DIR_IMAGE}/${BOOT_TOOLS}/${ATF_MACHINE_NAME} ${S}/${SOC_TARGET}/bl31.bin
+ cp ${DEPLOY_DIR_IMAGE}/${UBOOT_NAME} ${S}/${SOC_TARGET}/u-boot.bin
+
+ elif [ "${SOC_TARGET}" = "iMX8QM" ]; then
+ echo 8QM boot binary build
+ cp ${DEPLOY_DIR_IMAGE}/${BOOT_TOOLS}/${SC_FIRMWARE_NAME} ${S}/${SOC_TARGET}/scfw_tcm.bin
+ cp ${DEPLOY_DIR_IMAGE}/${BOOT_TOOLS}/${ATF_MACHINE_NAME} ${S}/${SOC_TARGET}/bl31.bin
+ cp ${DEPLOY_DIR_IMAGE}/${UBOOT_NAME} ${S}/${SOC_TARGET}/u-boot.bin
+
+ cp ${DEPLOY_DIR_IMAGE}/imx8qm_m4_0_TCM_rpmsg_lite_pingpong_rtos_linux_remote.bin ${S}/${SOC_TARGET}/m40_tcm.bin
+ cp ${DEPLOY_DIR_IMAGE}/imx8qm_m4_1_TCM_rpmsg_lite_pingpong_rtos_linux_remote.bin ${S}/${SOC_TARGET}/m41_tcm.bin
+
+ else
+ echo 8QX boot binary build
+ cp ${DEPLOY_DIR_IMAGE}/imx8qx_m4_TCM_rpmsg_lite_pingpong_rtos_linux_remote.bin ${S}/${SOC_TARGET}/m40_tcm.bin
+ cp ${DEPLOY_DIR_IMAGE}/imx8qx_m4_TCM_rpmsg_lite_pingpong_rtos_linux_remote.bin ${S}/${SOC_TARGET}/CM4.bin
+ cp ${DEPLOY_DIR_IMAGE}/ahab-container.img ${S}/${SOC_TARGET}/
+ cp ${DEPLOY_DIR_IMAGE}/${BOOT_TOOLS}/${SC_FIRMWARE_NAME} ${S}/${SOC_TARGET}/scfw_tcm.bin
+ cp ${DEPLOY_DIR_IMAGE}/${BOOT_TOOLS}/${ATF_MACHINE_NAME} ${S}/${SOC_TARGET}/bl31.bin
+ cp ${DEPLOY_DIR_IMAGE}/${UBOOT_NAME} ${S}/${SOC_TARGET}/u-boot.bin
+ fi
+
+ # Copy TEE binary to SoC target folder to mkimage
+ if ${DEPLOY_OPTEE}; then
+ cp ${DEPLOY_DIR_IMAGE}/tee.bin ${S}/${SOC_TARGET}/
+ fi
+
+ # mkimage for i.MX8
+ for target in ${IMXBOOT_TARGETS}; do
+ echo "building ${SOC_TARGET} - ${target}"
+ make SOC=${SOC_TARGET} ${target}
+ if [ -e "${S}/${SOC_TARGET}/flash.bin" ]; then
+ cp ${S}/${SOC_TARGET}/flash.bin ${S}/${BOOT_CONFIG_MACHINE}-${target}
+ fi
+ done
+}
+
+do_install () {
+ install -d ${D}/boot
+ for target in ${IMXBOOT_TARGETS}; do
+ install -m 0644 ${S}/${BOOT_CONFIG_MACHINE}-${target} ${D}/boot/
+ done
+}
+
+do_deploy () {
+ install -d ${DEPLOYDIR}/${BOOT_TOOLS}
+
+ # copy the tool mkimage to deploy path and sc fw, dcd and uboot
+ install -m 0644 ${DEPLOY_DIR_IMAGE}/${UBOOT_NAME} ${DEPLOYDIR}/${BOOT_TOOLS}
+ if [ "${SOC_TARGET}" = "iMX8M" ]; then
+ install -m 0644 ${DEPLOY_DIR_IMAGE}/u-boot-spl.bin-${MACHINE}-${UBOOT_CONFIG} ${DEPLOYDIR}/${BOOT_TOOLS}
+ for ddr_firmware in ${DDR_FIRMWARE_NAME}; do
+ install -m 0644 ${DEPLOY_DIR_IMAGE}/${ddr_firmware} ${DEPLOYDIR}/${BOOT_TOOLS}
+ done
+ install -m 0644 ${DEPLOY_DIR_IMAGE}/signed_hdmi*.bin ${DEPLOYDIR}/${BOOT_TOOLS}
+
+ install -m 0755 ${S}/${SOC_TARGET}/${TOOLS_NAME} ${DEPLOYDIR}/${BOOT_TOOLS}
+
+ install -m 0755 ${S}/${SOC_TARGET}/mkimage_fit_atf.sh ${DEPLOYDIR}/${BOOT_TOOLS}
+ elif [ "${SOC_TARGET}" = "iMX8QM" ]; then
+ install -m 0644 ${S}/${SOC_TARGET}/${DCD_NAME} ${DEPLOYDIR}/${BOOT_TOOLS}
+
+ install -m 0755 ${S}/${TOOLS_NAME} ${DEPLOYDIR}/${BOOT_TOOLS}
+ else
+ if [ "${MACHINE}" = "imx8qxpa0mek" ]; then
+ install -m 0644 ${S}/${SOC_TARGET}/${DCD_NAME} ${DEPLOYDIR}/${BOOT_TOOLS}
+ fi
+ install -m 0644 ${S}/${SOC_TARGET}/ahab-container.img ${DEPLOYDIR}/${BOOT_TOOLS}
+ install -m 0644 ${S}/${SOC_TARGET}/m40_tcm.bin ${DEPLOYDIR}/${BOOT_TOOLS}
+ install -m 0644 ${S}/${SOC_TARGET}/CM4.bin ${DEPLOYDIR}/${BOOT_TOOLS}
+
+ install -m 0755 ${S}/${TOOLS_NAME} ${DEPLOYDIR}/${BOOT_TOOLS}
+ fi
+
+ # copy tee.bin to deploy path
+ if "${DEPLOY_OPTEE}"; then
+ install -m 0644 ${DEPLOY_DIR_IMAGE}/tee.bin ${DEPLOYDIR}/${BOOT_TOOLS}
+ fi
+
+ # copy makefile (soc.mak) for reference
+ install -m 0644 ${S}/${SOC_TARGET}/soc.mak ${DEPLOYDIR}/${BOOT_TOOLS}
+
+ # copy the generated boot image to deploy path
+ for target in ${IMXBOOT_TARGETS}; do
+ # Use first "target" as IMAGE_IMXBOOT_TARGET
+ if [ "$IMAGE_IMXBOOT_TARGET" = "" ]; then
+ IMAGE_IMXBOOT_TARGET="$target"
+ echo "Set boot target as $IMAGE_IMXBOOT_TARGET"
+ fi
+ install -m 0644 ${S}/${BOOT_CONFIG_MACHINE}-${target} ${DEPLOYDIR}
+ done
+ cd ${DEPLOYDIR}
+ ln -sf ${BOOT_CONFIG_MACHINE}-${IMAGE_IMXBOOT_TARGET} ${BOOT_CONFIG_MACHINE}
+ cd -
+}
+addtask deploy before do_build after do_compile
+
+FILES_${PN} = "/boot"
+
+COMPATIBLE_MACHINE = "(mx8qm|mx8qxp|mx8mq)"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
diff --git a/recipes-bsp/imx-mkimage/imx-m4-demos_1.0.1.bb b/recipes-bsp/imx-mkimage/imx-m4-demos_1.0.1.bb
new file mode 100644
index 0000000..036cdce
--- /dev/null
+++ b/recipes-bsp/imx-mkimage/imx-m4-demos_1.0.1.bb
@@ -0,0 +1,28 @@
+SUMMARY = "i.MX M4 core Demo images"
+SECTION = "app"
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://COPYING;md5=8cf95184c220e247b9917e7244124c5a"
+
+inherit deploy fsl-eula-unpack
+
+M4_SOC ?= "imx7d-sabresd"
+M4_SOC_mx7 = "imx7d-sabresd"
+
+SRC_URI = "${FSL_MIRROR}/${M4_SOC}-m4-freertos-${PV}.bin;fsl-eula=true"
+S = "${WORKDIR}/${M4_SOC}-m4-freertos-${PV}"
+
+SRC_URI[md5sum] = "b05b780ff3916f4953ab58ac95233c38"
+SRC_URI[sha256sum] = "cc00d3b936d49b2794a2a99e10129437e70caba3fd26b8379b8c50dd22f73254"
+
+do_deploy () {
+ # Install the demo binaries
+ install -d ${DEPLOYDIR}
+ cp ${S}/*.bin ${DEPLOYDIR}/
+ ls ${DEPLOYDIR}/
+}
+
+addtask deploy before do_build after do_compile
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+COMPATIBLE_MACHINE = "(mx7)"
+
diff --git a/recipes-bsp/imx-mkimage/imx-m4-demos_2.3.0.bb b/recipes-bsp/imx-mkimage/imx-m4-demos_2.3.0.bb
new file mode 100644
index 0000000..599a5d5
--- /dev/null
+++ b/recipes-bsp/imx-mkimage/imx-m4-demos_2.3.0.bb
@@ -0,0 +1,42 @@
+# Copyright 2017-2018 NXP
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+SUMMARY = "i.MX M4 core Demo images"
+SECTION = "app"
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://COPYING;md5=08fd295cce89b0a9c74b9b83ed74f671"
+
+inherit deploy fsl-eula-unpack2
+
+SOC ?= "imx8qm"
+SOC_mx7ulp= "imx7ulp"
+SOC_mx8mq= "imx8mq"
+SOC_mx8qm= "imx8qm"
+SOC_mx8qxp= "imx8qx"
+
+IMX_PACKAGE_NAME = "${SOC}-m4-demo-${PV}"
+SRC_URI_NAME = "${SOC}"
+
+SRC_URI[imx7ulp.md5sum] = "601472aa2056c34324ba8b2d8b656d10"
+SRC_URI[imx7ulp.sha256sum] = "6ad1d21356a5bbfdc52e4709348c7bee49e0731ef0a106f599c78817e14d3d12"
+
+SRC_URI[imx8mq.md5sum] = "c2aeda4ca7cc7d1c2916be7dd42b946f"
+SRC_URI[imx8mq.sha256sum] = "fd441e75395b0c6f90626c883ee8a93406b14e7d55adc7925116254394bb7ad8"
+
+SRC_URI[imx8qm.md5sum] = "b75dda504083ac1ee05423974c22bbce"
+SRC_URI[imx8qm.sha256sum] = "fdc486af0a02e3093559b31cb9c982f05c209bfc03da0910062091c406bfb496"
+
+SRC_URI[imx8qx.md5sum] = "b18198150c3aa5b1e01aba2047166728"
+SRC_URI[imx8qx.sha256sum] = "3b3887694b7cfe02d2918b0780f941da3d5c0e867725927b8c8f19fbff106bc9"
+
+SCR = "SCR-${SOC}-m4-demo.txt"
+
+do_deploy () {
+ # Install the demo binaries
+ cp ${D}/* ${DEPLOYDIR}/
+}
+
+addtask deploy before do_build after do_install
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+COMPATIBLE_MACHINE = "(mx7ulp|mx8mq|mx8qm|mx8qxp)"
diff --git a/recipes-bsp/imx-mkimage/imx-m4-demos_2.3.1.bb b/recipes-bsp/imx-mkimage/imx-m4-demos_2.3.1.bb
new file mode 100644
index 0000000..62ecca9
--- /dev/null
+++ b/recipes-bsp/imx-mkimage/imx-m4-demos_2.3.1.bb
@@ -0,0 +1,33 @@
+# Copyright 2017-2018 NXP
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+SUMMARY = "i.MX M4 core Demo images"
+SECTION = "app"
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://COPYING;md5=ab61cab9599935bfe9f700405ef00f28"
+
+inherit deploy fsl-eula-unpack2
+
+SOC ?= "imx8qm"
+SOC_mx7ulp= "imx7ulp"
+SOC_mx8mq= "imx8mq"
+SOC_mx8qm= "imx8qm"
+SOC_mx8qxp= "imx8qx"
+
+IMX_PACKAGE_NAME = "${SOC}-m4-demo-${PV}"
+SRC_URI_NAME = "${SOC}"
+
+SRC_URI[imx8qx.md5sum] = "e497c9742c0f20fbc429446c8052ade7"
+SRC_URI[imx8qx.sha256sum] = "b46ac529c7c0fab9f99d39b094a9c4d6651616643f5df5ac2a4113bef02411fb"
+
+SCR = "SCR-${SOC}-m4-demo.txt"
+
+do_deploy () {
+ # Install the demo binaries
+ cp ${D}/* ${DEPLOYDIR}/
+}
+
+addtask deploy before do_build after do_install
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+COMPATIBLE_MACHINE = "(mx8qxp)"
diff --git a/recipes-bsp/imx-mkimage/imx-m4-demos_2.4.0.bb b/recipes-bsp/imx-mkimage/imx-m4-demos_2.4.0.bb
new file mode 100644
index 0000000..30100aa
--- /dev/null
+++ b/recipes-bsp/imx-mkimage/imx-m4-demos_2.4.0.bb
@@ -0,0 +1,33 @@
+# Copyright 2017-2018 NXP
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+SUMMARY = "i.MX M4 core Demo images"
+SECTION = "app"
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://COPYING;md5=75abe2fa1d16ca79f87cde926f05f72d"
+
+inherit deploy fsl-eula-unpack2
+
+SOC ?= "imx8qm"
+SOC_mx7ulp= "imx7ulp"
+SOC_mx8mq= "imx8mq"
+SOC_mx8qm= "imx8qm"
+SOC_mx8qxp= "imx8qx"
+
+IMX_PACKAGE_NAME = "${SOC}-m4-demo-${PV}"
+SRC_URI_NAME = "${SOC}"
+
+SRC_URI[imx7ulp.md5sum] = "cf2c88b91b4f87781365d8b0921d1cf3"
+SRC_URI[imx7ulp.sha256sum] = "f4852a8da27bec0853ef499614d9337d586749805bc2c3d58500a7016ae52bdb"
+
+SCR = "SCR-${SOC}-m4-demo.txt"
+
+do_deploy () {
+ # Install the demo binaries
+ cp ${D}/* ${DEPLOYDIR}/
+}
+
+addtask deploy before do_build after do_install
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+COMPATIBLE_MACHINE = "(mx7ulp)"
diff --git a/recipes-bsp/imx-mkimage/imx-mkimage_git.bb b/recipes-bsp/imx-mkimage/imx-mkimage_git.bb
new file mode 100644
index 0000000..b0a2719
--- /dev/null
+++ b/recipes-bsp/imx-mkimage/imx-mkimage_git.bb
@@ -0,0 +1,35 @@
+# Copyright (C) 2016 Freescale Semiconductor
+# Copyright 2017-2018 NXP
+
+require imx-mkimage_git.inc
+
+DESCRIPTION = "i.MX make image"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/GPL-2.0;md5=801f80980d171dd6425610833a22dbe6"
+SECTION = "BSP"
+
+inherit native deploy
+
+CFLAGS = "-O2 -Wall -std=c99 -static -I ${STAGING_INCDIR} -L ${STAGING_LIBDIR}"
+
+do_compile () {
+ cd ${S}
+ oe_runmake clean
+ oe_runmake bin
+ oe_runmake -C iMX8M -f soc.mak mkimage_imx8
+ oe_runmake -C iMX8QM -f soc.mak imx8qm_dcd.cfg.tmp
+ oe_runmake -C iMX8QX -f soc.mak imx8qx_dcd.cfg.tmp
+}
+
+do_install () {
+ cd ${S}
+ install -d ${D}${bindir}
+ install -m 0755 iMX8M/mkimage_imx8 ${D}${bindir}/mkimage_imx8m
+ install -m 0755 mkimage_imx8 ${D}${bindir}/mkimage_imx8
+}
+
+do_deploy () {
+ install -m 0644 ${S}/iMX8QM/imx8qm_dcd.cfg.tmp ${DEPLOYDIR}
+ install -m 0644 ${S}/iMX8QX/imx8qx_dcd.cfg.tmp ${DEPLOYDIR}
+}
+addtask deploy before do_build after do_install
diff --git a/recipes-bsp/imx-mkimage/imx-mkimage_git.inc b/recipes-bsp/imx-mkimage/imx-mkimage_git.inc
new file mode 100644
index 0000000..d4eaead
--- /dev/null
+++ b/recipes-bsp/imx-mkimage/imx-mkimage_git.inc
@@ -0,0 +1,11 @@
+# Copyright 2017-2018 NXP
+
+DEPENDS = "zlib-native openssl-native"
+
+SRCBRANCH = "imx_4.9.88_imx8qxp_beta2"
+SRC_URI = "git://source.codeaurora.org/external/imx/imx-mkimage.git;protocol=https;branch=${SRCBRANCH}"
+SRCREV = "5c18f544c460747daed2844714c49685ed6ce897"
+S = "${WORKDIR}/git"
+
+BOOT_TOOLS = "imx-boot-tools"
+SYSROOT_DIRS += "/boot"
--
2.7.4
next prev parent reply other threads:[~2018-08-07 15:43 UTC|newest]
Thread overview: 38+ messages / expand[flat|nested] mbox.gz Atom feed top
2018-08-07 15:41 [PATCH v3 00/43] L4.9.88-2.2.0 recipes-bsp and recipes-graphics Tom Hochstein
2018-08-07 15:41 ` [PATCH v3 01/43] xserver-xorg: Update OpenGL configuration Tom Hochstein
2018-08-07 15:41 ` [PATCH v3 02/43] imx-gpu-g2d: Improve COMPATIBLE_MACHINE Tom Hochstein
2018-08-07 15:41 ` [PATCH v3 03/43] waffle: Configure for i.MX GPU Tom Hochstein
2018-08-07 15:41 ` [PATCH v3 04/43] weston: Fix non-GPU support Tom Hochstein
2018-09-07 8:05 ` [v3,04/43] " Gary Bisson
2018-09-07 11:41 ` Tom Hochstein
2018-09-07 12:19 ` Gary Bisson
2018-09-07 13:26 ` Tom Hochstein
2018-09-07 13:47 ` Gary Bisson
2018-08-07 15:41 ` [PATCH v3 05/43] wayland-protocols: Downgrade to 1.13 for i.MX Tom Hochstein
2018-09-10 8:12 ` Andreas Müller
2018-09-10 15:13 ` Tom Hochstein
2018-09-10 17:29 ` Andreas Müller
2018-08-07 15:41 ` [PATCH v3 06/43] wayland-protocols: Add HDR10 metadata and alpha compositing protocols Tom Hochstein
2018-08-07 15:41 ` [PATCH v3 07/43] EULA: Update to v24 Tom Hochstein
2018-08-07 15:42 ` [PATCH v3 08/43] linux-imx: Add i.MX 8 support Tom Hochstein
2018-08-07 15:42 ` [PATCH v3 09/43] u-boot-imx: Add support for i.MX 8QM, 8MQ, and 8QXP Tom Hochstein
2018-08-07 15:42 ` [PATCH v3 10/43] machine: " Tom Hochstein
2018-08-07 15:42 ` [PATCH v3 11/43] imx-dpu-g2d: Use machine override for compatibility Tom Hochstein
2018-08-07 15:42 ` [PATCH v3 12/43] kernel-module-imx-gpu-viv: Update to 6.2.4.p1.6 Tom Hochstein
2018-08-07 15:42 ` [PATCH v3 13/43] imx-gpu-viv: " Tom Hochstein
2018-08-07 15:42 ` [PATCH v3 14/43] imx-gpu-g2d: " Tom Hochstein
2018-08-07 15:42 ` [PATCH v3 15/43] imx-dpu-g2d: Update to 1.4.6 Tom Hochstein
2018-08-07 15:42 ` [PATCH v3 16/43] xf86-video-imx-vivante: Update to 6.2.4.p1.6 Tom Hochstein
2018-08-07 15:42 ` [PATCH v3 17/43] imx-gpu-viv: Remove wayland-egl files Tom Hochstein
2018-08-07 15:42 ` [PATCH v3 18/43] imx-gpu-viv: Add support for i.MX 8 and 8X families Tom Hochstein
2018-08-07 15:42 ` [PATCH v3 19/43] imx-gpu-viv: Add support for OpenCL and OpenVX Tom Hochstein
2018-08-07 15:42 ` [PATCH v3 20/43] fsl-eula: Extend EULA-based archive support Tom Hochstein
2018-08-07 15:42 ` [PATCH v3 21/43] u-boot-imx: Deploy tools on boot partition for i.MX 8MQ Tom Hochstein
2018-08-07 15:42 ` [PATCH v3 22/43] imx-atf: Add new package ARM Trusted Firmware Tom Hochstein
2018-08-07 15:42 ` [PATCH v3 23/43] imx-sc-firmware: Add new package System Controller Firmware Tom Hochstein
2018-08-07 15:42 ` Tom Hochstein [this message]
2018-08-07 15:42 ` [PATCH v3 25/43] alsa-state: Fix buffer size issue Tom Hochstein
2018-08-07 15:42 ` [PATCH v3 26/43] alsa-state: Add support for splitting ESAI device Tom Hochstein
2018-08-07 15:42 ` [PATCH v3 27/43] alsa-state: Fix channel swap issues Tom Hochstein
2018-08-07 15:42 ` [PATCH v3 28/43] alsa-state: Fix HDMI for i.MX 8M Tom Hochstein
2018-08-07 15:42 ` [PATCH v3 29/43] alsa-state: Add new codecs " Tom Hochstein
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1533656555-8038-25-git-send-email-tom.hochstein@nxp.com \
--to=tom.hochstein@nxp.com \
--cc=meta-freescale@yoctoproject.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.