Re: [PATCH] Ensure that MIPS target code is compiled for the O32 ABI.

[Mark H Weaver <mhw@netris.org>]

[-- Attachment #1: Type: text/plain, Size: 149 bytes --]

Hi Andrei,

Here's a patch on top of yours that omits the link step from the new
autoconf test.  This eliminates the warnings I encountered before:


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: [PATCH] Omit the link step in the MIPS O32 check --]
[-- Type: text/x-patch, Size: 630 bytes --]

diff --git a/configure.ac b/configure.ac
index f3c9b90..cd9fa8d 100644
--- a/configure.ac
+++ b/configure.ac
@@ -605,14 +605,10 @@ if test "x$target_cpu" = xmips || test "x$target_cpu" = xmipsel ; then
         break
       fi
       CFLAGS="$TARGET_CFLAGS $arg -Werror"
-      AC_LINK_IFELSE([AC_LANG_PROGRAM([[
+      AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 #if !defined(_ABIO32) || !defined(_MIPS_SIM) || (_MIPS_SIM != _ABIO32)
 #error not o32 ABI
 #endif
-asm (".globl start; start:");
-void __main (void);
-void __main (void) {}
-int main (void);
 ]], [[]])],
 		        [grub_cv_target_cc_mips_o32_abi="$arg"], [])
     done

[-- Attachment #3: Type: text/plain, Size: 75 bytes --]


Here's an updated version of your commit, incorporating the above patch:


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #4: [PATCH] configure: try to force o32 ABI on MIPS --]
[-- Type: text/x-patch, Size: 2024 bytes --]

From 8adcca69d3d9aacd20010a450aa20083a834392b Mon Sep 17 00:00:00 2001
From: Andrei Borzenkov <arvidjaar@gmail.com>
Date: Fri, 11 Sep 2015 11:28:49 -0400
Subject: [PATCH] configure: try to force o32 ABI on MIPS

GRUB expects o32 ABI, in particular used assembly is valid only in this mode.
Some systems (e.g. GNU Guix) default to using newer n64 or n32 ABI. Try to
find suitable options to force o32.

For GCC this is simply -mabi=32. While clang supports this option as well,
o32 ABI is valid for MIPS target and n32/64 ABI are valid for MIPS64 target
only, so use "-target mips/mipsel -mabi=32".

Reported-By: Mark H Weaver <mhw@netris.org>
Also-By: Mark H Weaver <mhw@netris.org>
---
 configure.ac | 25 +++++++++++++++++++++++++
 1 file changed, 25 insertions(+)

diff --git a/configure.ac b/configure.ac
index c864311..cd9fa8d 100644
--- a/configure.ac
+++ b/configure.ac
@@ -597,6 +597,31 @@ int main (void);
   TARGET_LDFLAGS="$TARGET_LDFLAGS $grub_cv_target_cc_big_endian"
 fi
 
+if test "x$target_cpu" = xmips || test "x$target_cpu" = xmipsel ; then
+  AC_CACHE_CHECK([for options to force MIPS o32 ABI], grub_cv_target_cc_mips_o32_abi, [
+    grub_cv_target_cc_mips_o32_abi=no
+    for arg in "" "-mabi=32" "-target $target_cpu -mabi=32" ; do
+      if test x"$grub_cv_target_cc_mips_o32_abi" != xno ; then
+        break
+      fi
+      CFLAGS="$TARGET_CFLAGS $arg -Werror"
+      AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
+#if !defined(_ABIO32) || !defined(_MIPS_SIM) || (_MIPS_SIM != _ABIO32)
+#error not o32 ABI
+#endif
+]], [[]])],
+		        [grub_cv_target_cc_mips_o32_abi="$arg"], [])
+    done
+  ])
+
+  if test x"$grub_cv_target_cc_mips_o32_abi" = xno ; then
+    AC_MSG_ERROR([could not force MIPS o32 ABI])
+  fi
+
+  TARGET_CFLAGS="$TARGET_CFLAGS $grub_cv_target_cc_mips_o32_abi"
+  TARGET_CCASFLAGS="$TARGET_CCASFLAGS $grub_cv_target_cc_mips_o32_abi"
+fi
+
 AC_CACHE_CHECK([for options to compile assembly], [grub_cv_cc_target_asm_compile], [
 test_program=
 case "x$target_cpu-$platform" in
-- 
2.5.0


[-- Attachment #5: Type: text/plain, Size: 144 bytes --]


I tested this on MIPS with GCC 5.2.0 and clang 3.6.0.  It works the same
as before, but the warnings are gone.

What do you think?

      Mark