[PATCH (GIT-GUI,MINGW) 0/3] Fix OpenSSH & Git-Gui integration in msysgit

[PATCH (GIT-GUI,MINGW) 0/3] Fix OpenSSH & Git-Gui integration in msysgit

[Alexander Gavrilov]

It is a well known problem on msysgit that when ssh is started
from git-gui during a fetch, any situations where it normally
displays a prompt to the user cause it to hang silently. It is
even worse than the situation on Linux, where the prompts appear
on the terminal that started the GUI.

This combination of 3 patches aims to eliminate this problem. One
of them changes a flag that is used to spawn the ssh executable,
to make it recognize that it does not have a valid controlling
console. The other two add features to git-gui that make ssh
usage more convenient, including a simple implementation of an
SSH_ASKPASS program.

When the patches are applied, all SSH prompts in msysgit
appear in a GUI dialog box in the middle of the screen.
Additionally, it is possible to view or create an OpenSSH
key pair directly from git-gui.


Note: This was already posted to the msysgit list. The only differences
      are that git-gui now sets a more evidently fake value for DISPLAY,
      and the last patch has been acked.


GIT-GUI:

	git-gui: Add a dialog that shows the OpenSSH public key.
	---
	 git-gui.sh     |    4 ++
	 lib/sshkey.tcl |  126 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
	 2 files changed, 130 insertions(+), 0 deletions(-)
	 create mode 100644 lib/sshkey.tcl

	git-gui: Add a simple implementation of SSH_ASKPASS.
	---
	 Makefile         |    2 ++
	 git-gui.sh       |   12 ++++++++++++
	 git-gui--askpass |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
	 3 files changed, 73 insertions(+), 0 deletions(-)
	 create mode 100755 git-gui--askpass


CORE(MINGW):

	Windows: Make OpenSSH properly detect tty detachment.
	---
	 compat/mingw.c |    8 ++++++--
	 1 files changed, 6 insertions(+), 2 deletions(-)

[PATCH (GIT-GUI,MINGW) 1/3] git-gui: Add a dialog that shows the OpenSSH public key.

[Alexander Gavrilov]

Generating a new SSH key or finding an existing one may
be a difficult task for non-technical users, especially
on Windows.

This commit adds a new dialog that shows the public key,
or allows the user to generate a new one if none were found.
Since this is a convenience/informational feature for new
users, and the dialog is mostly read-only, it is located
in the Help menu.

The command line used to invoke ssh-keygen is designed to
force it to use SSH_ASKPASS if available, or accept empty
passphrases, but _never_ wait for user response on the tty.

Signed-off-by: Alexander Gavrilov <angavrilov@gmail.com>
---
 git-gui.sh     |    4 ++
 lib/sshkey.tcl |  126 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 130 insertions(+), 0 deletions(-)
 create mode 100644 lib/sshkey.tcl

diff --git a/git-gui.sh b/git-gui.sh
index 4f95139..e4d1f70 100755
--- a/git-gui.sh
+++ b/git-gui.sh
@@ -2536,6 +2536,10 @@ proc start_browser {url} {
 
 .mbar.help add command -label [mc "Online Documentation"] \
 	-command [list start_browser $doc_url]
+
+.mbar.help add command -label [mc "Show SSH Key"] \
+	-command do_ssh_key
+
 unset doc_path doc_url
 
 # -- Standard bindings
diff --git a/lib/sshkey.tcl b/lib/sshkey.tcl
new file mode 100644
index 0000000..82a1a80
--- /dev/null
+++ b/lib/sshkey.tcl
@@ -0,0 +1,126 @@
+# git-gui about git-gui dialog
+# Copyright (C) 2006, 2007 Shawn Pearce
+
+proc find_ssh_key {} {
+	foreach name {~/.ssh/id_dsa.pub ~/.ssh/id_rsa.pub ~/.ssh/identity.pub} {
+		if {[file exists $name]} {
+			set fh    [open $name r]
+			set cont  [read $fh]
+			close $fh
+			return [list $name $cont]
+		}
+	}
+
+	return {}
+}
+
+proc do_ssh_key {} {
+	global sshkey_title have_tk85 sshkey_fd
+
+	set w .sshkey_dialog
+	if {[winfo exists $w]} {
+		raise $w
+		return
+	}
+
+	toplevel $w
+	wm transient $w .
+
+	set finfo [find_ssh_key]
+	if {$finfo eq {}} {
+		set sshkey_title [mc "No keys found."]
+		set gen_state   normal
+	} else {
+		set sshkey_title [mc "Found a public key in: %s" [lindex $finfo 0]]
+		set gen_state   disabled
+	}
+
+	frame $w.header -relief flat
+	label $w.header.lbl -textvariable sshkey_title -anchor w
+	button $w.header.gen -text [mc "Generate Key"] \
+		-command [list make_ssh_key $w] -state $gen_state
+	pack $w.header.lbl -side left -expand 1 -fill x
+	pack $w.header.gen -side right
+	pack $w.header -fill x -pady 5 -padx 5
+
+	text $w.contents -width 60 -height 10 -wrap char -relief sunken
+	pack $w.contents -fill both -expand 1
+	if {$have_tk85} {
+		$w.contents configure -inactiveselectbackground darkblue
+	}
+
+	frame $w.buttons
+	button $w.buttons.close -text [mc Close] \
+		-default active -command [list destroy $w]
+	pack $w.buttons.close -side right
+	button $w.buttons.copy -text [mc "Copy To Clipboard"] \
+		-command [list tk_textCopy $w.contents]
+	pack $w.buttons.copy -side left
+	pack $w.buttons -side bottom -fill x -pady 5 -padx 5
+
+	if {$finfo ne {}} {
+		$w.contents insert end [lindex $finfo 1] sel
+	}
+	$w.contents configure -state disabled
+
+	bind $w <Visibility> "grab $w; focus $w.buttons.close"
+	bind $w <Key-Escape> "destroy $w"
+	bind $w <Key-Return> "destroy $w"
+	bind $w <Destroy> kill_sshkey
+	wm title $w [mc "Your OpenSSH Public Key"]
+	tk::PlaceWindow $w widget .
+	tkwait window $w
+}
+
+proc make_ssh_key {w} {
+	global sshkey_title sshkey_output sshkey_fd
+
+	set sshkey_title [mc "Generating..."]
+	$w.header.gen configure -state disabled
+
+	set cmdline [list sh -c {echo | ssh-keygen -q -t rsa -f ~/.ssh/id_rsa 2>&1}]
+
+	if {[catch { set sshkey_fd [_open_stdout_stderr $cmdline] } err]} {
+		error_popup [mc "Could not start ssh-keygen:\n\n%s" $err]
+		return
+	}
+
+	set sshkey_output {}
+	fconfigure $sshkey_fd -blocking 0
+	fileevent $sshkey_fd readable [list read_sshkey_output $sshkey_fd $w]
+}
+
+proc kill_sshkey {} {
+	global sshkey_fd
+	if {![info exists sshkey_fd]} return
+	catch { kill_file_process $sshkey_fd }
+	catch { close $sshkey_fd }
+}
+
+proc read_sshkey_output {fd w} {
+	global sshkey_fd sshkey_output sshkey_title
+
+	set sshkey_output "$sshkey_output[read $fd]"
+	if {![eof $fd]} return
+
+	fconfigure $fd -blocking 1
+	unset sshkey_fd
+
+	$w.contents configure -state normal
+	if {[catch {close $fd} err]} {
+		set sshkey_title [mc "Generation failed."]
+		$w.contents insert end $err
+		$w.contents insert end "\n"
+		$w.contents insert end $sshkey_output
+	} else {
+		set finfo [find_ssh_key]
+		if {$finfo eq {}} {
+			set sshkey_title [mc "Generation succeded, but no keys found."]
+			$w.contents insert end $sshkey_output
+		} else {
+			set sshkey_title [mc "Your key is in: %s" [lindex $finfo 0]]
+			$w.contents insert end [lindex $finfo 1] sel
+		}
+	}
+	$w.contents configure -state disable
+}
-- 
1.6.0.20.g6148bc

[PATCH (GIT-GUI,MINGW) 2/3] git-gui: Add a simple implementation of SSH_ASKPASS.

[Alexander Gavrilov]

OpenSSH allows specifying an external program to use
for direct user interaction. While most Linux systems
already have such programs, some environments, for
instance, msysgit, lack it. This patch adds a simple
fallback Tcl implementation of the tool.

In msysgit it is also necessary to set a fake value of
the DISPLAY variable, because otherwise ssh won't even
try to use SSH_ASKPASS handlers.

Signed-off-by: Alexander Gavrilov <angavrilov@gmail.com>
---
 Makefile         |    2 ++
 git-gui.sh       |   12 ++++++++++++
 git-gui--askpass |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 3 files changed, 73 insertions(+), 0 deletions(-)
 create mode 100755 git-gui--askpass

diff --git a/Makefile b/Makefile
index 55765c8..0ee47bf 100644
--- a/Makefile
+++ b/Makefile
@@ -285,6 +285,7 @@ all:: $(GITGUI_MAIN) lib/tclIndex $(ALL_MSGFILES)
 install: all
 	$(QUIET)$(INSTALL_D0)'$(DESTDIR_SQ)$(gitexecdir_SQ)' $(INSTALL_D1)
 	$(QUIET)$(INSTALL_X0)git-gui $(INSTALL_X1) '$(DESTDIR_SQ)$(gitexecdir_SQ)'
+	$(QUIET)$(INSTALL_X0)git-gui--askpass $(INSTALL_X1) '$(DESTDIR_SQ)$(gitexecdir_SQ)'
 	$(QUIET)$(foreach p,$(GITGUI_BUILT_INS), $(INSTALL_L0)'$(DESTDIR_SQ)$(gitexecdir_SQ)/$p' $(INSTALL_L1)'$(DESTDIR_SQ)$(gitexecdir_SQ)/git-gui' $(INSTALL_L2)'$(DESTDIR_SQ)$(gitexecdir_SQ)/$p' $(INSTALL_L3) &&) true
 ifdef GITGUI_WINDOWS_WRAPPER
 	$(QUIET)$(INSTALL_R0)git-gui.tcl $(INSTALL_R1) '$(DESTDIR_SQ)$(gitexecdir_SQ)'
@@ -302,6 +303,7 @@ endif
 uninstall:
 	$(QUIET)$(CLEAN_DST) '$(DESTDIR_SQ)$(gitexecdir_SQ)'
 	$(QUIET)$(REMOVE_F0)'$(DESTDIR_SQ)$(gitexecdir_SQ)'/git-gui $(REMOVE_F1)
+	$(QUIET)$(REMOVE_F0)'$(DESTDIR_SQ)$(gitexecdir_SQ)'/git-gui--askpass $(REMOVE_F1)
 	$(QUIET)$(foreach p,$(GITGUI_BUILT_INS), $(REMOVE_F0)'$(DESTDIR_SQ)$(gitexecdir_SQ)'/$p $(REMOVE_F1) &&) true
 ifdef GITGUI_WINDOWS_WRAPPER
 	$(QUIET)$(REMOVE_F0)'$(DESTDIR_SQ)$(gitexecdir_SQ)'/git-gui.tcl $(REMOVE_F1)
diff --git a/git-gui.sh b/git-gui.sh
index e4d1f70..5e04a7c 100755
--- a/git-gui.sh
+++ b/git-gui.sh
@@ -592,6 +592,11 @@ bind . <Visibility> {
 if {[is_Windows]} {
 	wm iconbitmap . -default $oguilib/git-gui.ico
 	set ::tk::AlwaysShowSelection 1
+
+	# Spoof an X11 display for SSH
+	if {![info exists env(DISPLAY)]} {
+		set env(DISPLAY) :native
+	}
 }
 
 ######################################################################
@@ -1071,6 +1076,13 @@ set nullid2 "0000000000000000000000000000000000000001"
 set have_tk85 [expr {[package vcompare $tk_version "8.5"] >= 0}]
 
 ######################################################################
+
+# Suggest our implementation of askpass, if not already set
+if {![info exists env(SSH_ASKPASS)]} {
+	set env(SSH_ASKPASS) [gitexec git-gui--askpass]
+}
+
+######################################################################
 ##
 ## task management
 
diff --git a/git-gui--askpass b/git-gui--askpass
new file mode 100755
index 0000000..12e117e
--- /dev/null
+++ b/git-gui--askpass
@@ -0,0 +1,59 @@
+#!/bin/sh
+# Tcl ignores the next line -*- tcl -*- \
+exec wish "$0" -- "$@"
+
+# This is a trivial implementation of an SSH_ASKPASS handler.
+# Git-gui uses this script if none are already configured.
+
+set answer {}
+set yesno  0
+set rc     255
+
+if {$argc < 1} {
+	set prompt "Enter your OpenSSH passphrase:"
+} else {
+	set prompt [join $argv " "]
+	if {[regexp -nocase {\(yes\/no\)\?\s*$} $prompt]} {
+		set yesno 1
+	}
+}
+
+message .m -text $prompt -justify center -aspect 4000
+pack .m -side top -fill x -padx 20 -pady 20 -expand 1
+
+entry .e -textvariable answer -width 50
+pack .e -side top -fill x -padx 10 -pady 10
+
+if {!$yesno} {
+	.e configure -show "*"
+}
+
+frame .b
+button .b.ok     -text OK     -command finish
+button .b.cancel -text Cancel -command {destroy .}
+
+pack .b.ok -side left -expand 1
+pack .b.cancel -side right -expand 1
+pack .b -side bottom -fill x -padx 10 -pady 10
+
+bind . <Visibility> {focus -force .e}
+bind . <Key-Return> finish
+bind . <Key-Escape> {destroy .}
+bind . <Destroy>    {exit $rc}
+
+proc finish {} {
+	if {$::yesno} {
+		if {$::answer ne "yes" && $::answer ne "no"} {
+			tk_messageBox -icon error -title "Error" -type ok \
+				-message "Only 'yes' or 'no' input allowed."
+			return
+		}
+	}
+
+	set ::rc 0
+	puts $::answer
+	destroy .
+}
+
+wm title . "OpenSSH"
+tk::PlaceWindow .
-- 
1.6.0.20.g6148bc

[PATCH (GIT-GUI,MINGW) 3/3] Windows: Make OpenSSH properly detect tty detachment.

[Alexander Gavrilov]

Apparently, CREATE_NO_WINDOW makes the OS tell the process
that it has a console, but without actually creating the
window. As a result, when git is started from GUI, ssh
tries to ask its questions on the invisible console.

This patch uses DETACHED_PROCESS instead, which clearly
means that the process should be left without a console.
The downside is that if the process manually calls
AllocConsole, the window will appear. A similar thing
might occur if it calls another console executable.

Signed-off-by: Alexander Gavrilov <angavrilov@gmail.com>
Acked-by: Johannes Sixt <johannes.sixt@telecom.at>
---
 compat/mingw.c |    8 ++++++--
 1 files changed, 6 insertions(+), 2 deletions(-)

diff --git a/compat/mingw.c b/compat/mingw.c
index 1e29b88..b6fcf69 100644
--- a/compat/mingw.c
+++ b/compat/mingw.c
@@ -586,12 +586,16 @@ static pid_t mingw_spawnve(const char *cmd, const char **argv, char **env,
 		 * would normally create a console window. But
 		 * since we'll be redirecting std streams, we do
 		 * not need the console.
+		 * It is necessary to use DETACHED_PROCESS
+		 * instead of CREATE_NO_WINDOW to make ssh
+		 * recognize that it has no console.
 		 */
-		flags = CREATE_NO_WINDOW;
+		flags = DETACHED_PROCESS;
 	} else {
 		/* There is already a console. If we specified
-		 * CREATE_NO_WINDOW here, too, Windows would
+		 * DETACHED_PROCESS here, too, Windows would
 		 * disassociate the child from the console.
+		 * The same is true for CREATE_NO_WINDOW.
 		 * Go figure!
 		 */
 		flags = 0;
-- 
1.6.0.2.1256.ga12f0