Re: [PATCH][jethro][RFC 1/2] libsdl: expand PACKAGECONFIG and enable native builds

[Trevor Woerner <twoerner@gmail.com>]

This patch causes my jethro build to now fail with:

ERROR: Nothing PROVIDES 'virtual/nativesdk-nativesdk-libx11' (but 
virtual:nativesdk:/z/dragon410c-repo/dragon410c-tw-jethro/layers/openembedded-core/meta/recipes-graphics/libsdl/libsdl_1.2.15.bb 
DEPENDS on or otherwise requires it). Close matches:
   virtual/nativesdk-libx11
   virtual/nativesdk-libc
   virtual/nativesdk-db



On 02/29/16 11:02, Ross Burton wrote:
> Use PACKAGECONFIG instead of using logic in DEPENDS and EXTRA_OECONF, adding new
> options for PulseAudio, tslib, DirectFB, OpenGL and X11.  Pass
> --disable-x11-shared so that it links to the X libraries instead of using
> dlopen().
>
> Disable tslib by default as the kernel event input subsystem is generally used.
>
> SDL's OpenGL support requires X11 so check for both x11 and opengl, and merge
> the dependencies.
>
> Finally enable native builds, with a minimal PACKAGECONFIG that will build from
> oe-core for native and nativesdk.
>
> (From OE-Core rev: 3d6c31c3a4ff34376e17005a981bb55fc6f7a38f)
>
> Signed-off-by: Ross Burton <ross.burton@intel.com>
> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
> ---
>   meta/recipes-graphics/libsdl/libsdl_1.2.15.bb | 35 ++++++++++++++-------------
>   1 file changed, 18 insertions(+), 17 deletions(-)
>
> diff --git a/meta/recipes-graphics/libsdl/libsdl_1.2.15.bb b/meta/recipes-graphics/libsdl/libsdl_1.2.15.bb
> index c0d5c6a..1cf3c39 100644
> --- a/meta/recipes-graphics/libsdl/libsdl_1.2.15.bb
> +++ b/meta/recipes-graphics/libsdl/libsdl_1.2.15.bb
> @@ -12,13 +12,6 @@ LIC_FILES_CHKSUM = "file://COPYING;md5=27818cd7fd83877a8e3ef82b82798ef4"
>   
>   PROVIDES = "virtual/libsdl"
>   
> -DEPENDS = "${@bb.utils.contains('DISTRO_FEATURES', 'directfb', 'directfb', '', d)} \
> -           ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'virtual/libgl', '', d)} \
> -           ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'virtual/libx11 libxext libxrandr libxrender', '', d)} \
> -           ${@bb.utils.contains('DISTRO_FEATURES', 'x11 opengl', 'libglu', '', d)} \
> -           tslib"
> -DEPENDS_class-nativesdk = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'virtual/nativesdk-libx11 nativesdk-libxrandr nativesdk-libxrender nativesdk-libxext', '', d)}"
> -
>   PR = "r3"
>   
>   SRC_URI = "http://www.libsdl.org/release/SDL-${PV}.tar.gz \
> @@ -38,21 +31,29 @@ inherit autotools lib_package binconfig-disabled pkgconfig
>   
>   EXTRA_OECONF = "--disable-static --enable-cdrom --enable-threads --enable-timers \
>                   --enable-file --disable-oss --disable-esd --disable-arts \
> -                --disable-diskaudio --disable-nas --disable-esd-shared --disable-esdtest \
> +                --disable-diskaudio --disable-nas \
>                   --disable-mintaudio --disable-nasm --disable-video-dga \
>                   --disable-video-fbcon --disable-video-ps2gs --disable-video-ps3 \
>                   --disable-xbios --disable-gem --disable-video-dummy \
> -                --enable-input-events --enable-input-tslib --enable-pthreads \
> -                ${@bb.utils.contains('DISTRO_FEATURES', 'directfb', '--enable-video-directfb', '--disable-video-directfb', d)} \
> -                ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', '--enable-video-opengl', '--disable-video-opengl', d)} \
> -                ${@bb.utils.contains('DISTRO_FEATURES', 'x11', '--enable-video-x11', '--disable-video-x11', d)} \
> +                --enable-input-events --enable-pthreads \
>                   --disable-video-svga \
>                   --disable-video-picogui --disable-video-qtopia --enable-sdl-dlopen \
> -                --disable-rpath \
> -                --disable-pulseaudio"
> +                --disable-rpath"
> +
> +PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'alsa', 'alsa', '', d)} \
> +                   ${@bb.utils.contains('DISTRO_FEATURES', 'pulseaudio', 'pulseaudio', '', d)} \
> +                   ${@bb.utils.contains('DISTRO_FEATURES', 'directfb', 'directfb', '', d)} \
> +                   ${@bb.utils.contains('DISTRO_FEATURES', 'x11 opengl', 'opengl', '', d)} \
> +                   ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11', '', d)}"
> +PACKAGECONFIG_class-native = "x11"
> +PACKAGECONFIG_class-nativesdk = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11', '', d)}"
>   
> -PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'alsa', 'alsa', '', d)}"
> -PACKAGECONFIG[alsa] = "--enable-alsa --disable-alsatest,--disable-alsa,alsa-lib,"
> +PACKAGECONFIG[alsa] = "--enable-alsa --disable-alsatest,--disable-alsa,alsa-lib"
> +PACKAGECONFIG[pulseaudio] = "--enable-pulseaudio,--disable-pulseaudio,pulseaudio"
> +PACKAGECONFIG[tslib] = "--enable-input-tslib, --disable-input-tslib, tslib"
> +PACKAGECONFIG[directfb] = "--enable-video-directfb, --disable-video-directfb, directfb"
> +PACKAGECONFIG[opengl] = "--enable-video-opengl, --disable-video-opengl, virtual/libgl libglu"
> +PACKAGECONFIG[x11] = "--enable-video-x11 --disable-x11-shared, --disable-video-x11, virtual/libx11 libxext libxrandr libxrender"
>   
>   EXTRA_AUTORECONF += "--include=acinclude --exclude=autoheader"
>   
> @@ -65,4 +66,4 @@ do_configure_prepend() {
>           export SYSROOT=$PKG_CONFIG_SYSROOT_DIR
>   }
>   
> -BBCLASSEXTEND = "nativesdk"
> +BBCLASSEXTEND = "native nativesdk"