Re: [PATCH v2] ti-softhsmv2: Add recipe for ti customised softhsm package

[Denys Dmytriyenko <denys@ti.com>]

Ack

On Thu, Jan 29, 2015 at 11:11:25AM -0500, Sam Nelson wrote:
> - Provide library, deamon and util for ti customised softhsm
> 
> Signed-off-by: Sam Nelson <sam.nelson@ti.com>
> 
> ---
> Changes from previous patch
> - Update LICENSE information
> ---
> ---
>  recipes-ti/ti-softhsmv2/ti-softhsmv2_git.bb |   43 +++++++++++++++++++++++++++
>  1 file changed, 43 insertions(+)
>  create mode 100644 recipes-ti/ti-softhsmv2/ti-softhsmv2_git.bb
> 
> diff --git a/recipes-ti/ti-softhsmv2/ti-softhsmv2_git.bb b/recipes-ti/ti-softhsmv2/ti-softhsmv2_git.bb
> new file mode 100644
> index 0000000..518508c
> --- /dev/null
> +++ b/recipes-ti/ti-softhsmv2/ti-softhsmv2_git.bb
> @@ -0,0 +1,43 @@
> +DESCRIPTION = "TI softhsmv2 package"
> +LICENSE = "BSD-2-Clause | BSD-3-Clause | ISC | IBM-License | FSFULLR | Zlib"
> +LIC_FILES_CHKSUM = "file://LICENSE;md5=55144a048ba54f211a1aaa38c7fd2424"
> +SECTION = "libs"
> +
> +mntdir = "/mnt"
> +
> +inherit autotools pkgconfig
> +
> +DEPENDS = "openssl libdaemon"
> +COMPATIBLE_MACHINE = "(tci6614-evm|keystone)"
> +
> +BRANCH="master"
> +SRC_URI = "git://git.ti.com/keystone-linux/ti-softhsmv2.git;protocol=git;branch=${BRANCH}"
> +#Following commit corresponds to tag DEV.SOFTHSM-01.03.00.01
> +SRCREV = "c79d93ac2a326567a7245dda1b903ef340b5650c"
> +PV = "1.3.0.1"
> +
> +S = "${WORKDIR}/git"
> +
> +CFLAGS += " -mno-unaligned-access"
> +CPPFLAGS += " -mno-unaligned-access"
> +
> +INITSCRIPT_NAME = "softhsm-daemon.sh"
> +INITSCRIPT_PARAMS = "defaults 10"
> +
> +inherit update-rc.d
> +
> +SELECTED_OPTIMIZATION := "${@d.getVar("SELECTED_OPTIMIZATION", True).replace("-O2", "-O3")}"
> +SELECTED_OPTIMIZATION := "${@d.getVar("SELECTED_OPTIMIZATION", True).replace("-ggdb2", "")}"
> +
> +FILES_${PN} += "${libdir}/softhsm/lib*.so.* ${mntdir}/*"
> +FILES_${PN}-dbg += "${libdir}/softhsm/.debug"
> +FILES_${PN}-staticdev += "${libdir}/softhsm/*.a "
> +FILES_${PN}-dev += "${libdir}/softhsm/*.la ${libdir}/softhsm/lib*.so"
> +
> +do_install_append() {
> +	install -d ${D}${mntdir}/securedbv0
> +	install -d ${D}${mntdir}/securedbv1
> +
> +	install -d ${D}${sysconfdir}/init.d/
> +	install -c -m 755 ${S}/src/bin/daemon/softhsm-daemon.sh ${D}${sysconfdir}/init.d/${INITSCRIPT_NAME}
> +}
> -- 
> 1.7.9.5
> 
> -- 
> _______________________________________________
> meta-ti mailing list
> meta-ti@yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-ti