Re: [meta-oe][PATCH v2] fbida 2.09: cleanups and use PACKAGECONFIG

[Martin Jansa <martin.jansa@gmail.com>]

[-- Attachment #1: Type: text/plain, Size: 3483 bytes --]

On Fri, Feb 28, 2014 at 02:41:40PM +0100, Matthieu Crapet wrote:
> There are now 3 packageconfig variables: gif, png, tiff.
> 
> Changes:
> - fix missing $ for STAGING_INCDIR (jpeg version detection)
> - add DESCRIPTION
> - no more QA warnings
> Use this to reveal:
> sed -i -e '/^verbose/s/no/yes/' ${S}/mk/Autoconf.mk
> 
> Signed-off-by: Matthieu Crapet <Matthieu.Crapet@ingenico.com>
> ---
>  meta-oe/recipes-graphics/fbida/fbida_2.09.bb | 35 ++++++++++++++++++++++++----
>  1 file changed, 31 insertions(+), 4 deletions(-)
> 
> diff --git a/meta-oe/recipes-graphics/fbida/fbida_2.09.bb b/meta-oe/recipes-graphics/fbida/fbida_2.09.bb
> index 32f376f..0c663c1 100644
> --- a/meta-oe/recipes-graphics/fbida/fbida_2.09.bb
> +++ b/meta-oe/recipes-graphics/fbida/fbida_2.09.bb
> @@ -1,21 +1,49 @@
> +SUMMARY = "Framebuffer image and doc viewer tools"
> +DESCRIPTION = "The fbida project contains a few applications for viewing and editing images, \
> +               with the main focus being photos."
>  HOMEPAGE = "http://linux.bytesex.org/fbida/"
> -SUMMARY = "frame buffer image and doc viewer tools"
>  AUTHOR = "Gerd Hoffmann"
>  SECTION = "utils"
>  
>  LICENSE = "GPLv2"
>  LIC_FILES_CHKSUM = "file://COPYING;md5=8ca43cbc842c2336e835926c2166c28b"
>  
> -DEPENDS = "virtual/libiconv libpng jpeg fontconfig freetype libexif curl libungif tiff"
> +DEPENDS = "virtual/libiconv jpeg fontconfig freetype libexif curl"
>  
> +PR = "r1"

you don't need this

> +
> +# Note: SRCREV is 3 revisions ahead of 2.09

It would be better to add

PV = "2.09+git${SRCPV}"

and rename the recipe to fbida_git.bb that way it will be clear from
package version which revision was used.

>  SRC_URI = "git://git.kraxel.org/fbida"
>  SRCREV = "cb0ce5fa5f42bfaea4f8f326bcd8914dd14e782d"
>  S = "${WORKDIR}/git"
>  
>  EXTRA_OEMAKE = "STRIP="
>  
> +PACKAGECONFIG ??= "gif png"
> +PACKAGECONFIG[gif] = ",,libungif"
> +PACKAGECONFIG[png] = ",,libpng"
> +PACKAGECONFIG[tiff] = ",,tiff"
> +
>  do_compile() {
> -    sed -i -e 's: cpp: ${TARGET_PREFIX}cpp -I{STAGING_INCDIR}:g' GNUmakefile
> +    sed -i -e 's:/sbin/ldconfig:echo x:' ${S}/mk/Autoconf.mk
> +    sed -i -e 's: cpp: ${TARGET_PREFIX}cpp -I${STAGING_INCDIR}:' ${S}/GNUmakefile
> +
> +    if [ -z "${@base_contains('DISTRO_FEATURES', 'x11', 'x11', '', d)}" ]; then
> +        sed -i -e '/^HAVE_MOTIF/s/:=.*$/:= no/' ${S}/GNUmakefile
> +    fi
> +
> +    # Be sure to respect preferences (force to "no")
> +    # Also avoid issues when ${BUILD_ARCH} == ${HOST_ARCH}
> +    if [ -z "${@base_contains('PACKAGECONFIG', 'gif', 'gif', '', d)}" ]; then
> +        sed -i -e '/^HAVE_LIBUNGIF/s/:=.*$/:= no/' ${S}/GNUmakefile
> +    fi
> +    if [ -z "${@base_contains('PACKAGECONFIG', 'png', 'png', '', d)}" ]; then
> +        sed -i -e '/^HAVE_LIBPNG/s/:=.*$/:= no/' ${S}/GNUmakefile
> +    fi
> +    if [ -z "${@base_contains('PACKAGECONFIG', 'tiff', 'tiff', '', d)}" ]; then
> +        sed -i -e '/^HAVE_LIBTIFF/s/:=.*$/:= no/' ${S}/GNUmakefile
> +    fi
> +
>      oe_runmake
>  }
>  
> @@ -24,4 +52,3 @@ do_install() {
>  }
>  
>  RDEPENDS_${PN} = "ttf-dejavu-sans-mono"
> -
> -- 
> 1.8.5.4
> 
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel@lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa@gmail.com

[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 205 bytes --]