Re: [PATCH 1/2] insane.bbclass: Add test for static .a libraries in non-staticdev packages

[Richard Purdie <richard.purdie@linuxfoundation.org>]

On Tue, 2012-01-24 at 17:49 -0800, Saul Wold wrote:
> This check verifies that non staticdev and non pic packages do not
> have static libraries in them. There are a few exceptions for the
> libgcc-dev and libgcov-dev packages which are whitelisted, also the
> *_nonshared.a need to be part of their respective -dev packages.
> 
> This is currently a warning to work out any other issues in the upper
> layers but will be moved to ERROR at somepoint in the future.
> 
> [YOCTO #663]
> 
> Signed-off-by: Saul Wold <sgw@linux.intel.com>
> ---
>  meta/classes/insane.bbclass |   20 +++++++++++++++++++-
>  1 files changed, 19 insertions(+), 1 deletions(-)
> 
> diff --git a/meta/classes/insane.bbclass b/meta/classes/insane.bbclass
> index ce21496..7aea73b 100644
> --- a/meta/classes/insane.bbclass
> +++ b/meta/classes/insane.bbclass
> @@ -109,7 +109,7 @@ def package_qa_get_machine_dict():
>  
> 
>  # Currently not being used by default "desktop"
> -WARN_QA ?= "ldflags useless-rpaths rpaths unsafe-references-in-binaries unsafe-references-in-scripts"
> +WARN_QA ?= "ldflags useless-rpaths rpaths unsafe-references-in-binaries unsafe-references-in-scripts staticdev"
>  ERROR_QA ?= "dev-so debug-deps dev-deps debug-files arch la2 pkgconfig la perms"
>  
>  def package_qa_clean_path(path,d):
> @@ -192,6 +192,24 @@ def package_qa_check_dev(path, name, d, elf, messages):
>          messages.append("non -dev/-dbg/-nativesdk package contains symlink .so: %s path '%s'" % \
>                   (name, package_qa_clean_path(path,d)))
>  
> +QAPATHTEST[staticdev] = "package_qa_check_staticdev"
> +
> +# These 2 packages contain archive libraries that need to be in -dev
> +STATICDEV_WHITELIST = "libgcc-dev libgcov-dev"
> +def package_qa_check_staticdev(path, name, d, elf, messages):
> +    """
> +    Check for ".a" library in non-staticdev packages, use a STATICDEV_WHITELIST
> +    for exceptions
> +    """
> +
> +    import re
> +    staticdev_whitelist = d.getVar('STATICDEV_WHITELIST', True)
> +    if (staticdev_whitelist.find(name) != -1):
> +        return
> +    if not name.endswith("-pic") and not name.endswith("-staticdev") and path.endswith(".a") and not path.endswith("_nonshared.a"):
> +        messages.append("non -staticdev package contains static .a library: %s path '%s'" % \
> +                 (name, package_qa_clean_path(path,d)))
> +
>  QAPATHTEST[debug-files] = "package_qa_check_dbg"
>  def package_qa_check_dbg(path, name, d, elf, messages):
>      """

Looks good but instead of adding STATICDEV_WHITELIST, could we set:

INSANE_SKIP_libgcc-dev = "staticdev"
INSANE_SKIP_libgcov-dev = "staticdev"

in the gcc recipe and use the existing code to handle that?

Cheers,

Richard