Re: [meta-oe][PATCH v4 2/2] mpv: Media Player

From: Martin Jansa <martin.jansa@gmail.com>
To: openembedded-devel@lists.openembedded.org
Cc: Gary Thomas <gary@mlbassoc.com>
Subject: Re: [meta-oe][PATCH v4 2/2] mpv: Media Player
Date: Wed, 25 May 2016 14:42:56 +0200	[thread overview]
Message-ID: <20160525124256.GA2568@jama> (raw)
In-Reply-To: <1464116871-38779-2-git-send-email-abdur_rehman@mentor.com>

[-- Attachment #1: Type: text/plain, Size: 3450 bytes --]

On Wed, May 25, 2016 at 12:07:51AM +0500, Abdur Rehman wrote:
> mpv is a fork of mplayer2 and MPlayer. It shares some features with
> the former projects while introducing many more.
> 
> Signed-off-by: Gary Thomas <gary@mlbassoc.com>
> Signed-off-by: Abdur Rehman <abdur_rehman@mentor.com>
> ---
>  meta-oe/recipes-multimedia/mplayer/mpv_0.15.0.bb | 69 ++++++++++++++++++++++++
>  1 file changed, 69 insertions(+)
>  create mode 100644 meta-oe/recipes-multimedia/mplayer/mpv_0.15.0.bb
> 
> diff --git a/meta-oe/recipes-multimedia/mplayer/mpv_0.15.0.bb b/meta-oe/recipes-multimedia/mplayer/mpv_0.15.0.bb
> new file mode 100644
> index 0000000..e5d5c53
> --- /dev/null
> +++ b/meta-oe/recipes-multimedia/mplayer/mpv_0.15.0.bb
> @@ -0,0 +1,69 @@
> +SUMMARY = "Open Source multimedia player"
> +SECTION = "multimedia"
> +HOMEPAGE = "http://www.mpv.io/"
> +DEPENDS = "zlib ffmpeg jpeg virtual/libx11 xsp libxv \
> +           libxscrnsaver libv4l libxinerama \
> +"
> +
> +REQUIRED_DISTRO_FEATURES = "x11"

You need to inherit distro_features_check for this to work.

> +LICENSE = "GPLv2+"
> +LIC_FILES_CHKSUM = "file://LICENSE;md5=91f1cb870c1cc2d31351a4d2595441cb"
> +
> +SRC_URI = "https://github.com/mpv-player/mpv/archive/v${PV}.tar.gz;name=mpv \
> +           http://www.freehackers.org/~tnagy/release/waf-1.8.12;name=waf \
> +"
> +SRC_URI[mpv.md5sum] = "9042bd3fbff2bc8ba0b7fadaa4a22101"
> +SRC_URI[mpv.sha256sum] = "7d31217ba8572f364fcea2955733f821374ae6d8c6d8f22f8bc63c44c0400bdc"
> +SRC_URI[waf.md5sum] = "cef4ee82206b1843db082d0b0506bf71"
> +SRC_URI[waf.sha256sum] = "01bf2beab2106d1558800c8709bc2c8e496d3da4a2ca343fe091f22fca60c98b"
> +
> +inherit pkgconfig pythonnative
> +
> +# Note: both lua and libass are required to get on-screen-display (controls)
> +PACKAGECONFIG ??= "lua libass"
> +PACKAGECONFIG[lua] = "--enable-lua,--disable-lua,lua luajit"
> +PACKAGECONFIG[libass] = "--enable-libass,--disable-libass,libass"
> +PACKAGECONFIG[libarchive] = "--enable-libarchive,--disable-libarchive,libarchive"
> +PACKAGECONFIG[jack] = "--enable-jack, --disable-jack, jack"
> +
> +EXTRA_OECONF = " \
> +    --prefix=${prefix} \
> +    --target=${SIMPLE_TARGET_SYS} \
> +    --confdir=${sysconfdir} \
> +    --datadir=${datadir} \
> +    --disable-manpage-build \
> +    --disable-gl \
> +    --disable-libsmbclient \
> +    --disable-encoding \
> +    --disable-libbluray \
> +    --disable-dvdread \
> +    --disable-dvdnav \
> +    --disable-cdda \
> +    --disable-enca \
> +    --disable-libguess \
> +    --disable-uchardet \
> +    --disable-rubberband \
> +    --disable-lcms2 \
> +    --disable-vapoursynth \
> +    --disable-vapoursynth-lazy \
> +"
> +
> +do_configure() {
> +    if [ ! -L ../waf ]; then
> +        chmod a+x ../waf-1.8.12
> +	ln -s waf-1.8.12 ../waf
> +    fi
> +    export SIMPLE_TARGET_SYS="$(echo ${TARGET_SYS} | sed s:${TARGET_VENDOR}::g)"
> +    ../waf configure ${EXTRA_OECONF}
> +}
> +
> +do_compile () {
> +    ../waf build
> +}
> +
> +do_install() {
> +    ../waf install --destdir=${D}
> +}
> +
> +FILES_${PN} += "${datadir}/icons"
> -- 
> 2.8.1
> 
> -- 
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel@lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa@gmail.com

[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 188 bytes --]