[PATCH net-next] selftests/net: packetdrill: add tcp_disorder_fin_in_FIN_WAIT.pkt

[PATCH net-next] selftests/net: packetdrill: add tcp_disorder_fin_in_FIN_WAIT.pkt

[Eric Dumazet]

Commit 795a7dfbc3d9 ("net: tcp: accept old ack during closing")
was fixing an old bug, add a test to make sure we won't break
this case in future kernels.

Signed-off-by: Eric Dumazet <edumazet@google.com>
Cc: Menglong Dong <menglong8.dong@gmail.com>
---
 .../tcp_disorder_fin_in_FIN_WAIT.pkt          | 33 +++++++++++++++++++
 1 file changed, 33 insertions(+)
 create mode 100644 tools/testing/selftests/net/packetdrill/tcp_disorder_fin_in_FIN_WAIT.pkt

diff --git a/tools/testing/selftests/net/packetdrill/tcp_disorder_fin_in_FIN_WAIT.pkt b/tools/testing/selftests/net/packetdrill/tcp_disorder_fin_in_FIN_WAIT.pkt
new file mode 100644
index 0000000000000000000000000000000000000000..336cbf7815c86cfdbc44a3322413abf0bfed1516
--- /dev/null
+++ b/tools/testing/selftests/net/packetdrill/tcp_disorder_fin_in_FIN_WAIT.pkt
@@ -0,0 +1,33 @@
+// SPDX-License-Identifier: GPL-2.0
+
+// Check fix in 795a7dfbc3d9 ("net: tcp: accept old ack during closing")
+
+// Set up config.
+`./defaults.sh`
+
+// Initialize a server socket.
+    0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+   +0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+   +0 bind(3, ..., ...) = 0
+   +0 listen(3, 1) = 0
+
+   +0 < S  0:0(0) win 65535 <mss 1000,sackOK,nop,nop,nop,wscale 7>
+   *  > S. 0:0(0) ack 1 <mss 1460,nop,nop,sackOK,nop,wscale 8>
+   +0 < .  1:1(0) ack 1 win 257
+
+   +0 accept(3, ..., ...) = 4
+
+   +0 shutdown(4, SHUT_WR) = 0
+   *  > F. 1:1(0) ack 1
+
+// We expect to receive one ACK.
+// But what happens if a FIN was already in transmt and received out-of-order ?
+
+   +0 < .  2:2(0) ack 2 win 257
+
+// This FIN packet was sent before the prior ACK (see ack 1).
+   +0 < F. 1:1(0) ack 1 win 257
+
+// Even if the FIN is received out-of-order, we should ACK it.
+
+   *  > .  2:2(0) ack 2
-- 
2.53.0.880.g73c4285caa-goog

Re: [PATCH net-next] selftests/net: packetdrill: add tcp_disorder_fin_in_FIN_WAIT.pkt

[patchwork-bot+netdevbpf]

Hello:

This patch was applied to netdev/net-next.git (main)
by Jakub Kicinski <kuba@kernel.org>:

On Fri, 13 Mar 2026 11:54:29 +0000 you wrote:
> Commit 795a7dfbc3d9 ("net: tcp: accept old ack during closing")
> was fixing an old bug, add a test to make sure we won't break
> this case in future kernels.
> 
> Signed-off-by: Eric Dumazet <edumazet@google.com>
> Cc: Menglong Dong <menglong8.dong@gmail.com>
> 
> [...]

Here is the summary with links:
  - [net-next] selftests/net: packetdrill: add tcp_disorder_fin_in_FIN_WAIT.pkt
    https://git.kernel.org/netdev/net-next/c/4686679a14d2

You are awesome, thank you!
-- 
Deet-doot-dot, I am a bot.
https://korg.docs.kernel.org/patchwork/pwbot.html