* [PATCH v3 1/8] t0021/rot13-filter: fix list comparison
2017-11-10 13:21 [PATCH v3 0/8] Create Git/Packet.pm Christian Couder
@ 2017-11-10 13:21 ` Christian Couder
2017-11-10 13:21 ` [PATCH v3 2/8] t0021/rot13-filter: refactor packet reading functions Christian Couder
` (7 subsequent siblings)
8 siblings, 0 replies; 10+ messages in thread
From: Christian Couder @ 2017-11-10 13:21 UTC (permalink / raw)
To: git
Cc: Junio C Hamano, Jeff King, Ben Peart, Jonathan Tan,
Nguyen Thai Ngoc Duy, Mike Hommey, Lars Schneider, Eric Wong,
Christian Couder
Since edcc8581 ("convert: add filter.<driver>.process
option", 2016-10-16) when t0021/rot13-filter.pl was created, list
comparison in this perl script have been quite broken.
packet_txt_read() returns a 2-element list, and the right hand
side of "eq" also has a list with (two, elements), but "eq" takes
the last element of the list on each side, and compares them. The
first elements (0 or 1) on the right hand side lists do not matter,
which means we do not require to see a flush at the end of the
version -- a simple empty string or an EOF would do, which is
definitely not what we want.
Signed-off-by: Christian Couder <chriscool@tuxfamily.org>
---
t/t0021/rot13-filter.pl | 35 ++++++++++++++++++++++++++++-------
1 file changed, 28 insertions(+), 7 deletions(-)
diff --git a/t/t0021/rot13-filter.pl b/t/t0021/rot13-filter.pl
index ad685d92f8..4b2d9087d4 100644
--- a/t/t0021/rot13-filter.pl
+++ b/t/t0021/rot13-filter.pl
@@ -55,6 +55,20 @@ sub rot13 {
return $str;
}
+sub packet_compare_lists {
+ my ($expect, @result) = @_;
+ my $ix;
+ if (scalar @$expect != scalar @result) {
+ return undef;
+ }
+ for ($ix = 0; $ix < $#result; $ix++) {
+ if ($expect->[$ix] ne $result[$ix]) {
+ return undef;
+ }
+ }
+ return 1;
+}
+
sub packet_bin_read {
my $buffer;
my $bytes_read = read STDIN, $buffer, 4;
@@ -110,18 +124,25 @@ sub packet_flush {
print $debug "START\n";
$debug->flush();
-( packet_txt_read() eq ( 0, "git-filter-client" ) ) || die "bad initialize";
-( packet_txt_read() eq ( 0, "version=2" ) ) || die "bad version";
-( packet_bin_read() eq ( 1, "" ) ) || die "bad version end";
+packet_compare_lists([0, "git-filter-client"], packet_txt_read()) ||
+ die "bad initialize";
+packet_compare_lists([0, "version=2"], packet_txt_read()) ||
+ die "bad version";
+packet_compare_lists([1, ""], packet_bin_read()) ||
+ die "bad version end";
packet_txt_write("git-filter-server");
packet_txt_write("version=2");
packet_flush();
-( packet_txt_read() eq ( 0, "capability=clean" ) ) || die "bad capability";
-( packet_txt_read() eq ( 0, "capability=smudge" ) ) || die "bad capability";
-( packet_txt_read() eq ( 0, "capability=delay" ) ) || die "bad capability";
-( packet_bin_read() eq ( 1, "" ) ) || die "bad capability end";
+packet_compare_lists([0, "capability=clean"], packet_txt_read()) ||
+ die "bad capability";
+packet_compare_lists([0, "capability=smudge"], packet_txt_read()) ||
+ die "bad capability";
+packet_compare_lists([0, "capability=delay"], packet_txt_read()) ||
+ die "bad capability";
+packet_compare_lists([1, ""], packet_bin_read()) ||
+ die "bad capability end";
foreach (@capabilities) {
packet_txt_write( "capability=" . $_ );
--
2.15.0.132.g7ad97d78be
^ permalink raw reply related [flat|nested] 10+ messages in thread* [PATCH v3 2/8] t0021/rot13-filter: refactor packet reading functions
2017-11-10 13:21 [PATCH v3 0/8] Create Git/Packet.pm Christian Couder
2017-11-10 13:21 ` [PATCH v3 1/8] t0021/rot13-filter: fix list comparison Christian Couder
@ 2017-11-10 13:21 ` Christian Couder
2017-11-10 13:21 ` [PATCH v3 3/8] t0021/rot13-filter: improve 'if .. elsif .. else' style Christian Couder
` (6 subsequent siblings)
8 siblings, 0 replies; 10+ messages in thread
From: Christian Couder @ 2017-11-10 13:21 UTC (permalink / raw)
To: git
Cc: Junio C Hamano, Jeff King, Ben Peart, Jonathan Tan,
Nguyen Thai Ngoc Duy, Mike Hommey, Lars Schneider, Eric Wong,
Christian Couder
To make it possible in a following commit to move packet
reading and writing functions into a Packet.pm module,
let's refactor these functions, so they don't handle
printing debug output and exiting.
While at it let's create packet_key_val_read()
to still handle erroring out in a common case.
Signed-off-by: Christian Couder <chriscool@tuxfamily.org>
---
t/t0021/rot13-filter.pl | 43 +++++++++++++++++++++++++++++++------------
1 file changed, 31 insertions(+), 12 deletions(-)
diff --git a/t/t0021/rot13-filter.pl b/t/t0021/rot13-filter.pl
index 4b2d9087d4..b1909699f4 100644
--- a/t/t0021/rot13-filter.pl
+++ b/t/t0021/rot13-filter.pl
@@ -74,8 +74,7 @@ sub packet_bin_read {
my $bytes_read = read STDIN, $buffer, 4;
if ( $bytes_read == 0 ) {
# EOF - Git stopped talking to us!
- print $debug "STOP\n";
- exit();
+ return ( -1, "" );
}
elsif ( $bytes_read != 4 ) {
die "invalid packet: '$buffer'";
@@ -99,10 +98,20 @@ sub packet_bin_read {
sub packet_txt_read {
my ( $res, $buf ) = packet_bin_read();
- unless ( $buf eq '' or $buf =~ s/\n$// ) {
- die "A non-binary line MUST be terminated by an LF.";
+ if ( $res == -1 or $buf eq '' or $buf =~ s/\n$// ) {
+ return ( $res, $buf );
+ }
+ die "A non-binary line MUST be terminated by an LF.";
+}
+
+# Read a text line and check that it is in the form "key=value"
+sub packet_key_val_read {
+ my ( $key ) = @_;
+ my ( $res, $buf ) = packet_txt_read();
+ if ( $res == -1 or ( $buf =~ s/^$key=// and $buf ne '' ) ) {
+ return ( $res, $buf );
}
- return ( $res, $buf );
+ die "bad $key: '$buf'";
}
sub packet_bin_write {
@@ -152,13 +161,18 @@ print $debug "init handshake complete\n";
$debug->flush();
while (1) {
- my ( $command ) = packet_txt_read() =~ /^command=(.+)$/;
+ my ( $res, $command ) = packet_key_val_read("command");
+ if ( $res == -1 ) {
+ print $debug "STOP\n";
+ exit();
+ }
print $debug "IN: $command";
$debug->flush();
if ( $command eq "list_available_blobs" ) {
# Flush
- packet_bin_read();
+ packet_compare_lists([1, ""], packet_bin_read()) ||
+ die "bad list_available_blobs end";
foreach my $pathname ( sort keys %DELAY ) {
if ( $DELAY{$pathname}{"requested"} >= 1 ) {
@@ -184,14 +198,13 @@ while (1) {
packet_flush();
}
else {
- my ( $pathname ) = packet_txt_read() =~ /^pathname=(.+)$/;
+ my ( $res, $pathname ) = packet_key_val_read("pathname");
+ if ( $res == -1 ) {
+ die "unexpected EOF while expecting pathname";
+ }
print $debug " $pathname";
$debug->flush();
- if ( $pathname eq "" ) {
- die "bad pathname '$pathname'";
- }
-
# Read until flush
my ( $done, $buffer ) = packet_txt_read();
while ( $buffer ne '' ) {
@@ -205,6 +218,9 @@ while (1) {
( $done, $buffer ) = packet_txt_read();
}
+ if ( $done == -1 ) {
+ die "unexpected EOF after pathname '$pathname'";
+ }
my $input = "";
{
@@ -215,6 +231,9 @@ while (1) {
( $done, $buffer ) = packet_bin_read();
$input .= $buffer;
}
+ if ( $done == -1 ) {
+ die "unexpected EOF while reading input for '$pathname'";
+ }
print $debug " " . length($input) . " [OK] -- ";
$debug->flush();
}
--
2.15.0.132.g7ad97d78be
^ permalink raw reply related [flat|nested] 10+ messages in thread* [PATCH v3 3/8] t0021/rot13-filter: improve 'if .. elsif .. else' style
2017-11-10 13:21 [PATCH v3 0/8] Create Git/Packet.pm Christian Couder
2017-11-10 13:21 ` [PATCH v3 1/8] t0021/rot13-filter: fix list comparison Christian Couder
2017-11-10 13:21 ` [PATCH v3 2/8] t0021/rot13-filter: refactor packet reading functions Christian Couder
@ 2017-11-10 13:21 ` Christian Couder
2017-11-10 13:21 ` [PATCH v3 4/8] t0021/rot13-filter: improve error message Christian Couder
` (5 subsequent siblings)
8 siblings, 0 replies; 10+ messages in thread
From: Christian Couder @ 2017-11-10 13:21 UTC (permalink / raw)
To: git
Cc: Junio C Hamano, Jeff King, Ben Peart, Jonathan Tan,
Nguyen Thai Ngoc Duy, Mike Hommey, Lars Schneider, Eric Wong,
Christian Couder
Before further refactoring the "t0021/rot13-filter.pl" script,
let's modernize the style of its 'if .. elsif .. else' clauses
to improve its readability by making it more similar to our
other perl scripts.
Signed-off-by: Christian Couder <chriscool@tuxfamily.org>
---
t/t0021/rot13-filter.pl | 39 +++++++++++++--------------------------
1 file changed, 13 insertions(+), 26 deletions(-)
diff --git a/t/t0021/rot13-filter.pl b/t/t0021/rot13-filter.pl
index b1909699f4..8bba97af1a 100644
--- a/t/t0021/rot13-filter.pl
+++ b/t/t0021/rot13-filter.pl
@@ -75,23 +75,20 @@ sub packet_bin_read {
if ( $bytes_read == 0 ) {
# EOF - Git stopped talking to us!
return ( -1, "" );
- }
- elsif ( $bytes_read != 4 ) {
+ } elsif ( $bytes_read != 4 ) {
die "invalid packet: '$buffer'";
}
my $pkt_size = hex($buffer);
if ( $pkt_size == 0 ) {
return ( 1, "" );
- }
- elsif ( $pkt_size > 4 ) {
+ } elsif ( $pkt_size > 4 ) {
my $content_size = $pkt_size - 4;
$bytes_read = read STDIN, $buffer, $content_size;
if ( $bytes_read != $content_size ) {
die "invalid packet ($content_size bytes expected; $bytes_read bytes read)";
}
return ( 0, $buffer );
- }
- else {
+ } else {
die "invalid packet size: $pkt_size";
}
}
@@ -196,8 +193,7 @@ while (1) {
$debug->flush();
packet_txt_write("status=success");
packet_flush();
- }
- else {
+ } else {
my ( $res, $pathname ) = packet_key_val_read("pathname");
if ( $res == -1 ) {
die "unexpected EOF while expecting pathname";
@@ -241,17 +237,13 @@ while (1) {
my $output;
if ( exists $DELAY{$pathname} and exists $DELAY{$pathname}{"output"} ) {
$output = $DELAY{$pathname}{"output"}
- }
- elsif ( $pathname eq "error.r" or $pathname eq "abort.r" ) {
+ } elsif ( $pathname eq "error.r" or $pathname eq "abort.r" ) {
$output = "";
- }
- elsif ( $command eq "clean" and grep( /^clean$/, @capabilities ) ) {
+ } elsif ( $command eq "clean" and grep( /^clean$/, @capabilities ) ) {
$output = rot13($input);
- }
- elsif ( $command eq "smudge" and grep( /^smudge$/, @capabilities ) ) {
+ } elsif ( $command eq "smudge" and grep( /^smudge$/, @capabilities ) ) {
$output = rot13($input);
- }
- else {
+ } else {
die "bad command '$command'";
}
@@ -260,25 +252,21 @@ while (1) {
$debug->flush();
packet_txt_write("status=error");
packet_flush();
- }
- elsif ( $pathname eq "abort.r" ) {
+ } elsif ( $pathname eq "abort.r" ) {
print $debug "[ABORT]\n";
$debug->flush();
packet_txt_write("status=abort");
packet_flush();
- }
- elsif ( $command eq "smudge" and
+ } elsif ( $command eq "smudge" and
exists $DELAY{$pathname} and
- $DELAY{$pathname}{"requested"} == 1
- ) {
+ $DELAY{$pathname}{"requested"} == 1 ) {
print $debug "[DELAYED]\n";
$debug->flush();
packet_txt_write("status=delayed");
packet_flush();
$DELAY{$pathname}{"requested"} = 2;
$DELAY{$pathname}{"output"} = $output;
- }
- else {
+ } else {
packet_txt_write("status=success");
packet_flush();
@@ -298,8 +286,7 @@ while (1) {
print $debug ".";
if ( length($output) > $MAX_PACKET_CONTENT_SIZE ) {
$output = substr( $output, $MAX_PACKET_CONTENT_SIZE );
- }
- else {
+ } else {
$output = "";
}
}
--
2.15.0.132.g7ad97d78be
^ permalink raw reply related [flat|nested] 10+ messages in thread* [PATCH v3 4/8] t0021/rot13-filter: improve error message
2017-11-10 13:21 [PATCH v3 0/8] Create Git/Packet.pm Christian Couder
` (2 preceding siblings ...)
2017-11-10 13:21 ` [PATCH v3 3/8] t0021/rot13-filter: improve 'if .. elsif .. else' style Christian Couder
@ 2017-11-10 13:21 ` Christian Couder
2017-11-10 13:21 ` [PATCH v3 5/8] t0021/rot13-filter: add packet_initialize() Christian Couder
` (4 subsequent siblings)
8 siblings, 0 replies; 10+ messages in thread
From: Christian Couder @ 2017-11-10 13:21 UTC (permalink / raw)
To: git
Cc: Junio C Hamano, Jeff King, Ben Peart, Jonathan Tan,
Nguyen Thai Ngoc Duy, Mike Hommey, Lars Schneider, Eric Wong,
Christian Couder
If there is no new line at the end of something it receives,
the packet_txt_read() function die()s, but it's difficult to
debug without much context.
Let's give a bit more information when that happens.
Signed-off-by: Christian Couder <chriscool@tuxfamily.org>
---
t/t0021/rot13-filter.pl | 3 ++-
1 file changed, 2 insertions(+), 1 deletion(-)
diff --git a/t/t0021/rot13-filter.pl b/t/t0021/rot13-filter.pl
index 8bba97af1a..55b6e17034 100644
--- a/t/t0021/rot13-filter.pl
+++ b/t/t0021/rot13-filter.pl
@@ -98,7 +98,8 @@ sub packet_txt_read {
if ( $res == -1 or $buf eq '' or $buf =~ s/\n$// ) {
return ( $res, $buf );
}
- die "A non-binary line MUST be terminated by an LF.";
+ die "A non-binary line MUST be terminated by an LF.\n"
+ . "Received: '$buf'";
}
# Read a text line and check that it is in the form "key=value"
--
2.15.0.132.g7ad97d78be
^ permalink raw reply related [flat|nested] 10+ messages in thread* [PATCH v3 5/8] t0021/rot13-filter: add packet_initialize()
2017-11-10 13:21 [PATCH v3 0/8] Create Git/Packet.pm Christian Couder
` (3 preceding siblings ...)
2017-11-10 13:21 ` [PATCH v3 4/8] t0021/rot13-filter: improve error message Christian Couder
@ 2017-11-10 13:21 ` Christian Couder
2017-11-10 13:21 ` [PATCH v3 6/8] t0021/rot13-filter: refactor checking final lf Christian Couder
` (3 subsequent siblings)
8 siblings, 0 replies; 10+ messages in thread
From: Christian Couder @ 2017-11-10 13:21 UTC (permalink / raw)
To: git
Cc: Junio C Hamano, Jeff King, Ben Peart, Jonathan Tan,
Nguyen Thai Ngoc Duy, Mike Hommey, Lars Schneider, Eric Wong,
Christian Couder
Let's refactor the code to initialize communication into its own
packet_initialize() function, so that we can reuse this
functionality in following patches.
Signed-off-by: Christian Couder <chriscool@tuxfamily.org>
---
t/t0021/rot13-filter.pl | 26 ++++++++++++++++----------
1 file changed, 16 insertions(+), 10 deletions(-)
diff --git a/t/t0021/rot13-filter.pl b/t/t0021/rot13-filter.pl
index 55b6e17034..9e18be66b6 100644
--- a/t/t0021/rot13-filter.pl
+++ b/t/t0021/rot13-filter.pl
@@ -128,19 +128,25 @@ sub packet_flush {
STDOUT->flush();
}
+sub packet_initialize {
+ my ($name, $version) = @_;
+
+ packet_compare_lists([0, $name . "-client"], packet_txt_read()) ||
+ die "bad initialize";
+ packet_compare_lists([0, "version=" . $version], packet_txt_read()) ||
+ die "bad version";
+ packet_compare_lists([1, ""], packet_bin_read()) ||
+ die "bad version end";
+
+ packet_txt_write( $name . "-server" );
+ packet_txt_write( "version=" . $version );
+ packet_flush();
+}
+
print $debug "START\n";
$debug->flush();
-packet_compare_lists([0, "git-filter-client"], packet_txt_read()) ||
- die "bad initialize";
-packet_compare_lists([0, "version=2"], packet_txt_read()) ||
- die "bad version";
-packet_compare_lists([1, ""], packet_bin_read()) ||
- die "bad version end";
-
-packet_txt_write("git-filter-server");
-packet_txt_write("version=2");
-packet_flush();
+packet_initialize("git-filter", 2);
packet_compare_lists([0, "capability=clean"], packet_txt_read()) ||
die "bad capability";
--
2.15.0.132.g7ad97d78be
^ permalink raw reply related [flat|nested] 10+ messages in thread* [PATCH v3 6/8] t0021/rot13-filter: refactor checking final lf
2017-11-10 13:21 [PATCH v3 0/8] Create Git/Packet.pm Christian Couder
` (4 preceding siblings ...)
2017-11-10 13:21 ` [PATCH v3 5/8] t0021/rot13-filter: add packet_initialize() Christian Couder
@ 2017-11-10 13:21 ` Christian Couder
2017-11-10 13:21 ` [PATCH v3 7/8] t0021/rot13-filter: add capability functions Christian Couder
` (2 subsequent siblings)
8 siblings, 0 replies; 10+ messages in thread
From: Christian Couder @ 2017-11-10 13:21 UTC (permalink / raw)
To: git
Cc: Junio C Hamano, Jeff King, Ben Peart, Jonathan Tan,
Nguyen Thai Ngoc Duy, Mike Hommey, Lars Schneider, Eric Wong,
Christian Couder
As checking for a lf character at the end of a buffer
will be useful in another function, let's refactor this
functionality into a small remove_final_lf_or_die()
helper function.
Signed-off-by: Christian Couder <chriscool@tuxfamily.org>
---
t/t0021/rot13-filter.pl | 16 ++++++++++++----
1 file changed, 12 insertions(+), 4 deletions(-)
diff --git a/t/t0021/rot13-filter.pl b/t/t0021/rot13-filter.pl
index 9e18be66b6..8f255b6131 100644
--- a/t/t0021/rot13-filter.pl
+++ b/t/t0021/rot13-filter.pl
@@ -93,15 +93,23 @@ sub packet_bin_read {
}
}
-sub packet_txt_read {
- my ( $res, $buf ) = packet_bin_read();
- if ( $res == -1 or $buf eq '' or $buf =~ s/\n$// ) {
- return ( $res, $buf );
+sub remove_final_lf_or_die {
+ my $buf = shift;
+ if ( $buf =~ s/\n$// ) {
+ return $buf;
}
die "A non-binary line MUST be terminated by an LF.\n"
. "Received: '$buf'";
}
+sub packet_txt_read {
+ my ( $res, $buf ) = packet_bin_read();
+ if ( $res != -1 and $buf ne '' ) {
+ $buf = remove_final_lf_or_die($buf);
+ }
+ return ( $res, $buf );
+}
+
# Read a text line and check that it is in the form "key=value"
sub packet_key_val_read {
my ( $key ) = @_;
--
2.15.0.132.g7ad97d78be
^ permalink raw reply related [flat|nested] 10+ messages in thread* [PATCH v3 7/8] t0021/rot13-filter: add capability functions
2017-11-10 13:21 [PATCH v3 0/8] Create Git/Packet.pm Christian Couder
` (5 preceding siblings ...)
2017-11-10 13:21 ` [PATCH v3 6/8] t0021/rot13-filter: refactor checking final lf Christian Couder
@ 2017-11-10 13:21 ` Christian Couder
2017-11-10 13:22 ` [PATCH v3 8/8] Add Git/Packet.pm from parts of t0021/rot13-filter.pl Christian Couder
2017-11-10 19:03 ` [PATCH v3 0/8] Create Git/Packet.pm Junio C Hamano
8 siblings, 0 replies; 10+ messages in thread
From: Christian Couder @ 2017-11-10 13:21 UTC (permalink / raw)
To: git
Cc: Junio C Hamano, Jeff King, Ben Peart, Jonathan Tan,
Nguyen Thai Ngoc Duy, Mike Hommey, Lars Schneider, Eric Wong,
Christian Couder
These function help read and write capabilities.
To make them more generic and make it easy to reuse them,
the following changes are made:
- we don't require capabilities to come in a fixed order,
- we allow duplicates,
- we check that the remote supports the capabilities we
advertise,
- we don't check if the remote declares any capability we
don't know about.
The reason behind the last change is that the protocol
should work using only the capabilities that both ends
support, and it should not stop working if one end starts
to advertise a new capability.
Despite those changes, we can still require a set of
capabilities, and die if one of them is not supported.
Signed-off-by: Christian Couder <chriscool@tuxfamily.org>
---
t/t0021/rot13-filter.pl | 58 ++++++++++++++++++++++++++++++++++++++-----------
1 file changed, 45 insertions(+), 13 deletions(-)
diff --git a/t/t0021/rot13-filter.pl b/t/t0021/rot13-filter.pl
index 8f255b6131..6cd9ecffee 100644
--- a/t/t0021/rot13-filter.pl
+++ b/t/t0021/rot13-filter.pl
@@ -151,24 +151,56 @@ sub packet_initialize {
packet_flush();
}
+sub packet_read_capabilities {
+ my @cap;
+ while (1) {
+ my ( $res, $buf ) = packet_bin_read();
+ if ( $res == -1 ) {
+ die "unexpected EOF when reading capabilities";
+ }
+ return ( $res, @cap ) if ( $res != 0 );
+ $buf = remove_final_lf_or_die($buf);
+ unless ( $buf =~ s/capability=// ) {
+ die "bad capability buf: '$buf'";
+ }
+ push @cap, $buf;
+ }
+}
+
+# Read remote capabilities and check them against capabilities we require
+sub packet_read_and_check_capabilities {
+ my @required_caps = @_;
+ my ($res, @remote_caps) = packet_read_capabilities();
+ my %remote_caps = map { $_ => 1 } @remote_caps;
+ foreach (@required_caps) {
+ unless (exists($remote_caps{$_})) {
+ die "required '$_' capability not available from remote" ;
+ }
+ }
+ return %remote_caps;
+}
+
+# Check our capabilities we want to advertise against the remote ones
+# and then advertise our capabilities
+sub packet_check_and_write_capabilities {
+ my ($remote_caps, @our_caps) = @_;
+ foreach (@our_caps) {
+ unless (exists($remote_caps->{$_})) {
+ die "our capability '$_' is not available from remote"
+ }
+ packet_txt_write( "capability=" . $_ );
+ }
+ packet_flush();
+}
+
print $debug "START\n";
$debug->flush();
packet_initialize("git-filter", 2);
-packet_compare_lists([0, "capability=clean"], packet_txt_read()) ||
- die "bad capability";
-packet_compare_lists([0, "capability=smudge"], packet_txt_read()) ||
- die "bad capability";
-packet_compare_lists([0, "capability=delay"], packet_txt_read()) ||
- die "bad capability";
-packet_compare_lists([1, ""], packet_bin_read()) ||
- die "bad capability end";
-
-foreach (@capabilities) {
- packet_txt_write( "capability=" . $_ );
-}
-packet_flush();
+my %remote_caps = packet_read_and_check_capabilities("clean", "smudge", "delay");
+packet_check_and_write_capabilities(\%remote_caps, @capabilities);
+
print $debug "init handshake complete\n";
$debug->flush();
--
2.15.0.132.g7ad97d78be
^ permalink raw reply related [flat|nested] 10+ messages in thread* [PATCH v3 8/8] Add Git/Packet.pm from parts of t0021/rot13-filter.pl
2017-11-10 13:21 [PATCH v3 0/8] Create Git/Packet.pm Christian Couder
` (6 preceding siblings ...)
2017-11-10 13:21 ` [PATCH v3 7/8] t0021/rot13-filter: add capability functions Christian Couder
@ 2017-11-10 13:22 ` Christian Couder
2017-11-10 19:03 ` [PATCH v3 0/8] Create Git/Packet.pm Junio C Hamano
8 siblings, 0 replies; 10+ messages in thread
From: Christian Couder @ 2017-11-10 13:22 UTC (permalink / raw)
To: git
Cc: Junio C Hamano, Jeff King, Ben Peart, Jonathan Tan,
Nguyen Thai Ngoc Duy, Mike Hommey, Lars Schneider, Eric Wong,
Christian Couder
And while at it let's simplify t0021/rot13-filter.pl by
using Git/Packet.pm.
This will make it possible to reuse packet related
functions in other test scripts.
Signed-off-by: Christian Couder <chriscool@tuxfamily.org>
---
perl/Git/Packet.pm | 169 ++++++++++++++++++++++++++++++++++++++++++++++++
perl/Makefile | 1 +
t/t0021/rot13-filter.pl | 141 +---------------------------------------
3 files changed, 173 insertions(+), 138 deletions(-)
create mode 100644 perl/Git/Packet.pm
diff --git a/perl/Git/Packet.pm b/perl/Git/Packet.pm
new file mode 100644
index 0000000000..1682403ffc
--- /dev/null
+++ b/perl/Git/Packet.pm
@@ -0,0 +1,169 @@
+package Git::Packet;
+use 5.008;
+use strict;
+use warnings;
+BEGIN {
+ require Exporter;
+ if ($] < 5.008003) {
+ *import = \&Exporter::import;
+ } else {
+ # Exporter 5.57 which supports this invocation was
+ # released with perl 5.8.3
+ Exporter->import('import');
+ }
+}
+
+our @EXPORT = qw(
+ packet_compare_lists
+ packet_bin_read
+ packet_txt_read
+ packet_key_val_read
+ packet_bin_write
+ packet_txt_write
+ packet_flush
+ packet_initialize
+ packet_read_capabilities
+ packet_read_and_check_capabilities
+ packet_check_and_write_capabilities
+ );
+our @EXPORT_OK = @EXPORT;
+
+sub packet_compare_lists {
+ my ($expect, @result) = @_;
+ my $ix;
+ if (scalar @$expect != scalar @result) {
+ return undef;
+ }
+ for ($ix = 0; $ix < $#result; $ix++) {
+ if ($expect->[$ix] ne $result[$ix]) {
+ return undef;
+ }
+ }
+ return 1;
+}
+
+sub packet_bin_read {
+ my $buffer;
+ my $bytes_read = read STDIN, $buffer, 4;
+ if ( $bytes_read == 0 ) {
+ # EOF - Git stopped talking to us!
+ return ( -1, "" );
+ } elsif ( $bytes_read != 4 ) {
+ die "invalid packet: '$buffer'";
+ }
+ my $pkt_size = hex($buffer);
+ if ( $pkt_size == 0 ) {
+ return ( 1, "" );
+ } elsif ( $pkt_size > 4 ) {
+ my $content_size = $pkt_size - 4;
+ $bytes_read = read STDIN, $buffer, $content_size;
+ if ( $bytes_read != $content_size ) {
+ die "invalid packet ($content_size bytes expected; $bytes_read bytes read)";
+ }
+ return ( 0, $buffer );
+ } else {
+ die "invalid packet size: $pkt_size";
+ }
+}
+
+sub remove_final_lf_or_die {
+ my $buf = shift;
+ if ( $buf =~ s/\n$// ) {
+ return $buf;
+ }
+ die "A non-binary line MUST be terminated by an LF.\n"
+ . "Received: '$buf'";
+}
+
+sub packet_txt_read {
+ my ( $res, $buf ) = packet_bin_read();
+ if ( $res != -1 and $buf ne '' ) {
+ $buf = remove_final_lf_or_die($buf);
+ }
+ return ( $res, $buf );
+}
+
+# Read a text line and check that it is in the form "key=value"
+sub packet_key_val_read {
+ my ( $key ) = @_;
+ my ( $res, $buf ) = packet_txt_read();
+ if ( $res == -1 or ( $buf =~ s/^$key=// and $buf ne '' ) ) {
+ return ( $res, $buf );
+ }
+ die "bad $key: '$buf'";
+}
+
+sub packet_bin_write {
+ my $buf = shift;
+ print STDOUT sprintf( "%04x", length($buf) + 4 );
+ print STDOUT $buf;
+ STDOUT->flush();
+}
+
+sub packet_txt_write {
+ packet_bin_write( $_[0] . "\n" );
+}
+
+sub packet_flush {
+ print STDOUT sprintf( "%04x", 0 );
+ STDOUT->flush();
+}
+
+sub packet_initialize {
+ my ($name, $version) = @_;
+
+ packet_compare_lists([0, $name . "-client"], packet_txt_read()) ||
+ die "bad initialize";
+ packet_compare_lists([0, "version=" . $version], packet_txt_read()) ||
+ die "bad version";
+ packet_compare_lists([1, ""], packet_bin_read()) ||
+ die "bad version end";
+
+ packet_txt_write( $name . "-server" );
+ packet_txt_write( "version=" . $version );
+ packet_flush();
+}
+
+sub packet_read_capabilities {
+ my @cap;
+ while (1) {
+ my ( $res, $buf ) = packet_bin_read();
+ if ( $res == -1 ) {
+ die "unexpected EOF when reading capabilities";
+ }
+ return ( $res, @cap ) if ( $res != 0 );
+ $buf = remove_final_lf_or_die($buf);
+ unless ( $buf =~ s/capability=// ) {
+ die "bad capability buf: '$buf'";
+ }
+ push @cap, $buf;
+ }
+}
+
+# Read remote capabilities and check them against capabilities we require
+sub packet_read_and_check_capabilities {
+ my @required_caps = @_;
+ my ($res, @remote_caps) = packet_read_capabilities();
+ my %remote_caps = map { $_ => 1 } @remote_caps;
+ foreach (@required_caps) {
+ unless (exists($remote_caps{$_})) {
+ die "required '$_' capability not available from remote" ;
+ }
+ }
+ return %remote_caps;
+}
+
+# Check our capabilities we want to advertise against the remote ones
+# and then advertise our capabilities
+sub packet_check_and_write_capabilities {
+ my ($remote_caps, @our_caps) = @_;
+ foreach (@our_caps) {
+ unless (exists($remote_caps->{$_})) {
+ die "our capability '$_' is not available from remote"
+ }
+ packet_txt_write( "capability=" . $_ );
+ }
+ packet_flush();
+}
+
+1;
diff --git a/perl/Makefile b/perl/Makefile
index 15d96fcc7a..f657de20e3 100644
--- a/perl/Makefile
+++ b/perl/Makefile
@@ -30,6 +30,7 @@ instdir_SQ = $(subst ','\'',$(prefix)/lib)
modules += Git
modules += Git/I18N
modules += Git/IndexInfo
+modules += Git/Packet
modules += Git/SVN
modules += Git/SVN/Memoize/YAML
modules += Git/SVN/Fetcher
diff --git a/t/t0021/rot13-filter.pl b/t/t0021/rot13-filter.pl
index 6cd9ecffee..f1678851de 100644
--- a/t/t0021/rot13-filter.pl
+++ b/t/t0021/rot13-filter.pl
@@ -30,9 +30,12 @@
# to the "list_available_blobs" response.
#
+use 5.008;
+use lib (split(/:/, $ENV{GITPERLLIB}));
use strict;
use warnings;
use IO::File;
+use Git::Packet;
my $MAX_PACKET_CONTENT_SIZE = 65516;
my $log_file = shift @ARGV;
@@ -55,144 +58,6 @@ sub rot13 {
return $str;
}
-sub packet_compare_lists {
- my ($expect, @result) = @_;
- my $ix;
- if (scalar @$expect != scalar @result) {
- return undef;
- }
- for ($ix = 0; $ix < $#result; $ix++) {
- if ($expect->[$ix] ne $result[$ix]) {
- return undef;
- }
- }
- return 1;
-}
-
-sub packet_bin_read {
- my $buffer;
- my $bytes_read = read STDIN, $buffer, 4;
- if ( $bytes_read == 0 ) {
- # EOF - Git stopped talking to us!
- return ( -1, "" );
- } elsif ( $bytes_read != 4 ) {
- die "invalid packet: '$buffer'";
- }
- my $pkt_size = hex($buffer);
- if ( $pkt_size == 0 ) {
- return ( 1, "" );
- } elsif ( $pkt_size > 4 ) {
- my $content_size = $pkt_size - 4;
- $bytes_read = read STDIN, $buffer, $content_size;
- if ( $bytes_read != $content_size ) {
- die "invalid packet ($content_size bytes expected; $bytes_read bytes read)";
- }
- return ( 0, $buffer );
- } else {
- die "invalid packet size: $pkt_size";
- }
-}
-
-sub remove_final_lf_or_die {
- my $buf = shift;
- if ( $buf =~ s/\n$// ) {
- return $buf;
- }
- die "A non-binary line MUST be terminated by an LF.\n"
- . "Received: '$buf'";
-}
-
-sub packet_txt_read {
- my ( $res, $buf ) = packet_bin_read();
- if ( $res != -1 and $buf ne '' ) {
- $buf = remove_final_lf_or_die($buf);
- }
- return ( $res, $buf );
-}
-
-# Read a text line and check that it is in the form "key=value"
-sub packet_key_val_read {
- my ( $key ) = @_;
- my ( $res, $buf ) = packet_txt_read();
- if ( $res == -1 or ( $buf =~ s/^$key=// and $buf ne '' ) ) {
- return ( $res, $buf );
- }
- die "bad $key: '$buf'";
-}
-
-sub packet_bin_write {
- my $buf = shift;
- print STDOUT sprintf( "%04x", length($buf) + 4 );
- print STDOUT $buf;
- STDOUT->flush();
-}
-
-sub packet_txt_write {
- packet_bin_write( $_[0] . "\n" );
-}
-
-sub packet_flush {
- print STDOUT sprintf( "%04x", 0 );
- STDOUT->flush();
-}
-
-sub packet_initialize {
- my ($name, $version) = @_;
-
- packet_compare_lists([0, $name . "-client"], packet_txt_read()) ||
- die "bad initialize";
- packet_compare_lists([0, "version=" . $version], packet_txt_read()) ||
- die "bad version";
- packet_compare_lists([1, ""], packet_bin_read()) ||
- die "bad version end";
-
- packet_txt_write( $name . "-server" );
- packet_txt_write( "version=" . $version );
- packet_flush();
-}
-
-sub packet_read_capabilities {
- my @cap;
- while (1) {
- my ( $res, $buf ) = packet_bin_read();
- if ( $res == -1 ) {
- die "unexpected EOF when reading capabilities";
- }
- return ( $res, @cap ) if ( $res != 0 );
- $buf = remove_final_lf_or_die($buf);
- unless ( $buf =~ s/capability=// ) {
- die "bad capability buf: '$buf'";
- }
- push @cap, $buf;
- }
-}
-
-# Read remote capabilities and check them against capabilities we require
-sub packet_read_and_check_capabilities {
- my @required_caps = @_;
- my ($res, @remote_caps) = packet_read_capabilities();
- my %remote_caps = map { $_ => 1 } @remote_caps;
- foreach (@required_caps) {
- unless (exists($remote_caps{$_})) {
- die "required '$_' capability not available from remote" ;
- }
- }
- return %remote_caps;
-}
-
-# Check our capabilities we want to advertise against the remote ones
-# and then advertise our capabilities
-sub packet_check_and_write_capabilities {
- my ($remote_caps, @our_caps) = @_;
- foreach (@our_caps) {
- unless (exists($remote_caps->{$_})) {
- die "our capability '$_' is not available from remote"
- }
- packet_txt_write( "capability=" . $_ );
- }
- packet_flush();
-}
-
print $debug "START\n";
$debug->flush();
--
2.15.0.132.g7ad97d78be
^ permalink raw reply related [flat|nested] 10+ messages in thread* Re: [PATCH v3 0/8] Create Git/Packet.pm
2017-11-10 13:21 [PATCH v3 0/8] Create Git/Packet.pm Christian Couder
` (7 preceding siblings ...)
2017-11-10 13:22 ` [PATCH v3 8/8] Add Git/Packet.pm from parts of t0021/rot13-filter.pl Christian Couder
@ 2017-11-10 19:03 ` Junio C Hamano
8 siblings, 0 replies; 10+ messages in thread
From: Junio C Hamano @ 2017-11-10 19:03 UTC (permalink / raw)
To: Christian Couder
Cc: git, Jeff King, Ben Peart, Jonathan Tan, Nguyen Thai Ngoc Duy,
Mike Hommey, Lars Schneider, Eric Wong, Christian Couder
Christian Couder <christian.couder@gmail.com> writes:
> There are only a few small changes compared to v2:
Please go incremental as v2 is already in 'next', and small changes
are easier to reiew and understand when given as follow-up "polish
this minor glitch in the initial effort" patches.
Thanks.
^ permalink raw reply [flat|nested] 10+ messages in thread