* [meta-oe][PATCH v1 1/3] libiconv: drop EXTRA_OECONF as it is handled by gettext class
@ 2011-05-15 21:45 Otavio Salvador
2011-05-15 21:45 ` [meta-oe][PATCH v1 2/3] libpcsclite: add version 1.7.2 Otavio Salvador
` (2 more replies)
0 siblings, 3 replies; 6+ messages in thread
From: Otavio Salvador @ 2011-05-15 21:45 UTC (permalink / raw)
To: openembedded-devel; +Cc: Otavio Salvador
Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>
---
.../recipes-support/libiconv/libiconv_1.13.1.bb | 4 +---
1 files changed, 1 insertions(+), 3 deletions(-)
diff --git a/meta-oe/recipes-support/libiconv/libiconv_1.13.1.bb b/meta-oe/recipes-support/libiconv/libiconv_1.13.1.bb
index 868314b..35f4e2d 100644
--- a/meta-oe/recipes-support/libiconv/libiconv_1.13.1.bb
+++ b/meta-oe/recipes-support/libiconv/libiconv_1.13.1.bb
@@ -8,9 +8,7 @@ LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504 \
BBCLASSEXTEND = "native nativesdk"
PROVIDES = "virtual/libiconv"
-PR = "r2"
-
-EXTRA_OECONF += "${@['--disable-nls','--enable-nls'][bb.data.getVar('USE_NLS', d, 1) == 'yes']}"
+PR = "r3"
SRC_URI += "file://autoconf.patch"
--
1.7.2.5
^ permalink raw reply related [flat|nested] 6+ messages in thread
* [meta-oe][PATCH v1 2/3] libpcsclite: add version 1.7.2
2011-05-15 21:45 [meta-oe][PATCH v1 1/3] libiconv: drop EXTRA_OECONF as it is handled by gettext class Otavio Salvador
@ 2011-05-15 21:45 ` Otavio Salvador
2011-05-16 7:15 ` Koen Kooi
2011-05-15 21:45 ` [meta-oe][PATCH v1 3/3] freerdp: update to 2011-05-14 snapshot Otavio Salvador
2011-05-16 7:06 ` [meta-oe][PATCH v1 1/3] libiconv: drop EXTRA_OECONF as it is handled by gettext class Koen Kooi
2 siblings, 1 reply; 6+ messages in thread
From: Otavio Salvador @ 2011-05-15 21:45 UTC (permalink / raw)
To: openembedded-devel; +Cc: Otavio Salvador
The recipe name libpcsclite has been choosen since this is the most
important and used part of the project. The daemon itself is optional
and not always required to be installed.
Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>
---
meta-oe/recipes-support/pcsc-lite/files/pcscd.init | 32 +++++++++++++++++
.../recipes-support/pcsc-lite/libpcsclite_1.7.2.bb | 36 ++++++++++++++++++++
2 files changed, 68 insertions(+), 0 deletions(-)
create mode 100644 meta-oe/recipes-support/pcsc-lite/files/pcscd.init
create mode 100644 meta-oe/recipes-support/pcsc-lite/libpcsclite_1.7.2.bb
diff --git a/meta-oe/recipes-support/pcsc-lite/files/pcscd.init b/meta-oe/recipes-support/pcsc-lite/files/pcscd.init
new file mode 100644
index 0000000..92385ab
--- /dev/null
+++ b/meta-oe/recipes-support/pcsc-lite/files/pcscd.init
@@ -0,0 +1,32 @@
+#!/bin/sh
+DAEMON=/usr/sbin/pcscd
+NAME=pcscd
+DESC="PCSC Daemon"
+PIDFILE=/var/run/pcscd/pcscd.pid
+ARGS=""
+
+test -f $DAEMON || exit 0
+
+case "$1" in
+ start)
+ echo -n "Starting $DESC: $NAME"
+ start-stop-daemon --start --quiet --pidfile $PIDFILE --exec $DAEMON -- $ARGS
+ echo "."
+ ;;
+ stop)
+ echo -n "Stopping $DESC: $NAME"
+ start-stop-daemon --stop --quiet --pidfile $PIDFILE --exec $DAEMON
+ echo "."
+ ;;
+ restart)
+ $0 stop
+ sleep 1
+ $0 start
+ ;;
+ *)
+ echo "Usage: $0 {start|stop|restart}"
+ exit 1
+ ;;
+esac
+
+exit 0
diff --git a/meta-oe/recipes-support/pcsc-lite/libpcsclite_1.7.2.bb b/meta-oe/recipes-support/pcsc-lite/libpcsclite_1.7.2.bb
new file mode 100644
index 0000000..6326152
--- /dev/null
+++ b/meta-oe/recipes-support/pcsc-lite/libpcsclite_1.7.2.bb
@@ -0,0 +1,36 @@
+DESCRIPTION = "PC/SC Lite smart card framework and applications"
+HOMEPAGE = "http://pcsclite.alioth.debian.org/"
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://COPYING;md5=c8e551349dc346258274f0007679e149"
+DEPENDS = "udev"
+PR = "r0"
+
+SRC_URI = "https://alioth.debian.org/frs/download.php/3533/pcsc-lite-${PV}.tar.bz2 \
+ file://pcscd.init "
+
+SRC_URI[md5sum] = "47e7055cfc14399fdaa1b7a4aa06e5aa"
+SRC_URI[sha256sum] = "41f13d552eaa2c3978fbb6f2125e81903a0767011d999052fd1a6ee03880b398"
+
+inherit autotools update-rc.d
+
+INITSCRIPT_PACKAGES = "pcscd"
+INITSCRIPT_NAME_pcscd = "pcscd"
+INITSCRIPT_PARAMS_pcscd = "defaults"
+
+EXTRA_OECONF = " \
+ --enable-libusb \
+ --disable-libudev \
+ --enable-usbdropdir=${libdir}/pcsc/drivers \
+ "
+
+S = "${WORKDIR}/pcsc-lite-${PV}"
+
+do_install() {
+ oe_runmake DESTDIR="${D}" install
+ install -d "${D}/etc/init.d"
+ install -m 755 "${WORKDIR}/pcscd.init" "${D}/etc/init.d/pcscd"
+}
+
+PACKAGES =+ "pcscd"
+
+FILES_pcscd = "${bindir}/pscsd ${sysconfdir}/init.d"
--
1.7.2.5
^ permalink raw reply related [flat|nested] 6+ messages in thread
* [meta-oe][PATCH v1 3/3] freerdp: update to 2011-05-14 snapshot
2011-05-15 21:45 [meta-oe][PATCH v1 1/3] libiconv: drop EXTRA_OECONF as it is handled by gettext class Otavio Salvador
2011-05-15 21:45 ` [meta-oe][PATCH v1 2/3] libpcsclite: add version 1.7.2 Otavio Salvador
@ 2011-05-15 21:45 ` Otavio Salvador
2011-05-16 7:06 ` [meta-oe][PATCH v1 1/3] libiconv: drop EXTRA_OECONF as it is handled by gettext class Koen Kooi
2 siblings, 0 replies; 6+ messages in thread
From: Otavio Salvador @ 2011-05-15 21:45 UTC (permalink / raw)
To: openembedded-devel; +Cc: Otavio Salvador
This version includes major improvements since last version
packages. It also had the plugins packages redone so they can be
choosen depending on the environment needs.
Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>
---
meta-oe/recipes-support/freerdp/freerdp.inc | 40 +++++++++++++++++++----
meta-oe/recipes-support/freerdp/freerdp_git.bb | 4 +-
2 files changed, 35 insertions(+), 9 deletions(-)
diff --git a/meta-oe/recipes-support/freerdp/freerdp.inc b/meta-oe/recipes-support/freerdp/freerdp.inc
index f8402c7..15ceadd 100644
--- a/meta-oe/recipes-support/freerdp/freerdp.inc
+++ b/meta-oe/recipes-support/freerdp/freerdp.inc
@@ -3,22 +3,48 @@
DESCRIPTION = "FreeRDP RDP client"
HOMEPAGE = "http://freerdp.sourceforge.net"
-DEPENDS = "virtual/libx11 openssl libxcursor cups alsa-lib"
+DEPENDS = "virtual/libx11 openssl libxcursor libxv cups alsa-lib pulseaudio libpcsclite"
SECTION = "x11/network"
LICENSE = "Apache-2.0"
LIC_FILES_CHKSUM = "file://LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57"
-INC_PR = "r0"
+INC_PR = "r1"
inherit pkgconfig autotools
-do_configure_prepend() {
- # workaround gcc linking bug
- find ${S} -name 'Makefile.am' | xargs -n 1 sed 's,-pthread,-lpthread -D_REENTRANT,g' -i
-}
+EXTRA_OECONF += "--with-smartcard --with-xvideo"
do_install_append() {
rm ${D}${libdir}/freerdp/*.a ${D}${libdir}/freerdp/*.la
}
-RDEPENDS_${PN} += "xprop"
+PACKAGES =+ "libfreerdp"
+
+LEAD_SONAME = "libfreerdp.so"
+FILES_libfreerdp = "${libdir}/lib*${SOLIBS}"
+
+PACKAGES_DYNAMIC = "libfreerdp-plugin-*"
+
+python populate_packages_prepend () {
+ freerdp_root = bb.data.expand('${libdir}/freerdp', d)
+
+ do_split_packages(d, freerdp_root, '^(audin_.*)\.so$',
+ output_pattern='libfreerdp-plugin-%s',
+ description='FreeRDP plugin %s',
+ prepend=True, extra_depends='libfreerdp-plugin-audin')
+
+ do_split_packages(d, freerdp_root, '^(rdpsnd_.*)\.so$',
+ output_pattern='libfreerdp-plugin-%s',
+ description='FreeRDP plugin %s',
+ prepend=True, extra_depends='libfreerdp-plugin-rdpsnd')
+
+ do_split_packages(d, freerdp_root, '^(tsmf_.*)\.so$',
+ output_pattern='libfreerdp-plugin-%s',
+ description='FreeRDP plugin %s',
+ prepend=True, extra_depends='libfreerdp-plugin-tsmf')
+
+ do_split_packages(d, freerdp_root, '^([^-]*)\.so$',
+ output_pattern='libfreerdp-plugin-%s',
+ description='FreeRDP plugin %s',
+ prepend=True, extra_depends='')
+}
diff --git a/meta-oe/recipes-support/freerdp/freerdp_git.bb b/meta-oe/recipes-support/freerdp/freerdp_git.bb
index fa4ba9a..5bdb0af 100644
--- a/meta-oe/recipes-support/freerdp/freerdp_git.bb
+++ b/meta-oe/recipes-support/freerdp/freerdp_git.bb
@@ -7,9 +7,9 @@ inherit gitpkgv
PV = "gitr${SRCPV}"
PKGV = "${GITPKGVTAG}"
-PR = "${INC_PR}.0"
+PR = "${INC_PR}.1"
-SRCREV = "7bbde4fb3bc3a781364d0a626c49bc165cc507fd"
+SRCREV = "18e9d76c1936b6efc4ab6d91d127be20173ec903"
SRC_URI = "git://github.com/FreeRDP/FreeRDP.git;protocol=git"
S = "${WORKDIR}/git"
--
1.7.2.5
^ permalink raw reply related [flat|nested] 6+ messages in thread
* Re: [meta-oe][PATCH v1 1/3] libiconv: drop EXTRA_OECONF as it is handled by gettext class
2011-05-15 21:45 [meta-oe][PATCH v1 1/3] libiconv: drop EXTRA_OECONF as it is handled by gettext class Otavio Salvador
2011-05-15 21:45 ` [meta-oe][PATCH v1 2/3] libpcsclite: add version 1.7.2 Otavio Salvador
2011-05-15 21:45 ` [meta-oe][PATCH v1 3/3] freerdp: update to 2011-05-14 snapshot Otavio Salvador
@ 2011-05-16 7:06 ` Koen Kooi
2 siblings, 0 replies; 6+ messages in thread
From: Koen Kooi @ 2011-05-16 7:06 UTC (permalink / raw)
To: openembedded-devel
-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1
On 15-05-11 23:45, Otavio Salvador wrote:
> Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>
Applied, thanks
> ---
> .../recipes-support/libiconv/libiconv_1.13.1.bb | 4 +---
> 1 files changed, 1 insertions(+), 3 deletions(-)
>
> diff --git a/meta-oe/recipes-support/libiconv/libiconv_1.13.1.bb b/meta-oe/recipes-support/libiconv/libiconv_1.13.1.bb
> index 868314b..35f4e2d 100644
> --- a/meta-oe/recipes-support/libiconv/libiconv_1.13.1.bb
> +++ b/meta-oe/recipes-support/libiconv/libiconv_1.13.1.bb
> @@ -8,9 +8,7 @@ LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504 \
> BBCLASSEXTEND = "native nativesdk"
>
> PROVIDES = "virtual/libiconv"
> -PR = "r2"
> -
> -EXTRA_OECONF += "${@['--disable-nls','--enable-nls'][bb.data.getVar('USE_NLS', d, 1) == 'yes']}"
> +PR = "r3"
>
> SRC_URI += "file://autoconf.patch"
>
-----BEGIN PGP SIGNATURE-----
Version: GnuPG v1.4.5 (Darwin)
iD8DBQFN0M0TMkyGM64RGpERAhakAJ0TcMMQGhMJwVr2N85Ji9g9pLT3uACfWpZY
flqGMSqF2HjX9RgJ8wjV4ik=
=WuEb
-----END PGP SIGNATURE-----
^ permalink raw reply [flat|nested] 6+ messages in thread
* Re: [meta-oe][PATCH v1 2/3] libpcsclite: add version 1.7.2
2011-05-15 21:45 ` [meta-oe][PATCH v1 2/3] libpcsclite: add version 1.7.2 Otavio Salvador
@ 2011-05-16 7:15 ` Koen Kooi
2011-05-16 12:02 ` Otavio Salvador
0 siblings, 1 reply; 6+ messages in thread
From: Koen Kooi @ 2011-05-16 7:15 UTC (permalink / raw)
To: openembedded-devel
-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1
On 15-05-11 23:45, Otavio Salvador wrote:
> The recipe name libpcsclite has been choosen since this is the most
> important and used part of the project. The daemon itself is optional
> and not always required to be installed.
Wouldn't debian.bbclass already take care of such renaming with proper
packaging?
> +++ b/meta-oe/recipes-support/pcsc-lite/libpcsclite_1.7.2.bb
> +INITSCRIPT_PACKAGES = "pcscd"
> +INITSCRIPT_NAME_pcscd = "pcscd"
> +INITSCRIPT_PARAMS_pcscd = "defaults"
These should go near the other _pscsd entries
> +
> +EXTRA_OECONF = " \
> + --enable-libusb \
> + --disable-libudev \
Please add the proper libusb to DEPENDS and a comment why udev is in
DEPENDS, but disabled
-----BEGIN PGP SIGNATURE-----
Version: GnuPG v1.4.5 (Darwin)
iD8DBQFN0M8GMkyGM64RGpERAsJXAJ9aFHqXmtSGZ2rDgvTSnu+5DAPK/wCeNonq
weHpoQIB5GTXDvMvOjT4d/w=
=rHle
-----END PGP SIGNATURE-----
^ permalink raw reply [flat|nested] 6+ messages in thread
* Re: [meta-oe][PATCH v1 2/3] libpcsclite: add version 1.7.2
2011-05-16 7:15 ` Koen Kooi
@ 2011-05-16 12:02 ` Otavio Salvador
0 siblings, 0 replies; 6+ messages in thread
From: Otavio Salvador @ 2011-05-16 12:02 UTC (permalink / raw)
To: openembedded-devel
On Mon, May 16, 2011 at 04:15, Koen Kooi <koen@dominion.thruhere.net> wrote:
> -----BEGIN PGP SIGNED MESSAGE-----
> Hash: SHA1
>
> On 15-05-11 23:45, Otavio Salvador wrote:
>> The recipe name libpcsclite has been choosen since this is the most
>> important and used part of the project. The daemon itself is optional
>> and not always required to be installed.
>
> Wouldn't debian.bbclass already take care of such renaming with proper
> packaging?
It does for soname but not for -dev and -doc that is mostly related to
the library, not the daemon.
>> +++ b/meta-oe/recipes-support/pcsc-lite/libpcsclite_1.7.2.bb
>
>> +INITSCRIPT_PACKAGES = "pcscd"
>> +INITSCRIPT_NAME_pcscd = "pcscd"
>> +INITSCRIPT_PARAMS_pcscd = "defaults"
>
> These should go near the other _pscsd entries
>
>> +
>> +EXTRA_OECONF = " \
>> + --enable-libusb \
>> + --disable-libudev \
>
> Please add the proper libusb to DEPENDS and a comment why udev is in
> DEPENDS, but disabled
Fixed. Will post it again.
--
Otavio Salvador O.S. Systems
E-mail: otavio@ossystems.com.br http://www.ossystems.com.br
Mobile: +55 53 9981-7854 http://projetos.ossystems.com.br
^ permalink raw reply [flat|nested] 6+ messages in thread
end of thread, other threads:[~2011-05-16 12:05 UTC | newest]
Thread overview: 6+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-05-15 21:45 [meta-oe][PATCH v1 1/3] libiconv: drop EXTRA_OECONF as it is handled by gettext class Otavio Salvador
2011-05-15 21:45 ` [meta-oe][PATCH v1 2/3] libpcsclite: add version 1.7.2 Otavio Salvador
2011-05-16 7:15 ` Koen Kooi
2011-05-16 12:02 ` Otavio Salvador
2011-05-15 21:45 ` [meta-oe][PATCH v1 3/3] freerdp: update to 2011-05-14 snapshot Otavio Salvador
2011-05-16 7:06 ` [meta-oe][PATCH v1 1/3] libiconv: drop EXTRA_OECONF as it is handled by gettext class Koen Kooi
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.