[PATCH v2 1/2] support: add libmxml 3.3.1 recipe

["Clément Péron" <peron.clem@gmail.com>]

libmxml is required by new version of gator-daemon as it
has been removed from the package and is now an explicit
dependency.

This is a duplicate of the recipe present in meta-oe layer.

Signed-off-by: Clément Péron <peron.clem@gmail.com>
---
 .../recipes-support/libmxml/libmxml_3.3.1.bb  | 33 +++++++++++++++++++
 1 file changed, 33 insertions(+)
 create mode 100644 meta-arm/recipes-support/libmxml/libmxml_3.3.1.bb

diff --git a/meta-arm/recipes-support/libmxml/libmxml_3.3.1.bb b/meta-arm/recipes-support/libmxml/libmxml_3.3.1.bb
new file mode 100644
index 00000000..b81050b2
--- /dev/null
+++ b/meta-arm/recipes-support/libmxml/libmxml_3.3.1.bb
@@ -0,0 +1,33 @@
+DESCRIPTION = "Tiny XML Library"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=86d3f3a95c324c9479bd8986968f4327"
+HOMEPAGE = "https://www.msweet.org/mxml/"
+BUGTRACKER = "https://github.com/michaelrsweet/mxml/issues"
+
+SRC_URI = "git://github.com/michaelrsweet/mxml.git;nobranch=1;protocol=https"
+SRCREV = "fd47c7d115191c8a6bce2c781ffee41e179530f2"
+S = "${WORKDIR}/git"
+
+inherit autotools
+
+PACKAGECONFIG ??= "threads"
+PACKAGECONFIG[threads] = "--enable-threads,--disable-threads"
+
+# Package does not support out of tree builds.
+B = "${S}"
+
+# MXML uses autotools but it explicitly states it does not support autoheader.
+EXTRA_AUTORECONF = "--exclude=autopoint,autoheader"
+
+do_configure:prepend() {
+    # Respect optimization CFLAGS specified by OE.
+    sed -e 's/-Os -g//' -i ${S}/configure.ac
+
+    # Enable verbose compilation output. This is required for extra QA checks to work.
+    sed -e '/.SILENT:/d' -i ${S}/Makefile.in
+}
+
+do_install() {
+    # Package uses DSTROOT instread of standard DESTDIR to specify install location.
+    oe_runmake install DSTROOT=${D}
+}
-- 
2.40.0