Re: [meta-oe][PATCH 1/2] bdftopcf: add recipe

[Martin Jansa <martin.jansa@gmail.com>]

[-- Attachment #1: Type: text/plain, Size: 3805 bytes --]

On Thu, Apr 10, 2014 at 12:58:17PM -0400, Trevor Woerner wrote:
> Signed-off-by: Trevor Woerner <trevor.woerner@linaro.org>
> ---
>  meta-oe/recipes-graphics/xorg-app/bdftopcf_1.0.4.bb | 13 +++++++++++++
>  1 file changed, 13 insertions(+)
>  create mode 100644 meta-oe/recipes-graphics/xorg-app/bdftopcf_1.0.4.bb
> 
> diff --git a/meta-oe/recipes-graphics/xorg-app/bdftopcf_1.0.4.bb b/meta-oe/recipes-graphics/xorg-app/bdftopcf_1.0.4.bb
> new file mode 100644
> index 0000000..2b0775d
> --- /dev/null
> +++ b/meta-oe/recipes-graphics/xorg-app/bdftopcf_1.0.4.bb
> @@ -0,0 +1,13 @@
> +SUMMARY = "bdftopcf is a font compiler for the X server and font server"
> +HOMEPAGE = "http://cgit.freedesktop.org/xorg/app/bdftopcf/"
> +SECTION = "x11/app"
> +LICENSE = "MIT"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=f9a35333adf75edd1eaef84bca65a490"
> +DEPENDS = "libxfont"
> +
> +SRC_URI[md5sum] = "96a648a332160a7482885800f7a506fa"
> +SRC_URI[sha256sum] = "eaf59057ba3d7cffe29526562ce50868da7da823487a4cfb3e16946e5ffd2798"
> +
> +require recipes-graphics/xorg-app/xorg-app-common.inc
> +
> +BBCLASSEXTEND = "native"

bdftopcf-native failed in world build:

| checking whether make supports nested variables... (cached) yes
| checking for BDFTOPCF... no
| configure: error: Package requirements (xfont) were not met:
|
| No package 'xfont' found
|
| Consider adjusting the PKG_CONFIG_PATH environment variable if you
| installed software in a non-standard prefix.
|
| Alternatively, you may set the environment variables BDFTOPCF_CFLAGS
| and BDFTOPCF_LIBS to avoid the need to call pkg-config.
| See the pkg-config man page for more details.
| Configure failed. The contents of all config.log files follows to aid debugging
| /home/jenkins/oe/shr-core-branches/shr-core/tmp-eglibc/work/x86_64-linux/bdftopcf-native/1.0.4-r0/bdftopcf-1.0.4/config.log
| This file contains any messages produced by compilers while
| running configure, to aid debugging if configure makes a mistake.

You need to move require.*inc to the top, see:

# $DEPENDS [11 operations]
#   set /OE/build/shr-core/openembedded-core/meta/conf/bitbake.conf:255
#     ""
#   set /OE/build/shr-core/openembedded-core/meta/conf/documentation.conf:132
#     [doc] "Lists a recipe's build-time dependencies (i.e. other recipe files)."
#   _prepend /OE/build/shr-core/openembedded-core/meta/classes/base.bbclass:81
#     "${BASEDEPENDS} "
#   set /OE/build/shr-core/meta-openembedded/meta-oe/recipes-graphics/xorg-app/bdftopcf_1.0.4.bb:6
#     "libxfont"
#   set /OE/build/shr-core/openembedded-core/meta/recipes-graphics/xorg-app/xorg-app-common.inc:6
#     "util-macros-native virtual/libx11"
#   _prepend /OE/build/shr-core/openembedded-core/meta/classes/autotools.bbclass:24
#     "${@autotools_dep_prepend(d)}"
#   _prepend /OE/build/shr-core/openembedded-core/meta/classes/pkgconfig.bbclass:1
#     "pkgconfig-native "
#   set native_virtclass_handler(e):25 [map_dependencies]
#     "util-macros-native virtual/libx11-native"
#   set data_smart.py:432 [finalize]
#     "${BASEDEPENDS} util-macros-native virtual/libx11-native"
#   set data_smart.py:432 [finalize]
#     "${@autotools_dep_prepend(d)}${BASEDEPENDS} util-macros-native virtual/libx11-native"
#   set data_smart.py:432 [finalize]
#     "pkgconfig-native ${@autotools_dep_prepend(d)}${BASEDEPENDS} util-macros-native virtual/libx11-native"
# computed:
#   "pkgconfig-native ${@autotools_dep_prepend(d)}${BASEDEPENDS} util-macros-native virtual/libx11-native"
DEPENDS="pkgconfig-native autoconf-native automake-native libtool-native gnu-config-native  util-macros-native virtual/libx11-native"

other variables are overwritten from .inc as well.


-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa@gmail.com

[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 205 bytes --]