[PATCH 2/2] libxml-namespacesupport: use stable v1.12 release; inherit ptest-perl

[Tim Orling <timothy.t.orling@linux.intel.com>]

* Fix RDEPENDS
* Upstream v1.12_9 is a development version, not a stable release
* Add UPSTREAM_CHECK_REGEX skip development releases
* Drop anonymous python function to "fix" version, which breaks
  auto-upgrade-helper (AUH)
* Use LICENSE file for checksum rather than ephemeral META.yml
* License remains the same

Fixes: [YOCTO #12581]

License-Update: use LICENSE file for checksum

Signed-off-by: Tim Orling <timothy.t.orling@linux.intel.com>
---
 .../perl/libxml-namespacesupport-perl_1.12.9.bb    | 35 ----------------------
 .../perl/libxml-namespacesupport-perl_1.12.bb      | 27 +++++++++++++++++
 2 files changed, 27 insertions(+), 35 deletions(-)
 delete mode 100644 meta/recipes-extended/perl/libxml-namespacesupport-perl_1.12.9.bb
 create mode 100644 meta/recipes-extended/perl/libxml-namespacesupport-perl_1.12.bb

diff --git a/meta/recipes-extended/perl/libxml-namespacesupport-perl_1.12.9.bb b/meta/recipes-extended/perl/libxml-namespacesupport-perl_1.12.9.bb
deleted file mode 100644
index a7d26ea38c..0000000000
--- a/meta/recipes-extended/perl/libxml-namespacesupport-perl_1.12.9.bb
+++ /dev/null
@@ -1,35 +0,0 @@
-SUMMARY = "Perl module for supporting simple generic namespaces"
-HOMEPAGE = "http://veillard.com/XML/"
-DESCRIPTION = "XML::NamespaceSupport offers a simple way to process namespace-based XML names. \
-                It also helps maintain a prefix-to-namespace URI map, and provides a number of \
-                basic checks. "
-
-SECTION = "libs"
-LICENSE = "Artistic-1.0 | GPL-1.0+"
-PR = "r3"
-
-LIC_FILES_CHKSUM = "file://META.yml;beginline=22;endline=22;md5=9ca1a4a941496e7feedac72c4fb8b137"
-
-# the upstream project complicate a bit url generartion on point release, using a underscore
-# instead of a point on URL, i.e 1.12_9 instead of 1.12.9
-python () {
-    baseurl = "http://search.cpan.org/CPAN/authors/id/P/PE/PERIGRIN/XML-NamespaceSupport"
-    pv = d.getVar('PV')
-    pvsplit = pv.split('.')
-
-    if len(pvsplit) != 3:
-        d.setVar('SRC_URI', "%s-%s.tar.gz" % (baseurl, pv))
-        d.setVar('S', "${WORKDIR}/XML-NamespaceSupport-${PV}")
-    else:
-        pvx, pvy, pvz = pvsplit
-        d.setVar('SRC_URI', "%s-%s.%s_%s.tar.gz" % (baseurl, pvx, pvy, pvz))
-        d.setVar('S', "${WORKDIR}/XML-NamespaceSupport-%s.%s_%s" % (pvx, pvy, pvz))
-}
-
-SRC_URI[md5sum] = "165927a311fb640961b28607035beab8"
-SRC_URI[sha256sum] = "2e84a057f0a8c845a612d212742cb94fca4fc8a433150b5721bd448f77d1e4a9"
-
-inherit cpan
-
-BBCLASSEXTEND="native"
-
diff --git a/meta/recipes-extended/perl/libxml-namespacesupport-perl_1.12.bb b/meta/recipes-extended/perl/libxml-namespacesupport-perl_1.12.bb
new file mode 100644
index 0000000000..fa9f9954bb
--- /dev/null
+++ b/meta/recipes-extended/perl/libxml-namespacesupport-perl_1.12.bb
@@ -0,0 +1,27 @@
+SUMMARY = "Perl module for supporting simple generic namespaces"
+HOMEPAGE = "http://veillard.com/XML/"
+DESCRIPTION = "XML::NamespaceSupport offers a simple way to process namespace-based XML names. \
+                It also helps maintain a prefix-to-namespace URI map, and provides a number of \
+                basic checks. "
+
+SECTION = "libs"
+LICENSE = "Artistic-1.0 | GPL-1.0+"
+
+SRCNAME = "XML-NamespaceSupport"
+
+LIC_FILES_CHKSUM = "file://LICENSE;md5=c9d8a117e7620b5adf8d69c29613ceab"
+
+SRC_URI = "${CPAN_MIRROR}/authors/id/P/PE/PERIGRIN/${SRCNAME}-${PV}.tar.gz"
+SRC_URI[md5sum] = "a8916c6d095bcf073e1108af02e78c97"
+SRC_URI[sha256sum] = "47e995859f8dd0413aa3f22d350c4a62da652e854267aa0586ae544ae2bae5ef"
+
+UPSTREAM_CHECK_REGEX = "XML\-NamespaceSupport\-(?P<pver>(\d+\.\d+))(?!_\d+).tar"
+
+S = "${WORKDIR}/${SRCNAME}-${PV}"
+
+inherit cpan ptest-perl
+
+RDEPENDS_${PN}-ptest += "perl-module-test-more"
+
+BBCLASSEXTEND="native"
+
-- 
2.14.3