Re: [PATCH 3/8] docbook-xml: add docbook-xml-dtd4

[Hongxu Jia <hongxu.jia@windriver.com>]

On 07/08/2014 05:47 PM, Hongxu Jia wrote:

> diff --git a/meta/recipes-devtools/docbook-xml/docbook-xml-dtd4_4.5.bb b/meta/recipes-devtools/docbook-xml/docbook-xml-dtd4_4.5.bb
> new file mode 100644
> index 0000000..3b20391
> --- /dev/null
> +++ b/meta/recipes-devtools/docbook-xml/docbook-xml-dtd4_4.5.bb
> @@ -0,0 +1,75 @@
> +# The DTDs of the various versions have to be installed in parallel and
> +# should not replace each other. The installation step is common for
> +# all versions and just differs in ${DTD_VERSION} which is set in each
> +# version recipe.
> +#
> +# The DTDs do have some quirks (see LFS documentation).
> +SUMMARY = "Document type definitions for verification of XML data files"
> +DESCRIPTION = "Document type definitions for verification of XML data \
> +files against the DocBook rule set, it ships with the latest DocBook 4.5 \
> +XML DTD, as well as a selected set of legacy DTDs for use with older \
> +documents, including 4.0, 4.1.2, 4.2, 4.3 and 4.4"
> +HOMEPAGE = "http://www.docbook.org/xml/"
> +
> +LICENSE = "OASIS"
> +LIC_FILES_CHKSUM = "file://${WORKDIR}/LICENSE-OASIS;md5=c608985dd5f7f215e669e7639a0b1d2e"
> +
> +# Note: the upstream sources are not distributed with a license file.
> +# LICENSE-OASIS is included as a "patch" to workaround this. When
> +# upgrading this recipe, please verify whether this is still needed.
> +SRC_URI = "${DEBIAN_MIRROR}/main/d/docbook-xml/docbook-xml_${PV}.orig.tar.gz \
> +           file://LICENSE-OASIS \
> +           file://docbook-xml-update-catalog.xml.patch \
> +           file://docbook-xml.xml \
> +"
> +
> +SRC_URI[md5sum] = "487b4d44e15cffb1f4048af23f98208e"
> +SRC_URI[sha256sum] = "b0f8edcf697f5318e63dd98c9a931f3fee167af0805ba441db372e0f17b2a44f"
> +
> +S="${WORKDIR}/docbook-xml-4.5.c31424"
> +
> +inherit allarch
> +BBCLASSEXTEND = "native"
> +
> +SSTATEPOSTINSTFUNCS_append_class-native = " docbook_xml_dtd_sstate_postinst"
> +SYSROOT_PREPROCESS_FUNCS_append_class-native = " docbook_xml_dtd_sysroot_preprocess"
> +
> +do_configre (){
> +  :
> +}
> +
> +do_compile (){
> +  :
> +}
> +
> +do_install () {
> +    # Refer debian https://packages.debian.org/sid/all/docbook-xml/filelist
> +    for DTDVERSION in 4.0 4.1.2 4.2 4.3 4.4 4.5; do
> +        install -d -m 755 ${D}${datadir}/xml/docbook/schema/dtd/${DTDVERSION}
> +        cp -v -R docbook-${DTDVERSION}/* ${D}${datadir}/xml/docbook/schema/dtd/${DTDVERSION}
> +    done
> +
> +    install -d ${D}${sysconfdir}/xml/
> +    install -m 755  ${WORKDIR}/docbook-xml.xml ${D}${sysconfdir}/xml/docbook-xml.xml
> +}
> +
> +do_install_append_class-nativesdk () {
> +    # Update the hardcode dir in docbook-xml.xml
> +    sed -i -e "s|file:///usr/share/xml|file://${datadir}/xml|g" ${D}${sysconfdir}/xml/docbook-xml.xml
> +}

Remove the nativesdk do_install_append_class-nativesd, we don't support 
nativesdk.

I update the git tree directly, no v2 will be sent.

//Hongxu

> +
> +docbook_xml_dtd_sstate_postinst () {
> +    if [ "${BB_CURRENTTASK}" = "populate_sysroot" -o "${BB_CURRENTTASK}" = "populate_sysroot_setscene" ]
> +    then
> +        # Ensure that the catalog file sgml-docbook.cat is properly
> +        # updated when the package is installed from sstate cache.
> +        sed -i -e "s|file://.*/usr/share/xml|file://${datadir}/xml|g" ${SYSROOT_DESTDIR}${sysconfdir}/xml/docbook-xml.xml
> +    fi
> +}
> +
> +docbook_xml_dtd_sysroot_preprocess () {
> +    # Update the hardcode dir in docbook-xml.xml
> +    sed -i -e "s|file:///usr/share/xml|file://${datadir}/xml|g" ${SYSROOT_DESTDIR}${sysconfdir}/xml/docbook-xml.xml
> +}
> +
> +FILES_${PN} = "${datadir}/* ${sysconfdir}/xml/docbook-xml.xml"