Re: [PATCH 2/3] ti-sgx-ddk-um: add k3 (AM654x) support

[Denys Dmytriyenko <denys@ti.com>]

Would be nice to see it as a diff (-C/-M), even though you add a new version.

BTW, have you tested these recipes?

-- 
Denys


On Mon, Jul 09, 2018 at 12:35:47PM -0400, Eric Ruei wrote:
> - add COMPATIBLE_MACHINE to distinguish AM3/4/5 with K3 (AM654x)
> - add k3 support based on SGX DDK 1.17
> 
> Signed-off-by: Eric Ruei <e-ruei1@ti.com>
> ---
>  .../libgles/ti-sgx-ddk-um_1.14.3699939.bb          |  2 +
>  .../libgles/ti-sgx-ddk-um_1.17.4948957.bb          | 84 ++++++++++++++++++++++
>  2 files changed, 86 insertions(+)
>  create mode 100644 recipes-graphics/libgles/ti-sgx-ddk-um_1.17.4948957.bb
> 
> diff --git a/recipes-graphics/libgles/ti-sgx-ddk-um_1.14.3699939.bb b/recipes-graphics/libgles/ti-sgx-ddk-um_1.14.3699939.bb
> index 282a4ab..354e081 100644
> --- a/recipes-graphics/libgles/ti-sgx-ddk-um_1.14.3699939.bb
> +++ b/recipes-graphics/libgles/ti-sgx-ddk-um_1.14.3699939.bb
> @@ -3,6 +3,8 @@ HOMEPAGE = "https://git.ti.com/graphics/omap5-sgx-ddk-um-linux"
>  LICENSE = "TI-TSPA"
>  LIC_FILES_CHKSUM = "file://TI-Linux-Graphics-DDK-UM-Manifest.doc;md5=550702a031857e0426ef7d6f6cf2d9f4"
>  
> +COMPATIBLE_MACHINE = "ti33x|ti43x|omap-a15"
> +
>  PACKAGE_ARCH = "${MACHINE_ARCH}"
>  
>  BRANCH = "ti-img-sgx/rocko/${PV}"
> diff --git a/recipes-graphics/libgles/ti-sgx-ddk-um_1.17.4948957.bb b/recipes-graphics/libgles/ti-sgx-ddk-um_1.17.4948957.bb
> new file mode 100644
> index 0000000..016709a
> --- /dev/null
> +++ b/recipes-graphics/libgles/ti-sgx-ddk-um_1.17.4948957.bb
> @@ -0,0 +1,84 @@
> +DESCRIPTION = "Userspace libraries for PowerVR SGX chipset on TI SoCs"
> +HOMEPAGE = "https://git.ti.com/graphics/omap5-sgx-ddk-um-linux"
> +LICENSE = "TI-TSPA"
> +LIC_FILES_CHKSUM = "file://TI-Linux-Graphics-DDK-UM-Manifest.doc;md5=b17390502bc89535c86cfbbae961a2a8"
> +
> +COMPATIBLE_MACHINE = "k3"
> +
> +PACKAGE_ARCH = "${MACHINE_ARCH}"
> +
> +BRANCH = "ti-img-sgx/rocko/${PV}"
> +
> +SRC_URI = "git://git.ti.com/graphics/omap5-sgx-ddk-um-linux.git;protocol=git;branch=${BRANCH}"
> +SRCREV = "a564d20ec1b6aed55b3e60aa9ff35f3809eca110"
> +
> +# There's only hardfp version available
> +python __anonymous() {
> +    tunes = d.getVar("TUNE_FEATURES", d, 1)
> +    if not tunes:
> +        return
> +    pkgn = d.getVar("PN", d, 1)
> +    pkgv = d.getVar("PV", d, 1)
> +    if "callconvention-hard" not in tunes:
> +        bb.warn("%s-%s ONLY supports hardfp mode for now" % (pkgn, pkgv))
> +        raise bb.parse.SkipPackage("%s-%s ONLY supports hardfp mode for now" % (pkgn, pkgv))
> +}
> +
> +TARGET_PRODUCT_k3 = "ti654x"
> +
> +
> +INITSCRIPT_NAME = "rc.pvr"
> +INITSCRIPT_PARAMS = "defaults 8"
> +
> +inherit update-rc.d
> +
> +PR = "r29"
> +PROVIDES += "virtual/egl virtual/libgles1 virtual/libgles2 omap5-sgx-ddk-um-linux"
> +
> +DEPENDS += "libdrm udev libgbm wayland libffi"
> +RDEPENDS_${PN} += "libdrm libudev libgbm wayland libffi libdrm-omap"
> +
> +RPROVIDES_${PN} = "libegl libgles1 libgles2 omap5-sgx-ddk-um-linux"
> +RPROVIDES_${PN}-dev = "libegl-dev libgles1-dev libgles2-dev omap5-sgx-ddk-um-linux-dev"
> +RPROVIDES_${PN}-dbg = "libegl-dbg libgles1-dbg libgles2-dbg omap5-sgx-ddk-um-linux-dbg"
> +
> +RREPLACES_${PN} = "libegl libgles1 libgles2 omap5-sgx-ddk-um-linux"
> +RREPLACES_${PN}-dev = "libegl-dev libgles1-dev libgles2-dev omap5-sgx-ddk-um-linux-dev"
> +RREPLACES_${PN}-dbg = "libegl-dbg libgles1-dbg libgles2-dbg omap5-sgx-ddk-um-linux-dbg"
> +
> +RCONFLICTS_${PN} = "libegl libgles1 libgles2 omap5-sgx-ddk-um-linux"
> +RCONFLICTS_${PN}-dev = "libegl-dev libgles1-dev libgles2-dev omap5-sgx-ddk-um-linux-dev"
> +RCONFLICTS_${PN}-dbg = "libegl-dbg libgles1-dbg libgles2-dbg omap5-sgx-ddk-um-linux-dbg"
> +
> +# The actual SONAME is libGLESv2.so.2, so need to explicitly specify RPROVIDES for .so.1 here
> +RPROVIDES_${PN} += "libGLESv2.so.1"
> +
> +S = "${WORKDIR}/git"
> +
> +do_install () {
> +    oe_runmake install DESTDIR=${D} TARGET_PRODUCT=${TARGET_PRODUCT}
> +    mkdir -p ${D}${libdir}/gbm
> +    ln -sf ../libpvrGBMWSEGL.so.${PV} ${D}${libdir}/gbm/gbm_pvr.so
> +    ln -sf libGLESv2.so.${PV} ${D}${libdir}/libGLESv2.so.1
> +    chown -R root:root ${D}
> +}
> +
> +FILES_${PN} =  "${bindir}/*"
> +FILES_${PN} += " ${libdir}/*"
> +FILES_${PN} +=  "${includedir}/*"
> +FILES_${PN} +=  "${sysconfdir}/*"
> +
> +PACKAGES =+ "${PN}-plugins"
> +FILES_${PN}-plugins = "${libdir}/libsrv_init.so ${libdir}/libsrv_um.so ${libdir}/libglslcompiler.so ${libdir}/libPVRScopeServices.so ${libdir}/libGLESv2.so ${libdir}/libGLES_CM.so ${libdir}/libpvrDRMWSEGL.so  ${libdir}/libpvrGBMWSEGL.so  ${libdir}/libpvrws_WAYLAND.so"
> +RDEPENDS_${PN} += "${PN}-plugins"
> +
> +ALLOW_EMPTY_${PN}-plugins = "1"
> +
> +INHIBIT_PACKAGE_STRIP = "1"
> +INHIBIT_SYSROOT_STRIP = "1"
> +
> +INSANE_SKIP_${PN} += "dev-so ldflags useless-rpaths"
> +INSANE_SKIP_${PN}-plugins = "dev-so"
> +INSANE_SKIP_${PN} += "already-stripped"
> +
> +CLEANBROKEN = "1"
> -- 
> 1.9.1
> 
> -- 
> _______________________________________________
> meta-ti mailing list
> meta-ti@yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-ti