Re: [morty/master][PATCH 1/2] big-data-ipc-demo: Add ipc examples for big data buffer exchange

[Denys Dmytriyenko <denys@ti.com>]

Sam,

Is the use of "am57xx-evm" below too strict? That will exclude HS platforms 
and DRA7xx.


On Tue, Jun 20, 2017 at 01:45:48PM -0400, Sam Nelson wrote:
> Adds example with host running linux
> Demonstrates transfer of Big data buffers between A15 host and DSP core
> 
> Signed-off-by: Sam Nelson <sam.nelson@ti.com>
> ---
>  .../big-data-ipc-demo-linux_git.bb                 | 41 ++++++++++++++++++++++
>  .../big-data-ipc-demo/big-data-ipc-demo.inc        | 41 ++++++++++++++++++++++
>  2 files changed, 82 insertions(+)
>  create mode 100644 meta-arago-extras/recipes-apps/big-data-ipc-demo/big-data-ipc-demo-linux_git.bb
>  create mode 100644 meta-arago-extras/recipes-apps/big-data-ipc-demo/big-data-ipc-demo.inc
> 
> diff --git a/meta-arago-extras/recipes-apps/big-data-ipc-demo/big-data-ipc-demo-linux_git.bb b/meta-arago-extras/recipes-apps/big-data-ipc-demo/big-data-ipc-demo-linux_git.bb
> new file mode 100644
> index 0000000..0734177
> --- /dev/null
> +++ b/meta-arago-extras/recipes-apps/big-data-ipc-demo/big-data-ipc-demo-linux_git.bb
> @@ -0,0 +1,41 @@
> +SUMMARY = "TI Big data IPC: Host linux examples"
> +
> +require recipes-ti/includes/ti-paths.inc
> +require big-data-ipc-demo.inc
> +
> +DEPENDS = "ti-ipc \
> +           ti-xdctools \
> +           ti-sysbios \
> +           ti-ipc-rtos \
> +           cmem \
> +"
> +
> +EXTRA_OEMAKE = "\
> +    PLATFORM=${PLATFORM} \
> +    XDC_INSTALL_DIR="${XDC_INSTALL_DIR}" \
> +    BIOS_INSTALL_DIR="${SYSBIOS_INSTALL_DIR}" \
> +    IPC_INSTALL_DIR="${IPC_INSTALL_DIR}" \
> +    LINUX_SYSROOT_DIR="${STAGING_INCDIR}" \
> +    ${IPC_TARGETS} \
> +    JOBS="${PARALLEL_MAKE}" \
> +"
> +
> +do_create_srcipk_prepend() {
> +  rm -rf host_bios
> +}
> +
> +do_compile() {
> +  if [  "${PLATFORM}" != "UNKNOWN" ]; then
> +      oe_runmake host_linux
> +  fi
> +}
> +
> +do_install() {
> +  if [  "${PLATFORM}" != "UNKNOWN" ]; then
> +    oe_runmake EXEC_DIR="${D}${bindir}" install_linux_bin
> +  fi
> +}
> +
> +PACKAGES =+ "${PN}-firmware"
> +FILES_${PN}-firmware += "${bindir}/simple_buffer_example/release/server_dsp.xe66"
> +INSANE_SKIP_${PN}-firmware += "arch"
> diff --git a/meta-arago-extras/recipes-apps/big-data-ipc-demo/big-data-ipc-demo.inc b/meta-arago-extras/recipes-apps/big-data-ipc-demo/big-data-ipc-demo.inc
> new file mode 100644
> index 0000000..18b4cd8
> --- /dev/null
> +++ b/meta-arago-extras/recipes-apps/big-data-ipc-demo/big-data-ipc-demo.inc
> @@ -0,0 +1,41 @@
> +LICENSE = "BSD-3-Clause"
> +LIC_FILES_CHKSUM = "file://makefile;beginline=1;endline=31;md5=2f2ea348b98d5cc7807ece7adcc2c43a"
> +
> +COMPATIBLE_MACHINE = "am57xx-evm|keystone"
> +PACKAGE_ARCH = "${MACHINE_ARCH}"
> +
> +BIG_DATA_IPC_GIT_URI = "git://git.ti.com/processor-sdk/big-data-ipc-examples.git"
> +BIG_DATA_IPC_GIT_PROTOCOL = "git"
> +BIG_DATA_IPC_GIT_BRANCH = "master"
> +
> +# Below commit ID corresponds to "DEV.BIG_DATA_IPC.01.01.00.00"
> +BIG_DATA_IPC_SRCREV = "5907bff5a29fe2ba8719ae8c3c5d62b20b7b6bc9"
> +
> +BRANCH = "${BIG_DATA_IPC_GIT_BRANCH}"
> +SRC_URI = "${BIG_DATA_IPC_GIT_URI};protocol=${BIG_DATA_IPC_GIT_PROTOCOL};branch=${BRANCH}"
> +
> +SRCREV = "${BIG_DATA_IPC_SRCREV}"
> +PV = "01.01.00.00"
> +
> +require recipes-ti/includes/ti-staging.inc
> +
> +S = "${WORKDIR}/git"
> +
> +PLATFORM = "UNKNOWN"
> +PLATFORM_am57xx-evm = "DRA7XX"
> +PLATFORM_k2hk-evm = "TCI6636"
> +PLATFORM_k2l-evm = "TCI6630"
> +PLATFORM_k2e = "66AK2E"
> +PLATFORM_k2g = "66AK2G"
> +
> +IPC_TARGETS = ""
> +IPC_TARGETS_am57xx-evm = "\
> +    gnu.targets.arm.A15F="${GCC_ARM_NONE_TOOLCHAIN}" \
> +    ti.targets.elf.C66="${STAGING_DIR_NATIVE}/usr/share/ti/cgt-c6x" \
> +    ti.targets.arm.elf.M4="${M4_TOOLCHAIN_INSTALL_DIR}" \
> +"
> +
> +IPC_TARGETS_keystone = " \
> +    gnu.targets.arm.A15F="${GCC_ARM_NONE_TOOLCHAIN}" \
> +    ti.targets.elf.C66="${STAGING_DIR_NATIVE}/usr/share/ti/cgt-c6x" \
> +"
> -- 
> 1.9.1
> 
> _______________________________________________
> meta-arago mailing list
> meta-arago@arago-project.org
> http://arago-project.org/cgi-bin/mailman/listinfo/meta-arago