Re: [PATCH 01/12] fontforge: add 20141126

[Martin Jansa <martin.jansa@gmail.com>]

[-- Attachment #1: Type: text/plain, Size: 2784 bytes --]

On Mon, May 25, 2015 at 11:13:58PM +0200, Andreas Müller wrote:
> Have this recipe in my meta-qt5-extra but would be happy to get it under the
> hood of Martin's world.
> 
> It started with the native part to build kde's oxygen-fonts but maybe somebody
> likes to have it on target.
> 
> Tested native part by gazillions of builds / target part in xfce environment.
> 
> Signed-off-by: Andreas Müller <schnitzeltony@googlemail.com>
> ---
>  .../fontforge/fontforge_20141126.bb                | 41 ++++++++++++++++++++++
>  1 file changed, 41 insertions(+)
>  create mode 100644 meta-oe/recipes-graphics/fontforge/fontforge_20141126.bb
> 
> diff --git a/meta-oe/recipes-graphics/fontforge/fontforge_20141126.bb b/meta-oe/recipes-graphics/fontforge/fontforge_20141126.bb
> new file mode 100644
> index 0000000..72020db
> --- /dev/null
> +++ b/meta-oe/recipes-graphics/fontforge/fontforge_20141126.bb
> @@ -0,0 +1,41 @@
> +SUMMARY = "A font editor"
> +HOMEPAGE = "http://fontforge.github.io/en-US/"
> +LICENSE = "GPLv3"
> +LIC_FILES_CHKSUM = " \
> +    file://COPYING.gplv3;md5=d32239bcb673463ab874e80d47fae504 \
> +    file://LICENSE;md5=71d636ba7678baa1573e1b531041386e \
> +"
> +
> +inherit autotools pkgconfig pythonnative
> +
> +DEPENDS = "glib-2.0 pango giflib tiff libxml2 jpeg python libtool"
> +DEPENDS_append_class-target = " libxi"
> +
> +SRC_URI = "https://github.com/${BPN}/${BPN}/archive/${PV}.tar.gz"

Don't use github archives, they are regenerated from time to time with 
different checksums and they have stupid filenames (prone to collision 
with other recipes).

can you send follow-up patch?

> +SRC_URI[md5sum] = "0d6f5112c4e5689087339a94aceadf77"
> +SRC_URI[sha256sum] = "9c90c640023463c0b2b97b87575a014fcf44f688c3763f4cd136d3c267092106"
> +
> +EXTRA_OECONF_append_class-native = " with_x=no --disable-python-extension --disable-python-scripting"
> +
> +do_configure_prepend() {
> +    currdir=`pwd`
> +    cd ${S}
> +    ./bootstrap --force
> +    cd $currdir
> +}
> +
> +EXTRA_OEMAKE = "CFLAGS='${CFLAGS} -I${B}/uthash/src'"
> +
> +PACKAGES =+ "${PN}-python-dbg ${PN}-python"
> +
> +FILES_${PN} += " \
> +    ${datadir}/mime \
> +    ${datadir}/icons \
> +"
> +
> +FILES_${PN}-python = "${PYTHON_SITEPACKAGES_DIR} ${datadir}/${PN}/python"
> +FILES_${PN}-python-dbg = "${PYTHON_SITEPACKAGES_DIR}/.debug"
> +RDEPENDS_${PN}-python = "python"
> +
> +# for e.g kde's oxygen-fonts
> +BBCLASSEXTEND = "native"
> -- 
> 1.9.3
> 
> -- 
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel@lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa@gmail.com

[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 188 bytes --]