Re: [meta-raspberrypi][PATCH] linux-raspberrypi: Add version 3.8.13

[Philipp Wagner <lists@philipp-wagner.com>]

Hi,

a general question to start: 3.11.0 is out now as well (and it works, at
least in my tests), should we add that as well?

Am 03.09.2013 14:26, Paul Barker wrote:
> Upstream commit d996a1b91b2bf3dc06f4f4f822a56f4496457aa1, dated 2013-08-07.
> 
> Signed-off-by: Paul Barker <paul@paulbarker.me.uk>
> ---
>  recipes-kernel/linux/linux-raspberrypi_3.8.13.bb | 35 ++++++++++++++++++++++++
>  1 file changed, 35 insertions(+)
>  create mode 100644 recipes-kernel/linux/linux-raspberrypi_3.8.13.bb
> 
> diff --git a/recipes-kernel/linux/linux-raspberrypi_3.8.13.bb b/recipes-kernel/linux/linux-raspberrypi_3.8.13.bb
> new file mode 100644
> index 0000000..b482939
> --- /dev/null
> +++ b/recipes-kernel/linux/linux-raspberrypi_3.8.13.bb
> @@ -0,0 +1,35 @@
> +require linux.inc
> +
> +DESCRIPTION = "Linux kernel for the RaspberryPi board"
> +COMPATIBLE_MACHINE = "raspberrypi"
> +
> +PR = "r6"

I guess this does not matter, but would r1 not be more natural?

> +PV_append = "+git${SRCREV}"
> +
> +SRCREV = "d996a1b91b2bf3dc06f4f4f822a56f4496457aa1"
> +SRC_URI = "git://github.com/raspberrypi/linux.git;protocol=git;branch=rpi-3.8.y \
> +           file://sl030raspberrypii2ckernel.patch \
> +          "
> +S = "${WORKDIR}/git"
> +
> +# NOTE: For now we pull in the default config from the RPi kernel GIT tree.
> +KERNEL_DEFCONFIG = "bcmrpi_defconfig"
> +
> +# CMDLINE for raspberrypi
> +CMDLINE_raspberrypi = "dwc_otg.lpm_enable=0 console=ttyAMA0,115200 kgdboc=ttyAMA0,115200 root=/dev/mmcblk0p2 rootfstype=ext4 rootwait"
> +
> +UDEV_GE_141 ?= "1"

This is already part of linux.inc, is it necessary here again?

> +
> +do_configure_prepend() {
> +	install -m 0644 ${S}/arch/${ARCH}/configs/${KERNEL_DEFCONFIG} ${WORKDIR}/defconfig || die "No default configuration for ${MACHINE} / ${KERNEL_DEFCONFIG} available."
> +}
> +
> +do_install_prepend() {
> +	install -d ${D}/lib/firmware
> +}
> +
> +do_deploy_append() {
> +	# Deploy cmdline.txt
> +	install -d ${DEPLOYDIR}/bcm2835-bootfiles
> +	echo "${CMDLINE}" > ${DEPLOYDIR}/bcm2835-bootfiles/cmdline.txt
> +}
>