Re: [PATCH v3] dspdce-fw: add recipe to build dspdce-fw from git source

[Denys Dmytriyenko <denys@ti.com>]

On Tue, Sep 22, 2015 at 03:47:33PM -0400, Hongmei Gou wrote:
> Signed-off-by: Hongmei Gou <h-gou@ti.com>
> 
> v3 changes:
> 1) Remove SRCREV from PV

I didn't mean you should remove it, but if you need git commit in the version, 
you should use SRCPV instead of SRCREV, as there's some processing involved...


> 2) Remove PACKAGE_ARCH since the build steps are common for the compatible machines

Ack this one.


> ---
>  recipes-bsp/dspdce-fw/dspdce-fw_git.bb | 56 ++++++++++++++++++++++++++++++++++
>  1 file changed, 56 insertions(+)
>  create mode 100644 recipes-bsp/dspdce-fw/dspdce-fw_git.bb
> 
> diff --git a/recipes-bsp/dspdce-fw/dspdce-fw_git.bb b/recipes-bsp/dspdce-fw/dspdce-fw_git.bb
> new file mode 100644
> index 0000000..2ba48c3
> --- /dev/null
> +++ b/recipes-bsp/dspdce-fw/dspdce-fw_git.bb
> @@ -0,0 +1,56 @@
> +DESCRIPTION = "Firmware for DSP for an example application called copycodectest"
> +LICENSE = "TI-TSPA"
> +LIC_FILES_CHKSUM = "file://src/ti/framework/dce/dce.c;startline=1;endline=31;md5=2c6e9aba6ed75f22b1a2b7544b1c809d"
> +
> +COMPATIBLE_MACHINE = "dra7xx"
> +
> +SRC_URI = "git://git.ti.com/glsdk/dspdce.git;protocol=git"
> +
> +SRCREV = "71e8fbf8e4f91b60680cf18a0c202a222e9ae3ba"
> +
> +PV = "1.00.00.06+git"
> +
> +S = "${WORKDIR}/git"
> +
> +require recipes-ti/includes/ti-paths.inc
> +require recipes-ti/includes/ti-staging.inc
> +
> +PR = "r0"
> +
> +DEPENDS = "ti-xdctools ti-sysbios ti-codec-engine ti-framework-components ti-xdais ti-ipc-rtos ti-osal ti-cgt6x-native"
> +
> +export HWVERSION="ES10"
> +export BIOSTOOLSROOT="${STAGING_DIR_TARGET}/usr/share/ti"
> +
> +export XDCVERSION="ti-xdctools-tree"
> +export BIOSVERSION="ti-sysbios-tree"
> +export IPCVERSION="ti-ipc-tree"
> +export CEVERSION="ti-codec-engine-tree"
> +export FCVERSION="ti-framework-components-tree"
> +export XDAISVERSION="ti-xdais-tree"
> +export OSALVERSION="ti-osal-tree"
> +
> +export IPCSRC="${STAGING_DIR_TARGET}/usr/share/ti/ti-ipc-tree"
> +export C66XCGTOOLSPATH="${STAGING_DIR_NATIVE}/usr/share/ti/cgt-c6x"
> +
> +do_configure() {
> +    cd ${S}
> +    make unconfig
> +    make vayu_config
> +}
> +
> +do_compile() {
> +    cd ${S}
> +    make dspbin
> +}
> +
> +TARGET = "dra7-dsp1-fw.xe66.dce"
> +
> +do_install() {
> +        mkdir -p ${D}${base_libdir}/firmware
> +        cp ${S}/dra7xx-c66x-dsp.xe66 ${D}${base_libdir}/firmware/${TARGET}
> +}
> +
> +INSANE_SKIP_${PN} = "arch"
> +
> +FILES_${PN} += "${base_libdir}/firmware/${TARGET}"
> -- 
> 1.9.1
> 
> -- 
> _______________________________________________
> meta-ti mailing list
> meta-ti@yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-ti