[PATCH v2 1/2] mpdecimal: Add mpdecimal 4.0.1 as a new recipe in oe-core

[Jaipaul Cheernam <jaipaul.cheernam@est.tech>]

Python 3.15 removed the implicit fallback to the bundled copy of
libmpdec, requiring a system libmpdecimal to build the _decimal
module. [1]

- Volunteer to maintain mpdecimal

[1] https://github.com/python/cpython/issues/115119

Signed-off-by: Jaipaul Cheernam <jaipaul.cheernam@est.tech>
---
Changes Since V1:
 - Updated EXTRA_OEMAKE flags

 meta/conf/distro/include/maintainers.inc      |  1 +
 .../mpdecimal/mpdecimal_4.0.1.bb              | 23 +++++++++++++++++++
 2 files changed, 24 insertions(+)
 create mode 100644 meta/recipes-support/mpdecimal/mpdecimal_4.0.1.bb

diff --git a/meta/conf/distro/include/maintainers.inc b/meta/conf/distro/include/maintainers.inc
index 94ab0ccace..952ca58cb1 100644
--- a/meta/conf/distro/include/maintainers.inc
+++ b/meta/conf/distro/include/maintainers.inc
@@ -542,6 +542,7 @@ RECIPE_MAINTAINER:pn-mkfontscale = "Unassigned <unassigned@yoctoproject.org>"
 RECIPE_MAINTAINER:pn-mmc-utils = "Unassigned <unassigned@yoctoproject.org>"
 RECIPE_MAINTAINER:pn-mobile-broadband-provider-info = "Unassigned <unassigned@yoctoproject.org>"
 RECIPE_MAINTAINER:pn-modutils-initscripts = "Yi Zhao <yi.zhao@windriver.com>"
+RECIPE_MAINTAINER:pn-mpdecimal = "Jaipaul Cheernam <jaipaul.cheernam@est.tech>"
 RECIPE_MAINTAINER:pn-mpfr = "Khem Raj <raj.khem@gmail.com>"
 RECIPE_MAINTAINER:pn-mpg123 = "Unassigned <unassigned@yoctoproject.org>"
 RECIPE_MAINTAINER:pn-msmtp = "Wang Mingyu <wangmy@fujitsu.com>"
diff --git a/meta/recipes-support/mpdecimal/mpdecimal_4.0.1.bb b/meta/recipes-support/mpdecimal/mpdecimal_4.0.1.bb
new file mode 100644
index 0000000000..5d668a3826
--- /dev/null
+++ b/meta/recipes-support/mpdecimal/mpdecimal_4.0.1.bb
@@ -0,0 +1,23 @@
+SUMMARY = "Library for arbitrary precision decimal floating point arithmetic"
+DESCRIPTION = "mpdecimal is a C/C++ library for correctly rounded arbitrary \
+precision decimal floating point arithmetic. It is a complete implementation \
+of Mike Cowlishaw/IBM's General Decimal Arithmetic Specification and provides \
+libmpdec (C) and libmpdec++ (C++)."
+HOMEPAGE = "https://www.bytereef.org/mpdecimal/"
+SECTION = "libs"
+LICENSE = "BSD-2-Clause"
+LIC_FILES_CHKSUM = "file://COPYRIGHT.txt;md5=61bb27059c72d53804ef475f5b18d38f"
+
+SRC_URI = "https://www.bytereef.org/software/mpdecimal/releases/mpdecimal-${PV}.tar.gz"
+SRC_URI[sha256sum] = "96d33abb4bb0070c7be0fed4246cd38416188325f820468214471938545b1ac8"
+
+inherit autotools
+
+# libmpdec++ links using LDXXFLAGS instead of LDFLAGS
+EXTRA_OEMAKE += "LDXXFLAGS='${LDFLAGS}'"
+
+PACKAGES =+ "libmpdec libmpdec++"
+FILES:libmpdec = "${libdir}/libmpdec.so.*"
+FILES:libmpdec++ = "${libdir}/libmpdec++.so.*"
+
+BBCLASSEXTEND = "native nativesdk"