From: Nicholas Mc Guire <der.herr@hofr.at>
To: Namhyung Kim <namhyung@gmail.com>
Cc: Christopher Li <sparse@chrisli.org>, linux-sparse@vger.kernel.org
Subject: Re: [PATCH] use ARRAY_SIZE() when possible
Date: Thu, 9 Dec 2010 13:36:02 +0100 [thread overview]
Message-ID: <20101209123602.GB5470@opentech.at> (raw)
In-Reply-To: <1291894020-3388-1-git-send-email-namhyung@gmail.com>
On Thu, 09 Dec 2010, Namhyung Kim wrote:
> Convert (sizeof arr / sizeof arr[0]) to ARRAY_SIZE(arr).
>
would that not be a cadidate for coccinelle/spatch rather than a potentially
error prone and repetitive manual patch?
array.cocci from the current 0.4.2 coccinelle distribution below should du
the job.
Might make sense to add a coccinelle directory in sparse to handle such cases ?
hofrat
// Use the macro ARRAY_SIZE when possible
//
// Confidence: High
// Copyright: (C) Gilles Muller, Julia Lawall, EMN, INRIA, DIKU. GPLv2.
// URL: http://coccinelle.lip6.fr/rules/array.html
// Options: -I ... -all_includes can give more complete results
virtual org
virtual patch
@i@
@@
#include <linux/kernel.h>
/////////////////////////////////////
/////////////////////////////////////
@depends on i && patch && !org@
type T;
T[] E;
@@
- (sizeof(E)/sizeof(*E))
+ ARRAY_SIZE(E)
@depends on i && patch && !org@
type T;
T[] E;
@@
- (sizeof(E)/sizeof(E[...]))
+ ARRAY_SIZE(E)
@depends on i && patch && !org@
type T;
T[] E;
@@
- (sizeof(E)/sizeof(T))
+ ARRAY_SIZE(E)
@n_patch depends on patch && !org@
identifier AS,E;
@@
- #define AS(E) ARRAY_SIZE(E)
@ depends on patch && !org@
expression E;
identifier n_patch.AS;
@@
- AS(E)
+ ARRAY_SIZE(E)
/////////////////////////////////////
/////////////////////////////////////
@arr_ptr depends on i && !patch && org@
type T;
T[] E;
position p;
@@
(sizeof(E@p)/sizeof(*E))
@arr_tab depends on i && !patch && org@
type T;
T[] E;
position p;
@@
(sizeof(E@p)/sizeof(E[...]))
@arr_typ depends on i && !patch && org@
type T;
T[] E;
position p;
@@
(sizeof(E@p)/sizeof(T))
@n_org depends on !patch && org@
identifier AS,E;
@@
#define AS(E) ARRAY_SIZE(E)
@arr_def depends on !patch && org@
expression E;
identifier n_org.AS;
position p;
@@
AS@p(E)
@script:python@
p << arr_ptr.p;
e << arr_ptr.E;
@@
cocci.print_main(e,p)
@script:python@
p << arr_tab.p;
e << arr_tab.E;
@@
cocci.print_main(e,p)
@script:python@
p << arr_typ.p;
e << arr_typ.E;
@@
cocci.print_main(e,p)
@script:python@
p << arr_def.p;
e << arr_def.E;
@@
cocci.print_main(e,p)
next prev parent reply other threads:[~2010-12-09 12:47 UTC|newest]
Thread overview: 4+ messages / expand[flat|nested] mbox.gz Atom feed top
2010-12-09 11:27 [PATCH] use ARRAY_SIZE() when possible Namhyung Kim
2010-12-09 12:36 ` Nicholas Mc Guire [this message]
2010-12-10 8:56 ` Christopher Li
2010-12-10 8:51 ` Christopher Li
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20101209123602.GB5470@opentech.at \
--to=der.herr@hofr.at \
--cc=linux-sparse@vger.kernel.org \
--cc=namhyung@gmail.com \
--cc=sparse@chrisli.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).