git.vger.kernel.org archive mirror
 help / color / mirror / Atom feed
* GIT Web Interface
@ 2005-04-19  0:44 Kay Sievers
  2005-04-19  0:52 ` Petr Baudis
  0 siblings, 1 reply; 7+ messages in thread
From: Kay Sievers @ 2005-04-19  0:44 UTC (permalink / raw)
  To: git

I'm hacking on a simple web interface, cause I missed the bkweb too much.
It can't do much more than browse through the source tree and show the
log now, but that should change... :)
  http://ehlo.org/~kay/gitweb.pl?project=linux-2.6

How can I get the files touched with a changeset and the corresponding
diffs belonging to it?

Thanks,
Kay


-- 
#!/usr/bin/perl

# This file is licensed under the GPL v2, or a later version
# (C) 2005, Kay Sievers <kay.sievers@vrfy.org>


use strict;
use warnings;
use CGI;
use CGI::Carp qw(fatalsToBrowser);

my $query = new CGI;
my $gitbin = "/home/kay/bin";
my $gitroot = "/home/kay/public_html";

my $project = $query->param("project") || "";
my $action = $query->param("action") || "";
my $hash = $query->param("hash") || "";
my $projectroot = "$gitroot/$project";
$ENV{'SHA1_FILE_DIRECTORY'} = "$projectroot/.git/objects";

sub header {
	print $query->header();
	print $query->start_html("gitweb");
	print $query->h1($project);
}

sub footer {
	print $query->end_html();
}

if ($project eq "") {
	open my $fd, "-|", "ls", "-1", $gitroot;
	my (@path) = map { chomp; $_ } <$fd>;
	close $fd;
	header();
	print "projects:<br/>\n";
	foreach my $line (@path) {
		if (-e "$gitroot/$line/.git/HEAD") {
			print $query->a({-href => "gitweb.pl?project=$line"}, $line) . "<br/>\n";
		}
	}
	footer();
	exit;
}

if ($action eq "") {
	print $query->redirect("gitweb.pl?project=$project&action=show_log");
	exit;
}

if ($action eq "show_file") {
	header();
	print "<pre>\n";
	open my $fd, "-|", "$gitbin/cat-file", "blob", $hash;
	my $nr;
	while (my $line = <$fd>) {
		$nr++;
		print "$nr\t$line";
	}
	close $fd;
	print "</pre>\n";
	footer();
} elsif ($action eq "show_tree") {
	if ($hash eq "") {
		open my $fd, "$projectroot/.git/HEAD";
		my $head = <$fd>;
		chomp $head;
		close $fd;

		open $fd, "-|", "$gitbin/cat-file", "commit", $head;
		my $tree = <$fd>;
		chomp $tree;
		$tree =~ s/tree //;
		close $fd;
		$hash = $tree;
	}
	open my $fd, "-|", "$gitbin/ls-tree", $hash;
	my (@entries) = map { chomp; $_ } <$fd>;
	close $fd;
	header();
	foreach my $line (@entries) {
		$line =~ m/^([0-9]+)\t(.*)\t(.*)\t(.*)$/;
		my $t_type = $2;
		my $t_hash = $3;
		my $t_name = $4;
		if ($t_type eq "blob") {
			print "B\t" . $query->a({-href => "gitweb.pl?project=$project&action=show_file&hash=$3"}, $4) . "<br/>\n";
		} elsif ($t_type eq "tree") {
			print "T\t" . $query->a({-href => "gitweb.pl?project=$project&action=show_tree&hash=$3"}, $4) . "<br/>\n";
		}
	}
	footer();
} elsif ($action eq "show_log") {
	open my $fd, "$projectroot/.git/HEAD";
	my $head = <$fd>;
	chomp $head;
	close $fd;

	open my $fd, "-|", "$gitbin/rev-tree", $head;
	my (@revtree) = map { chomp; $_ } <$fd>;
	close $fd;

	header();
	foreach my $rev (reverse sort @revtree) {
		$rev =~ m/^([0-9]+) ([0-9a-fA-F]+)/;
		my $time = $1;
		my $commit = $2;

		open my $fd, "-|", "$gitbin/cat-file", "commit", $commit;
		print "commit $commit<br/>\n";
		while (my $line = <$fd>) {
			if ($line =~ m/^tree (.*)$/) {
				print $query->a({-href => "gitweb.pl?project=$project&action=show_tree&hash=$1"}, $line) . "<br/>\n";
			} elsif ($line =~ m/^(author|committer) (.*)/) {
				$line =~ m/^(.*) (.*>) ([0-9]+) (.*)$/;
				my $type = $1;
				my $name = $2;
				my $time = $3;
				my $timezone = $4;
				$name =~ s/</&lt;/;
				$name =~ s/>/&gt;/;
				$time = gmtime($time);
				print "$type $name $time $timezone<br/>\n";
			} else {
				$line =~ s/</&lt;/;
				$line =~ s/>/&gt;/;
				print "$line<br/>\n";
			}
		}
		close $fd;
		print "====================================<br/><br/>\n";
	}
	footer();
} else {
	header();
	print "unknown action\n";
	footer();
}


^ permalink raw reply	[flat|nested] 7+ messages in thread
end of thread, other threads:[~2005-04-19 17:38 UTC | newest]

Thread overview: 7+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2005-04-19  0:44 GIT Web Interface Kay Sievers
2005-04-19  0:52 ` Petr Baudis
2005-04-19 15:59   ` Kay Sievers
2005-04-19 16:52     ` Greg KH
2005-04-19 17:19       ` Stéphane Fillod
2005-04-19 17:32       ` Kay Sievers
2005-04-19 17:41         ` Greg KH

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).