[PATCH v3 1/3] hwdata: add recipe from meta-openembedded

[Hiago De Franco <hiagofranco@gmail.com>]

From: Hiago De Franco <hiago.franco@toradex.com>

Move hwdata recipe from meta-openembedded to openembedded-core.

libdisplay-info is now a requirement for Weston, since commit
a16598b038b2 ("backend-drm: make libdisplay-info mandatory"). However,
in order to build libdisplay-info, hwdata is required. Since Weston is
built inside openembedded-core, move hwdata in order to be able to
upgrade Weston, so oe-core has no dependency on meta-oe.

hwdata contains various hardware identification and configuration data.

Signed-off-by: Hiago De Franco <hiago.franco@toradex.com>
---
 meta/conf/distro/include/maintainers.inc    |  1 +
 meta/recipes-support/hwdata/hwdata_0.389.bb | 30 +++++++++++++++++++++
 2 files changed, 31 insertions(+)
 create mode 100644 meta/recipes-support/hwdata/hwdata_0.389.bb

diff --git a/meta/conf/distro/include/maintainers.inc b/meta/conf/distro/include/maintainers.inc
index d61b88f7de6c..04208ebbf22b 100644
--- a/meta/conf/distro/include/maintainers.inc
+++ b/meta/conf/distro/include/maintainers.inc
@@ -262,6 +262,7 @@ RECIPE_MAINTAINER:pn-harfbuzz = "Anuj Mittal <anuj.mittal@intel.com>"
 RECIPE_MAINTAINER:pn-hdparm = "Denys Dmytriyenko <denis@denix.org>"
 RECIPE_MAINTAINER:pn-help2man = "Hongxu Jia <hongxu.jia@windriver.com>"
 RECIPE_MAINTAINER:pn-hicolor-icon-theme = "Anuj Mittal <anuj.mittal@intel.com>"
+RECIPE_MAINTAINER:pn-hwdata = "Hiago De Franco <hiago.franco@toradex.com>"
 RECIPE_MAINTAINER:pn-hwlatdetect = "Alexander Kanavin <alex.kanavin@gmail.com>"
 RECIPE_MAINTAINER:pn-i2c-tools = "Anuj Mittal <anuj.mittal@intel.com>"
 RECIPE_MAINTAINER:pn-icecc-create-env = "Joshua Watt <JPEWhacker@gmail.com>"
diff --git a/meta/recipes-support/hwdata/hwdata_0.389.bb b/meta/recipes-support/hwdata/hwdata_0.389.bb
new file mode 100644
index 000000000000..8ab455cd2e99
--- /dev/null
+++ b/meta/recipes-support/hwdata/hwdata_0.389.bb
@@ -0,0 +1,30 @@
+SUMMARY = "Hardware identification and configuration data"
+DESCRIPTION = "hwdata contains various hardware identification and \
+configuration data, such as the pci.ids and usb.ids databases."
+HOMEPAGE = "https://github.com/vcrhonek/hwdata"
+SECTION = "System/Base"
+
+LICENSE = "GPL-2.0-or-later | XFree86-1.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=1556547711e8246992b999edd9445a57"
+
+SRC_URI = "git://github.com/vcrhonek/${BPN}.git;branch=master;protocol=https"
+SRCREV = "5313a12eb992a354c17fc895c1d69c8c42b09a06"
+
+S = "${WORKDIR}/git"
+
+inherit allarch
+
+do_configure() {
+    ${S}/configure --datadir=${datadir} --libdir=${libdir}
+}
+
+do_compile[noexec] = "1"
+
+do_install() {
+    oe_runmake install DESTDIR=${D}
+}
+
+FILES:${PN} = "${libdir}/* \
+               ${datadir}/* "
+
+BBCLASSEXTEND += "native"
-- 
2.39.5