[PATCH v5] coccinelle: misc: Add field_modify script

[PATCH v5] coccinelle: misc: Add field_modify script

[Luo Jie]

Find and suggest conversions of opencoded field modify patterns with
the wrapper FIELD_MODIFY() API defined in include/linux/bitfield.h
for catching the possible parameter type error in the compile time.

Signed-off-by: Luo Jie <quic_luoj@quicinc.com>
---
Add the helper FIELD_MODIFY() to the FIELD_XXX family of bitfield
macros. It is functionally similar as xxx_replace_bits(), but adds
the compile time checking to catch incorrect parameter type errors.

This series also converts the four instances of opencoded FIELD_MODIFY()
that are found in the core kernel files, to instead use the new
FIELD_MODIFY() macro. This is achieved with Coccinelle, by adding
the script field_modify.cocci.

The changes are validated on IPQ9574 SoC which uses ARM64 architecture.
---
Changes in v5:
- Remove ARM64 patches based on the discussion in v3 and v4 versions of
  this series.
- Simplify the condition selections in coccinelle script.
- Link to v4: https://lore.kernel.org/r/20250612-field_modify-v4-0-ae4f74da45a6@quicinc.com

Changes in v4:
- Add org, report and context mode for coccinelle script.
- Fix other comments on coccinelle script patch.
- Remove the FIELD_MODIFY patch as it is merged.
- Link to v3: https://lore.kernel.org/r/20250417-field_modify-v3-0-6f7992aafcb7@quicinc.com

Changes in v3:
- Correct the order of header files included.
- Add the Coccinelle script field_modify.cocci..
- Convert the opencoded FIELD_MODIFY() variants inside arm64 directory,
  identified by field_modify.cocci.
- Link to v2: https://lore.kernel.org/all/20250410131048.2054791-1-quic_luoj@quicinc.com/

Changes in v2:
- Update the documented example for FIELD_MODIFY().
- Improve the commit message to describe the need for the change.
- Link to v1: https://lore.kernel.org/all/20250318071526.1836194-1-quic_luoj@quicinc.com/
---
 scripts/coccinelle/misc/field_modify.cocci | 60 ++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git a/scripts/coccinelle/misc/field_modify.cocci b/scripts/coccinelle/misc/field_modify.cocci
new file mode 100644
index 000000000000..7d4858c0a68d
--- /dev/null
+++ b/scripts/coccinelle/misc/field_modify.cocci
@@ -0,0 +1,60 @@
+// SPDX-License-Identifier: GPL-2.0-only
+/// Replace below code with the wrapper FIELD_MODIFY(MASK, &reg, val)
+/// - reg &= ~MASK;
+/// - reg |= FIELD_PREP(MASK, val);
+//
+// Confidence: High
+// Author: Luo Jie <quic_luoj@quicinc.com>
+// Copyright: (C) 2025 Qualcomm Innovation Center, Inc.
+// Keywords: FIELD_PREP, FIELD_MODIFY
+// Options: --include-headers
+
+virtual context
+virtual patch
+virtual org
+virtual report
+
+@depends on context@
+identifier reg, val;
+constant mask;
+symbol FIELD_PREP;
+@@
+
+*reg &= ~mask;
+*reg |= FIELD_PREP(mask, val);
+
+@depends on patch@
+identifier reg, val;
+constant mask;
+symbol FIELD_PREP, FIELD_MODIFY;
+@@
+
+-reg &= ~mask;
+-reg |= FIELD_PREP(mask, val);
++FIELD_MODIFY(mask, &reg, val);
+
+@r depends on org || report@
+identifier reg, val;
+constant mask;
+symbol FIELD_PREP;
+position p;
+@@
+
+reg &= ~mask;
+reg |= FIELD_PREP@p(mask, val);
+
+@script:python depends on report@
+p << r.p;
+x << r.reg;
+@@
+
+coccilib.report.print_report(p[0], "WARNING: Consider using FIELD_MODIFY helper on %s" % (x))
+
+@script:python depends on org@
+p << r.p;
+x << r.reg;
+@@
+
+msg="WARNING: Consider using FIELD_MODIFY helper on %s" % (x)
+msg_safe=msg.replace("[","@(").replace("]",")")
+coccilib.org.print_todo(p[0], msg_safe)

---
base-commit: 0bb71d301869446810a0b13d3da290bd455d7c78
change-id: 20250612-field_modify-27139f673881

Best regards,
-- 
Luo Jie <quic_luoj@quicinc.com>

Re: [PATCH v5] coccinelle: misc: Add field_modify script

[Markus Elfring]

> +msg="WARNING: Consider using FIELD_MODIFY helper on %s" % (x)
> +msg_safe=msg.replace("[","@(").replace("]",")")
> +coccilib.org.print_todo(p[0], msg_safe)

How do you think about to use the following code variant instead?

msg = f"WARNING: Consider using FIELD_MODIFY helper on {x}"
coccilib.org.print_todo(p[0], msg.replace("[","@(").replace("]",")"))


Regards,
Markus

Re: [PATCH v5] coccinelle: misc: Add field_modify script

[Luo Jie]

On 6/24/2025 9:54 PM, Markus Elfring wrote:
>> +msg="WARNING: Consider using FIELD_MODIFY helper on %s" % (x)
>> +msg_safe=msg.replace("[","@(").replace("]",")")
>> +coccilib.org.print_todo(p[0], msg_safe)
> 
> How do you think about to use the following code variant instead?
> 
> msg = f"WARNING: Consider using FIELD_MODIFY helper on {x}"
> coccilib.org.print_todo(p[0], msg.replace("[","@(").replace("]",")"))
> 

I think your proposed variant is a better alternative. I will adopt
it in the next revision. Thanks.

> 
> Regards,
> Markus