[patch] Update autotools configuration

[patch] Update autotools configuration

[Javier Jardón]

[-- Attachment #1: Type: text/plain, Size: 230 bytes --]

Simple patch to update the autotools configuration.

It replaces deprecated autoconf macros and use the new libtool syntax.
Also It uses silent-rules to make the build less verbose (linux-like).

-- 
Javier Jardón Cabezas

[-- Attachment #2: 0001-build-Update-autotools-configuration.patch --]
[-- Type: application/octet-stream, Size: 3270 bytes --]

From c7ba713d0ab738d7c00029c6269d93c404155f6f Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Javier=20Jard=C3=B3n?= <jjardon@gnome.org>
Date: Tue, 8 Feb 2011 22:33:12 +0000
Subject: [PATCH] build: Update autotools configuration

Replace deprecated macros and use the new libtool syntax
Also use silent-rules to make the build option less verbose.
---
 Makefile.am   |    2 +-
 autogen.sh    |   14 ++++----------
 configure.ac  |   28 ++++++++++++++++++----------
 m4/.gitignore |    5 +++++
 4 files changed, 28 insertions(+), 21 deletions(-)
 create mode 100644 m4/.gitignore

diff --git a/Makefile.am b/Makefile.am
index 6808bf0..d098ed5 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -19,6 +19,6 @@
 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
 
-AUTOMAKE_OPTIONS = foreign
+ACLOCAL_AMFLAGS = -I m4 ${ACLOCAL_FLAGS}
 
 SUBDIRS = lib man tests tools benchmarks
diff --git a/autogen.sh b/autogen.sh
index 904cd67..30d679f 100755
--- a/autogen.sh
+++ b/autogen.sh
@@ -1,12 +1,6 @@
 #! /bin/sh
 
-srcdir=`dirname $0`
-test -z "$srcdir" && srcdir=.
-
-ORIGDIR=`pwd`
-cd $srcdir
-
-autoreconf -v --install || exit 1
-cd $ORIGDIR || exit $?
-
-$srcdir/configure --enable-maintainer-mode "$@"
+test -n "$srcdir" || srcdir=`dirname "$0"`
+test -n "$srcdir" || srcdir=.
+autoreconf --force --install --verbose "$srcdir"
+test -n "$NOCONFIGURE" || "$srcdir/configure" "$@"
diff --git a/configure.ac b/configure.ac
index 097d796..9fd8d35 100644
--- a/configure.ac
+++ b/configure.ac
@@ -20,26 +20,33 @@
 #
 # Process this file with autoconf to produce a configure script
 
-AC_PREREQ(2.57)
+AC_PREREQ([2.63])
 AC_INIT([intel-gpu-tools],
-        1.0.2,
+        [1.0.2],
         [https://bugs.freedesktop.org/enter_bug.cgi?product=xorg],
-        intel-gpu-tools)
+        [intel-gpu-tools])
 
 AC_CONFIG_SRCDIR([Makefile.am])
-AM_CONFIG_HEADER([config.h])
-AC_CONFIG_AUX_DIR(.)
+AC_CONFIG_HEADERS([config.h])
+AC_CONFIG_MACRO_DIR([m4])
+AC_CONFIG_AUX_DIR([build-aux])
 
-AM_INIT_AUTOMAKE([dist-bzip2])
+AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2])
+AM_MAINTAINER_MODE([enable])
 
-AM_MAINTAINER_MODE
+# Support silent build rules, requires at least automake-1.11. Disable
+# by either passing --disable-silent-rules to configure or passing V=1
+# to make
+m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
 
 # Checks for programs.
-AC_DISABLE_STATIC
-AC_PROG_LIBTOOL
 AC_PROG_CC
 AM_PROG_CC_C_O
 
+# Initialize libtool
+LT_PREREQ([2.2])
+LT_INIT([disable-static])
+
 PKG_CHECK_MODULES(DRM, [libdrm_intel >= 2.4.23], have_drm=yes, have_drm=no)
 if test "x$have_drm" = "xyes"; then
 	AC_DEFINE([HAVE_DRM], 1, [Define to 1 if we have DRM support])
@@ -82,7 +89,7 @@ m4_ifndef([XORG_MACROS_VERSION], [AC_FATAL([must install xorg-macros 1.3 or late
 XORG_MACROS_VERSION(1.3)
 XORG_DEFAULT_OPTIONS
 
-AC_OUTPUT([
+AC_CONFIG_FILES([
 	Makefile
 	benchmarks/Makefile
 	lib/Makefile
@@ -90,3 +97,4 @@ AC_OUTPUT([
 	tests/Makefile
 	tools/Makefile
 ])
+AC_OUTPUT
diff --git a/m4/.gitignore b/m4/.gitignore
new file mode 100644
index 0000000..464ba5c
--- /dev/null
+++ b/m4/.gitignore
@@ -0,0 +1,5 @@
+libtool.m4
+lt~obsolete.m4
+ltoptions.m4
+ltsugar.m4
+ltversion.m4
-- 
1.7.4


[-- Attachment #3: Type: text/plain, Size: 159 bytes --]

_______________________________________________
Intel-gfx mailing list
Intel-gfx@lists.freedesktop.org
http://lists.freedesktop.org/mailman/listinfo/intel-gfx

Re: [patch] Update autotools configuration

[Javier Jardón]

2011/2/9 Javier Jardón <jjardon@gnome.org>:
> Simple patch to update the autotools configuration.

Sorry, I forgot to mention that the patch is for the intel-gpu-tools project

Regards
-- 
Javier Jardón Cabezas
_______________________________________________
Intel-gfx mailing list
Intel-gfx@lists.freedesktop.org
http://lists.freedesktop.org/mailman/listinfo/intel-gfx

Re: [patch] Update autotools configuration

[Chris Wilson]

[-- Attachment #1: Type: text/plain, Size: 487 bytes --]

On Wed, 9 Feb 2011 00:20:23 +0000, Javier Jardón <jjardon@gnome.org> wrote:
> Simple patch to update the autotools configuration.
> 
> It replaces deprecated autoconf macros and use the new libtool syntax.
> Also It uses silent-rules to make the build less verbose (linux-like).

It's always a pleasure when someone comes along and improves the build
system. Thank you!

I hear Mesa is looking for a build maintainer... ;-)
-Chris

-- 
Chris Wilson, Intel Open Source Technology Centre

[-- Attachment #2: Type: text/plain, Size: 159 bytes --]

_______________________________________________
Intel-gfx mailing list
Intel-gfx@lists.freedesktop.org
http://lists.freedesktop.org/mailman/listinfo/intel-gfx