netdev.vger.kernel.org archive mirror
 help / color / mirror / Atom feed
* [PATCH 0/13] make return of 0 explicit
@ 2014-05-19  4:31 Julia Lawall
  2014-05-19  4:31 ` [PATCH 1/13] libertas: " Julia Lawall
                   ` (3 more replies)
  0 siblings, 4 replies; 18+ messages in thread
From: Julia Lawall @ 2014-05-19  4:31 UTC (permalink / raw)
  To: brcm80211-dev-list
  Cc: devel, linux-s390, alsa-devel, linux-scsi, libertas-dev,
	linux-wireless, linux-usb, kernel-janitors, linux-kernel,
	linux-raid, coreteam, netfilter-devel, netdev, oprofile-list,
	netfilter

Sometimes a local variable is used as a return value in a case where the
return value is always 0.  The result is more apparent if this variable is
just replaced by 0.  This is done by the following semantic patch, although
some cleanups may be needed. (http://coccinelle.lip6.fr/)

// <smpl>
@r exists@
local idexpression ret;
identifier reti;
expression e;
position p;
@@

ret@reti = 0;
... when != \(ret = e\|ret &= e\|ret |= e\|ret += e\|ret -= e\|ret *= e\|ret ^= e\)
    when != \(++ret\|--ret\|ret++\|ret--\)
    when != &ret
return ret;@p

@bad1 exists@
expression e != 0;
local idexpression r.ret;
position r.p;
@@

 \(ret = e\|ret &= e\|ret |= e\|ret += e\|ret -= e\|ret *= e\|ret ^= e\|++ret\|--ret\|ret++\|ret--\|&ret\)
 ...
 return ret;@p

@bad2 exists@
identifier r.reti;
position r.p;
identifier f;
type T;
@@

f(...,T reti,...) {
 ...
 return reti;@p
}

@change depends on !bad1 && !bad2@
position r.p;
local idexpression r.ret;
identifier f;
@@

f(...) { <+...
return 
-ret
+0
;@p
...+> }

@rewrite@
local idexpression r.ret;
expression e;
position p;
identifier change.f;
@@

f(...) { <+...
 \(ret@p = e\|&ret@p\)
...+> }

@depends on change@
local idexpression r.ret;
position p != rewrite.p;
identifier change.f;
@@

f(...) { <+...
(
break;
|
ret = 0;
... when exists
ret@p
... when any
|
- ret = 0;
)
...+> }

@depends on change@
identifier r.reti;
type T;
constant C;
identifier change.f;
@@

f(...) { ... when any
-T reti = C;
 ... when != reti
     when strict
 }

@depends on change@
identifier r.reti;
type T;
identifier change.f;
@@

f(...) { ... when any
-T reti;
 ... when != reti
     when strict
 }
// </smpl>

The first four rules detect cases where only 0 reaches a return.  The
remaining rules clean up any variable initializations or declarations that
are made unnecessary by this change.

^ permalink raw reply	[flat|nested] 18+ messages in thread
end of thread, other threads:[~2014-05-22 21:57 UTC | newest]

Thread overview: 18+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-05-19  4:31 [PATCH 0/13] make return of 0 explicit Julia Lawall
2014-05-19  4:31 ` [PATCH 1/13] libertas: " Julia Lawall
2014-05-19  7:43   ` walter harms
2014-05-19 12:45   ` Sergei Shtylyov
2014-05-19 17:25     ` Dan Williams
2014-05-22 12:32       ` [PATCH] libertas: fix return value when processing invalid packet Dan Williams
2014-05-22 21:57         ` James Cameron
2014-05-20  0:30     ` [PATCH 1/13] libertas: make return of 0 explicit Julia Lawall
2014-05-20  0:36     ` Julia Lawall
2014-05-19  4:31 ` [PATCH 4/13] wimax/i2400m: " Julia Lawall
2014-05-19  7:47   ` walter harms
2014-05-19 11:30     ` Julia Lawall
2014-05-19 13:22       ` walter harms
2014-05-19 12:46   ` Sergei Shtylyov
2014-05-20  0:44     ` [PATCH 4/13 v2] " Julia Lawall
2014-05-21 21:19       ` David Miller
2014-05-19  4:31 ` [PATCH 6/13] [NETFILTER]: arp_tables: " Julia Lawall
2014-05-19  4:31 ` [PATCH 12/13] brcmsmac: " Julia Lawall

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).