Re: [meta-arago][master/scarthgap][PATCH] meta-arago-extras: Add recipe for NNShark

[Denys Dmytriyenko <denis@denix.org>]

On Tue, Mar 11, 2025 at 09:28:44PM +0530, Chirag Shilwant via lists.yoctoproject.org wrote:
> Hello Andrew,
> 
> On 11/03/25 20:07, Andrew Davis via lists.yoctoproject.org wrote:
> >Signed-off-by: Andrew Davis <afd@ti.com>
> >---
> >  .../recipes-multimedia/nnshark/nnshark_git.bb | 38 +++++++++++++++++++
> >  1 file changed, 38 insertions(+)
> >  create mode 100644 meta-arago-extras/recipes-multimedia/nnshark/nnshark_git.bb
> >
> >diff --git a/meta-arago-extras/recipes-multimedia/nnshark/nnshark_git.bb b/meta-arago-extras/recipes-multimedia/nnshark/nnshark_git.bb
> >new file mode 100644
> >index 00000000..1a3d8ad5
> >--- /dev/null
> >+++ b/meta-arago-extras/recipes-multimedia/nnshark/nnshark_git.bb
> >@@ -0,0 +1,38 @@
> >+SUMMARY = "A GStreamer NNstreamer pipelines real-time profiling plugin"
> 
> 
> nitpick, the below sounds much better?
> 
> SUMMARY = "A GStreamer plugin to support real-time performance
> profiling of NNStreamer pipelines."

This is 86+ characters long, which is too long for the SUMMARY (72 max). Also, 
no dots at the end of the SUMMARY, only in the DESCRIPTION, which happens 
automatically if not set explicitly.


> >+HOMEPAGE = "https://github.com/nnstreamer/nnshark"
> >+
> >+LICENSE = "GPL-2.0-only & LGPL-2.1-only"
> >+LIC_FILES_CHKSUM = "file://COPYING;md5=e1caa368743492879002ad032445fa97 \
> >+                    file://COPYING.LESSER;md5=66c40c88533cd228b5b85936709801c8"
> >+
> >+SRC_URI = "git://github.com/nnstreamer/nnshark.git;protocol=https;branch=master;name=nnshark \
> >+           git://github.com/GStreamer/common.git;protocol=https;branch=master;name=common;subdir=${S}/common \
> >+"
> 
> any specific reasons to not go with something like below,
> 
> SRC_URI = "gitsm://github.com/nnstreamer/nnshark.git;protocol=https;branch=master
> \
> "
> 
> SRCREV = "bcee91b23a98c981b87051fe1b2ad545991c4aa2"

Unless you want to control each SRCREV separately.


> >+SRCREV_FORMAT="default"
> >+SRCREV_nnshark="bcee91b23a98c981b87051fe1b2ad545991c4aa2"
> >+SRCREV_common="b64f03f6090245624608beb5d2fff335e23a01c0"
> >+
> >+S = "${WORKDIR}/git"
> 
> probably master might need a separate patch for UNPACKDIR stuff?

No changes for git based recipes needed.


> >+
> >+DEPENDS = "\
> >+    gtk-doc-native \
> >+    gstreamer1.0 \
> >+    gstreamer1.0-plugins-base \
> >+"
> >+
> >+inherit pkgconfig autotools-brokensep
> >+
> >+EXTRA_OECONF = " \
> >+        --disable-graphviz \
> >+        --disable-gtk-doc \
> >+"
> >+
> >+do_configure:prepend() {
> >+    sh autogen.sh --noconfigure
> >+}
> >+
> >+FILES:${PN} += "\
> >+       ${libdir}/gstreamer-1.0/libgstsharktracers.so \
> >+       ${libdir}/gstreamer-1.0/libgstsharktracers.la \
> >+"