Re: [meta-arago][master][PATCH] mesa-demos: Update recipe to match oe-core

[Denys Dmytriyenko <denis@denix.org>]

On Wed, Sep 30, 2026 at 05:22:41PM -0500, Ryan Eatmon via lists.yoctoproject.org wrote:
> oe-core has moved the version of mesa-demos beyond the SRCREV that we
> were pointing to in our mesa-demos_get.bb recipe.  We can safely remove
> our recipe in favor of the oe-core version... except there is one change
> in our recipe that is needed that oe-core does not have.  Removing "x11"
> as a REQUIRED_DISTRO_FEATURES.
> 
> We are working on a patch to oe-core to fix this, in the meantime we can
> carry a simple bbappend to correctly adjust this.
> 
> Signed-off-by: Ryan Eatmon <reatmon@ti.com>
> ---
>  .../mesa/mesa-demos-arago.inc                 |  1 +
>  .../mesa/mesa-demos_%.bbappend                |  4 ++
>  .../recipes-graphics/mesa/mesa-demos_git.bb   | 41 -------------------
>  3 files changed, 5 insertions(+), 41 deletions(-)
>  create mode 100644 meta-arago-distro/recipes-graphics/mesa/mesa-demos-arago.inc
>  create mode 100644 meta-arago-distro/recipes-graphics/mesa/mesa-demos_%.bbappend
>  delete mode 100644 meta-arago-distro/recipes-graphics/mesa/mesa-demos_git.bb
> 
> diff --git a/meta-arago-distro/recipes-graphics/mesa/mesa-demos-arago.inc b/meta-arago-distro/recipes-graphics/mesa/mesa-demos-arago.inc
> new file mode 100644
> index 00000000..ff3f2992
> --- /dev/null
> +++ b/meta-arago-distro/recipes-graphics/mesa/mesa-demos-arago.inc
> @@ -0,0 +1 @@
> +REQUIRED_DISTRO_FEATURES:remove = "x11"
> diff --git a/meta-arago-distro/recipes-graphics/mesa/mesa-demos_%.bbappend b/meta-arago-distro/recipes-graphics/mesa/mesa-demos_%.bbappend
> new file mode 100644
> index 00000000..3b26e342
> --- /dev/null
> +++ b/meta-arago-distro/recipes-graphics/mesa/mesa-demos_%.bbappend
> @@ -0,0 +1,4 @@
> +MESA_DEMOS_ARAGO = ""
> +MESA_DEMOS_ARAGO:arago = "mesa-demos-arago.inc"

For a one-liner like this, I'd suggest doing it directly in the arago.conf, 
instead of a distro-guarded .bbappend:

REQUIRED_DISTRO_FEATURES:remove:pn-mesa-demos = "x11"

Similar to how we do this for different PACKAGECONFIGs...

It seems cleaner and is already distro-guarded.


> +
> +require ${MESA_DEMOS_ARAGO}
> diff --git a/meta-arago-distro/recipes-graphics/mesa/mesa-demos_git.bb b/meta-arago-distro/recipes-graphics/mesa/mesa-demos_git.bb
> deleted file mode 100644
> index 8dab581b..00000000
> --- a/meta-arago-distro/recipes-graphics/mesa/mesa-demos_git.bb
> +++ /dev/null
> @@ -1,41 +0,0 @@
> -SUMMARY = "Mesa demo applications"
> -DESCRIPTION = "This package includes the demonstration application, such as glxgears. \
> -These applications can be used for Mesa validation and benchmarking."
> -HOMEPAGE = "http://mesa3d.org"
> -BUGTRACKER = "https://bugs.freedesktop.org"
> -
> -LICENSE = "MIT AND LicenseRef-PD"
> -LIC_FILES_CHKSUM = "file://src/xdemos/glxgears.c;beginline=1;endline=20;md5=a481fbdb2ac800ecb12405c33bcfacae \
> -                    file://src/xdemos/glxdemo.c;beginline=1;endline=8;md5=b01d5ab1aee94d35b7efaa2ef48e1a06"
> -
> -SRC_URI = "git://gitlab.freedesktop.org/mesa/demos.git;protocol=https;branch=main"
> -SRCREV = "02eae079cb0b8186064d5b194ca4cc2995f099ee"
> -
> -PV = "9.0.0+git"
> -
> -inherit meson pkgconfig features_check
> -REQUIRED_DISTRO_FEATURES = "opengl"
> -
> -EXTRA_OEMESON = "-Dwith-system-data-files=true"
> -
> -PACKAGECONFIG ?= "drm egl gles1 gles2 \
> -                  ${@bb.utils.filter('DISTRO_FEATURES', 'vulkan x11 wayland', d)}"
> -
> -PACKAGECONFIG[drm] = "-Dlibdrm=enabled,-Dlibdrm=disabled,libdrm"
> -PACKAGECONFIG[egl] = "-Degl=enabled,-Degl=disabled,virtual/egl"
> -PACKAGECONFIG[gles1] = "-Dgles1=enabled,-Dgles1=disabled,virtual/libgles1"
> -PACKAGECONFIG[gles2] = "-Dgles2=enabled,-Dgles2=disabled,virtual/libgles2"
> -PACKAGECONFIG[glut] = "-Dwith-glut=${STAGING_EXECPREFIXDIR},-Dglut=disabled,freeglut"
> -PACKAGECONFIG[osmesa] = "-Dosmesa=enabled,-Dosmesa=disabled,"
> -PACKAGECONFIG[vulkan] = "-Dvulkan=enabled,-Dvulkan=disabled,vulkan-loader glslang-native"
> -PACKAGECONFIG[wayland] = "-Dwayland=enabled,-Dwayland=disabled,virtual/libgl wayland wayland-native wayland-protocols libxkbcommon libdecor"
> -PACKAGECONFIG[x11] = "-Dx11=enabled,-Dx11=disabled,virtual/libx11 libglu libxkbcommon libxcb"
> -
> -do_install:append() {
> -	# it can be completely empty when all PACKAGECONFIG options are disabled
> -	rmdir --ignore-fail-on-non-empty ${D}${bindir}
> -
> -	if [ -f ${D}${bindir}/clear ]; then
> -		mv ${D}${bindir}/clear ${D}${bindir}/clear.mesa-demos
> -	fi
> -}
> -- 
> 2.43.0