Re: [PATCH 06/24] gobject-introspection.bbclass: add a class that enables gobject introspection

[Martin Jansa <martin.jansa@gmail.com>]

[-- Attachment #1: Type: text/plain, Size: 3416 bytes --]

On Thu, Mar 10, 2016 at 12:52:20AM +0100, Andreas Oberritter wrote:
> Hello Alexander,
> 
> On 09.03.2016 16:01, Alexander Kanavin wrote:
> > Signed-off-by: Alexander Kanavin <alexander.kanavin@linux.intel.com>
> > ---
> >  meta/classes/gobject-introspection.bbclass | 39 ++++++++++++++++++++++++++++++
> >  1 file changed, 39 insertions(+)
> >  create mode 100644 meta/classes/gobject-introspection.bbclass
> > 
> > diff --git a/meta/classes/gobject-introspection.bbclass b/meta/classes/gobject-introspection.bbclass
> > new file mode 100644
> > index 0000000..ef51629
> > --- /dev/null
> > +++ b/meta/classes/gobject-introspection.bbclass
> > @@ -0,0 +1,39 @@
> > +# Inherit this class in recipes to enable building their introspection files
> > +
> > +# This allows disabling introspection support in recipes
> > +# (and therefore avoiding the use of qemu)
> > +# if gobject-introspection-data is omitted from DISTRO_FEATURES and MACHINE_FEATURES.
> > +EXTRA_OECONF_prepend = "${@bb.utils.contains('COMBINED_FEATURES', 'gobject-introspection-data', '--enable-introspection', '--disable-introspection', d)} "
> 
> testing only DISTRO_FEATURES would be better. If MACHINE_FEATURES gets
> tested, even though indirectly, I'd expect every recipe inheriting this
> class to switch to MACHINE_ARCH implicitly.

I think the idea was to prevent using qemu for MACHINEs without support
in qemu. But I fully agree that causing all recipes which inherit this
bbclass effectively MACHINE_ARCH is even worse.

DISTRO needs to make sure that all supported MACHINEs have support in
qemu or disable introspection for all of them.

> It's not a feature that depends on any type of hardware design.


> 
> Regards,
> Andreas
> 
> > +
> > +UNKNOWN_CONFIGURE_WHITELIST_append = " --enable-introspection --disable-introspection"
> > +
> > +# Generating introspection data depends on a combination of native and target introspection tools,
> > +# and qemu to run the target tools.
> > +DEPENDS_append = " gobject-introspection gobject-introspection-native qemu-native"
> > +
> > +# This is necessary for python scripts to succeed - distutils
> > +# failes if these are not set
> > +export BUILD_SYS
> > +export HOST_SYS
> > +export STAGING_LIBDIR
> > +export STAGING_INCDIR
> > +
> > +# This is used by introspection tools to find .gir includes
> > +export XDG_DATA_DIRS = "${STAGING_DATADIR}"
> > +
> > +do_configure_prepend_class-target () {
> > +    # introspection.m4 pre-packaged with upstream tarballs does not yet
> > +    # have our fixes
> > +    mkdir -p ${S}/m4
> > +    cp ${STAGING_DIR_TARGET}/${datadir}/aclocal/introspection.m4 ${S}/m4
> > +}
> > +
> > +
> > +# .typelib files are needed at runtime and so they go to the main package
> > +# (so they'll be together with libraries they support).
> > +FILES_${PN}_append = " ${libdir}/girepository-*/*.typelib" 
> > +    
> > +# .gir files go to dev package, as they're needed for developing (but not for running)
> > +# things that depends on introspection.
> > +FILES_${PN}-dev_append = " ${datadir}/gir-*/*.gir"
> > +
> > 
> 
> -- 
> _______________________________________________
> Openembedded-core mailing list
> Openembedded-core@lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-core

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa@gmail.com

[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 188 bytes --]