Re: [PATCH v3] coccinelle: semantic patch to check for inappropriate do_div() calls

Julia Lawall
2020-01-11T15:36:33Z

On Fri, 10 Jan 2020, Wen Yang wrote:

> do_div() does a 64-by-32 division.
> When the divisor is unsigned long, u64, or s64,
> do_div() truncates it to 32 bits, this means it
> can test non-zero and be truncated to zero for division.
> This semantic patch is inspired by Mateusz Guzik's patch:
> commit b0ab99e7736a ("sched: Fix possible divide by zero in avg_atom() calculation")
>
> Signed-off-by: Wen Yang <wenyang@linux.alibaba.com>

Acked-by: Julia Lawall <julia.lawall@inria.fr>

This looks good to me.

A small detail is that you don't need the parentheses in:

@r depends on (org || report)@

julia

> Cc: Julia Lawall <julia.lawall@inria.fr>
> Cc: Gilles Muller <Gilles.Muller@lip6.fr>
> Cc: Nicolas Palix <nicolas.palix@imag.fr>
> Cc: Michal Marek <michal.lkml@markovi.net>
> Cc: Matthias Maennich <maennich@google.com>
> Cc: Greg Kroah-Hartman <gregkh@linuxfoundation.org>
> Cc: Masahiro Yamada <yamada.masahiro@socionext.com>
> Cc: Thomas Gleixner <tglx@linutronix.de>
> Cc: cocci@systeme.lip6.fr
> Cc: linux-kernel@vger.kernel.org
> ---
> v3:
> - also filter out safe consts for context mode.
> - cleanup code.
>
> v2:
> - add a special case for constants and checking whether the value is obviously safe and no warning is needed.
> - fix 'WARNING:' twice in each case.
> - extend the warning to say "consider using div64_xxx instead".
>
> scripts/coccinelle/misc/do_div.cocci | 155 +++++++++++++++++++++++++++
> 1 file changed, 155 insertions(+)
> create mode 100644 scripts/coccinelle/misc/do_div.cocci
>
> diff --git a/scripts/coccinelle/misc/do_div.cocci b/scripts/coccinelle/misc/do_div.cocci
> new file mode 100644
> index 000000000000..79db083c5208
> --- /dev/null
> +++ b/scripts/coccinelle/misc/do_div.cocci
> @@ -0,0 +1,155 @@
> +// SPDX-License-Identifier: GPL-2.0-only
> +/// do_div() does a 64-by-32 division.
> +/// When the divisor is long, unsigned long, u64, or s64,
> +/// do_div() truncates it to 32 bits, this means it can test
> +/// non-zero and be truncated to 0 for division on 64bit platforms.
> +///
> +//# This makes an effort to find those inappropriate do_div() calls.
> +//
> +// Confidence: Moderate
> +// Copyright: (C) 2020 Wen Yang, Alibaba.
> +// Comments:
> +// Options: --no-includes --include-headers
> +
> +virtual context
> +virtual org
> +virtual report
> +
> +@initialize:python@
> +@@
> +
> +def get_digit_type_and_value(str):
> + is_digit = False
> + value = 0
> +
> + try:
> + if (str.isdigit()):
> + is_digit = True
> + value = int(str, 0)
> + elif (str.upper().endswith('ULL')):
> + is_digit = True
> + value = int(str[:-3], 0)
> + elif (str.upper().endswith('LL')):
> + is_digit = True
> + value = int(str[:-2], 0)
> + elif (str.upper().endswith('UL')):
> + is_digit = True
> + value = int(str[:-2], 0)
> + elif (str.upper().endswith('L')):
> + is_digit = True
> + value = int(str[:-1], 0)
> + elif (str.upper().endswith('U')):
> + is_digit = True
> + value = int(str[:-1], 0)
> + except Exception as e:
> + print('Error:',e)
> + is_digit = False
> + value = 0
> + finally:
> + return is_digit, value
> +
> +def filter_out_safe_constants(str):
> + is_digit, value = get_digit_type_and_value(str)
> + if (is_digit):
> + if (value >= 0x100000000):
> + return True
> + else:
> + return False
> + else:
> + return True
> +
> +def construct_warnings(suggested_fun):
> + msg="WARNING: do_div() does a 64-by-32 division, please consider using %s instead."
> + return msg % suggested_fun
> +
> +@depends on context@
> +expression f;
> +long l: script:python() { filter_out_safe_constants(l) };
> +unsigned long ul : script:python() { filter_out_safe_constants(ul) };
> +u64 ul64 : script:python() { filter_out_safe_constants(ul64) };
> +s64 sl64 : script:python() { filter_out_safe_constants(sl64) };
> +
> +@@
> +(
> +* do_div(f, l);
> +|
> +* do_div(f, ul);
> +|
> +* do_div(f, ul64);
> +|
> +* do_div(f, sl64);
> +)
> +
> +@r depends on (org || report)@
> +expression f;
> +position p;
> +long l: script:python() { filter_out_safe_constants(l) };
> +unsigned long ul : script:python() { filter_out_safe_constants(ul) };
> +u64 ul64 : script:python() { filter_out_safe_constants(ul64) };
> +s64 sl64 : script:python() { filter_out_safe_constants(sl64) };
> +@@
> +(
> +do_div@p(f, l);
> +|
> +do_div@p(f, ul);
> +|
> +do_div@p(f, ul64);
> +|
> +do_div@p(f, sl64);
> +)
> +
> +@script:python depends on org@
> +p << r.p;
> +ul << r.ul;
> +@@
> +
> +coccilib.org.print_todo(p[0], construct_warnings("div64_ul"))
> +
> +@script:python depends on org@
> +p << r.p;
> +l << r.l;
> +@@
> +
> +coccilib.org.print_todo(p[0], construct_warnings("div64_long"))
> +
> +@script:python depends on org@
> +p << r.p;
> +ul64 << r.ul64;
> +@@
> +
> +coccilib.org.print_todo(p[0], construct_warnings("div64_u64"))
> +
> +@script:python depends on org@
> +p << r.p;
> +sl64 << r.sl64;
> +@@
> +
> +coccilib.org.print_todo(p[0], construct_warnings("div64_s64"))
> +
> +@script:python depends on report@
> +p << r.p;
> +ul << r.ul;
> +@@
> +
> +coccilib.report.print_report(p[0], construct_warnings("div64_ul"))
> +
> +@script:python depends on report@
> +p << r.p;
> +l << r.l;
> +@@
> +
> +coccilib.report.print_report(p[0], construct_warnings("div64_long"))
> +
> +@script:python depends on report@
> +p << r.p;
> +sl64 << r.sl64;
> +@@
> +
> +coccilib.report.print_report(p[0], construct_warnings("div64_s64"))
> +
> +@script:python depends on report@
> +p << r.p;
> +ul64 << r.ul64;
> +@@
> +
> +coccilib.report.print_report(p[0], construct_warnings("div64_u64"))
> --
> 2.23.0
>
>