Re: [oe-core][PATCHv9 2/4] gtk4: import recipe from meta-gnome

[Alexandre Belloni <alexandre.belloni@bootlin.com>]

Build ended, there is also this one:

| 
| ../gcr-4.0.0/docs/meson.build:1:0: ERROR: Program 'gi-docgen' not found or not executable
| 
| A full log can be found at /home/pokybuild/yocto-worker/qemux86-world-alt/build/build/tmp/work/core2-64-poky-linux/gcr/4.0.0-r0/build/meson-logs/meson-log.txt
| WARNING: Running the setup command as `meson [options]` instead of `meson setup [options]` is ambiguous and deprecated.
| ERROR: meson failed
| WARNING: exit code 1 from a shell command.
NOTE: recipe gcr-4.0.0-r0: task do_configure: Failed

https://autobuilder.yoctoproject.org/typhoon/#/builders/108/builds/3821/steps/11/logs/stdio

On 01/12/2022 12:16:59+0100, Alexandre Belloni wrote:
> This is still building but I already have:
> stdio: WARNING: Nothing PROVIDES 'iso-codes-native' (but virtual:native:/home/pokybuild/yocto-worker/build-appliance/build/meta/recipes-gnome/gtk+/gtk4_4.8.2.bb DEPENDS on or otherwise requires it). Close matches:
> stdio: WARNING: Nothing PROVIDES 'libxkbcommon-native' (but virtual:native:/home/pokybuild/yocto-worker/build-appliance/build/meta/recipes-gnome/gtk+/gtk4_4.8.2.bb DEPENDS on or otherwise requires it). Close matches:
> 
> On 01/12/2022 08:53:22+0100, Markus Volk wrote:
> > Signed-off-by: Markus Volk <f_l_k@t-online.de>
> > ---
> >  meta/recipes-gnome/gtk+/gtk4_4.8.2.bb | 130 ++++++++++++++++++++++++++
> >  1 file changed, 130 insertions(+)
> >  create mode 100644 meta/recipes-gnome/gtk+/gtk4_4.8.2.bb
> > 
> > diff --git a/meta/recipes-gnome/gtk+/gtk4_4.8.2.bb b/meta/recipes-gnome/gtk+/gtk4_4.8.2.bb
> > new file mode 100644
> > index 0000000000..dc552c5c91
> > --- /dev/null
> > +++ b/meta/recipes-gnome/gtk+/gtk4_4.8.2.bb
> > @@ -0,0 +1,130 @@
> > +SUMMARY = "Multi-platform toolkit for creating GUIs"
> > +DESCRIPTION = "GTK is a multi-platform toolkit for creating graphical user interfaces. Offering a complete \
> > +set of widgets, GTK is suitable for projects ranging from small one-off projects to complete application suites."
> > +HOMEPAGE = "http://www.gtk.org"
> > +BUGTRACKER = "https://bugzilla.gnome.org/"
> > +SECTION = "libs"
> > +
> > +DEPENDS = " \
> > +    atk \
> > +    cairo \
> > +    fribidi \
> > +    gdk-pixbuf \
> > +    gdk-pixbuf-native \
> > +    gi-docgen \
> > +    glib-2.0 \
> > +    graphene \
> > +    harfbuzz \
> > +    iso-codes \
> > +    jpeg \
> > +    libepoxy \
> > +    libpng \
> > +    librsvg \
> > +    libxkbcommon \
> > +    pango \
> > +    tiff \
> > +"
> > +
> > +LICENSE = "LGPL-2.0-only & LGPL-2.0-or-later & LGPL-2.1-or-later"
> > +LIC_FILES_CHKSUM = " \
> > +    file://COPYING;md5=5f30f0716dfdd0d91eb439ebec522ec2 \
> > +    file://gtk/gtk.h;endline=25;md5=1d8dc0fccdbfa26287a271dce88af737 \
> > +    file://gdk/gdk.h;endline=25;md5=c920ce39dc88c6f06d3e7c50e08086f2 \
> > +    file://tests/testgtk.c;endline=25;md5=49d06770681b8322466b52ed19d29fb2 \
> > +"
> > +
> > +MAJ_VER = "${@oe.utils.trim_version("${PV}", 2)}"
> > +
> > +UPSTREAM_CHECK_REGEX = "gtk-(?P<pver>\d+\.(\d*[02468])+(\.\d+)+)\.tar.xz"
> > +
> > +SRC_URI = "http://ftp.gnome.org/pub/gnome/sources/gtk/${MAJ_VER}/gtk-${PV}.tar.xz"
> > +SRC_URI[sha256sum] = "85b7a160b6e02eafa4e7d38f046f8720fab537d3fe73c01c864333a983a692a9"
> > +
> > +S = "${WORKDIR}/gtk-${PV}"
> > +
> > +inherit meson gettext pkgconfig gi-docgen update-alternatives gsettings features_check gobject-introspection
> > +
> > +# TBD: nativesdk
> > +# gobject-introspection.bbclass pins introspection off for nativesk. As long as
> > +# we do not remove this wisdom or hack gtk4, it is not possible to build
> > +# nativesdk-gtk4
> > +BBCLASSEXTEND = "native"
> > +
> > +GSETTINGS_PACKAGE:class-native = ""
> > +
> > +ANY_OF_DISTRO_FEATURES = "${GTK3DISTROFEATURES}"
> > +REQUIRED_DISTRO_FEATURES = "opengl"
> > +
> > +GIR_MESON_ENABLE_FLAG = 'enabled'
> > +GIR_MESON_DISABLE_FLAG = 'disabled'
> > +
> > +EXTRA_OEMESON = " -Dbuild-tests=false -Ddemos=false"
> > +
> > +PACKAGECONFIG ??= "gstreamer ${@bb.utils.filter('DISTRO_FEATURES', 'wayland x11 vulkan', d)}"
> > +PACKAGECONFIG:class-native = "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)}"
> > +PACKAGECONFIG:class-nativesdk = "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)}"
> > +
> > +PACKAGECONFIG[x11] = "-Dx11-backend=true,-Dx11-backend=false,at-spi2-atk fontconfig libx11 libxext libxcursor libxi libxdamage libxrandr libxrender libxcomposite libxfixes xinerama"
> > +PACKAGECONFIG[wayland] = "-Dwayland-backend=true,-Dwayland-backend=false,wayland wayland-protocols virtual/egl virtual/libgles2 wayland-native"
> > +PACKAGECONFIG[cups] = "-Dprint-cups=enabled,-Dprint-cups=disabled,cups"
> > +PACKAGECONFIG[colord] = "-Dcolord=enabled,-Dcolord=disabled,colord"
> > +PACKAGECONFIG[ffmpeg] = "-Dmedia-ffmpeg=enabled,-Dmedia-ffmpeg=disabled,ffmpeg"
> > +# gtk4 wants gstreamer-player-1.0 -> gstreamer1.0-plugins-bad
> > +PACKAGECONFIG[gstreamer] = "-Dmedia-gstreamer=enabled,-Dmedia-gstreamer=disabled,gstreamer1.0-plugins-bad"
> > +PACKAGECONFIG[tracker] = "-Dtracker=enabled,-Dtracker=disabled,tracker"
> > +PACKAGECONFIG[vulkan] = "-Dvulkan=enabled,-Dvulkan=disabled, vulkan-loader vulkan-headers shaderc-native"
> > +
> > +PACKAGES =+ "${PN}-demo"
> > +LIBV = "4.0.0"
> > +
> > +FILES:${PN}:append = " \
> > +    ${datadir}/glib-2.0/schemas/ \
> > +    ${datadir}/gtk-4.0/emoji/ \
> > +    ${datadir}/metainfo/ \
> > +    ${datadir}/icons/hicolor/*/apps/org.gtk.PrintEditor4*.* \
> > +    ${libdir}/gtk-4.0/${LIBV}/media \
> > +    ${bindir}/gtk4-update-icon-cache \
> > +    ${bindir}/gtk4-launch \
> > +"
> > +
> > +FILES:${PN}-dev += " \
> > +    ${datadir}/gtk-4.0/gtk4builder.rng \
> > +    ${datadir}/gtk-4.0/include \
> > +    ${datadir}/gtk-4.0/valgrind \
> > +    ${datadir}/gettext/its \
> > +    ${bindir}/gtk4-builder-tool \
> > +    ${bindir}/gtk4-encode-symbolic-svg \
> > +    ${bindir}/gtk4-query-settings \
> > +"
> > +
> > +GTKBASE_RRECOMMENDS ?= " \
> > +    liberation-fonts \
> > +    gdk-pixbuf-loader-png \
> > +    gdk-pixbuf-loader-jpeg \
> > +    gdk-pixbuf-loader-gif \
> > +    gdk-pixbuf-loader-xpm \
> > +    shared-mime-info \
> > +    adwaita-icon-theme-symbolic \
> > +"
> > +
> > +
> > +GTKBASE_RRECOMMENDS:class-native ?= ""
> > +
> > +GTKGLIBC_RRECOMMENDS ?= "${GTKBASE_RRECOMMENDS} glibc-gconv-iso8859-1"
> > +
> > +RRECOMMENDS:${PN} = "${GTKBASE_RRECOMMENDS}"
> > +RRECOMMENDS:${PN}:libc-glibc = "${GTKGLIBC_RRECOMMENDS}"
> > +RDEPENDS:${PN}-dev += "${@bb.utils.contains("PACKAGECONFIG", "wayland", "wayland-protocols", "", d)}"
> > +
> > +PACKAGES_DYNAMIC += "^gtk4-printbackend-.*"
> > +python populate_packages:prepend () {
> > +    import os.path
> > +
> > +    gtk_libdir = d.expand('${libdir}/gtk-4.0/${LIBV}')
> > +    printmodules_root = os.path.join(gtk_libdir, 'printbackends');
> > +
> > +    do_split_packages(d, printmodules_root, r'^libprintbackend-(.*)\.so$', 'gtk4-printbackend-%s', 'GTK printbackend module for %s')
> > +
> > +    if (d.getVar('DEBIAN_NAMES')):
> > +        d.setVar(d.expand('PKG:${PN}'), '${MLPREFIX}libgtk-4.0')
> > +}
> > -- 
> > 2.34.1
> > 
> 
> > 
> > -=-=-=-=-=-=-=-=-=-=-=-
> > Links: You receive all messages sent to this group.
> > View/Reply Online (#174041): https://lists.openembedded.org/g/openembedded-core/message/174041
> > Mute This Topic: https://lists.openembedded.org/mt/95377615/3617179
> > Group Owner: openembedded-core+owner@lists.openembedded.org
> > Unsubscribe: https://lists.openembedded.org/g/openembedded-core/unsub [alexandre.belloni@bootlin.com]
> > -=-=-=-=-=-=-=-=-=-=-=-
> > 
> 
> 
> -- 
> Alexandre Belloni, co-owner and COO, Bootlin
> Embedded Linux and Kernel engineering
> https://bootlin.com

-- 
Alexandre Belloni, co-owner and COO, Bootlin
Embedded Linux and Kernel engineering
https://bootlin.com