Re: [meta-oe][PATCH] libva: Import from meta-intel and update to 1.7.3

From: Martin Jansa <martin.jansa@gmail.com>
To: openembedded-devel@lists.openembedded.org
Subject: Re: [meta-oe][PATCH] libva: Import from meta-intel and update to 1.7.3
Date: Tue, 29 Nov 2016 20:59:22 +0100	[thread overview]
Message-ID: <20161129195922.GD2700@jama> (raw)
In-Reply-To: <20161128225759.9756-1-raj.khem@gmail.com>

[-- Attachment #1: Type: text/plain, Size: 3884 bytes --]

On Mon, Nov 28, 2016 at 02:57:59PM -0800, Khem Raj wrote:
> This recipe is used by intel and amd BSP layers
> additional copies are also there see
> https://layers.openembedded.org/layerindex/branch/master/recipes/?q=libva

I'm sorry to report more and more issues, but this is causing few more autodetected dependencies

mpv-0.15.0: mpv rdepends on libva-x11, but it isn't a build dependency, missing libva in DEPENDS or PACKAGECONFIG? [build-deps]
mpv-0.15.0: mpv rdepends on libva, but it isn't a build dependency, missing libva in DEPENDS or PACKAGECONFIG? [build-deps]

and there is another one caused by libvdpau I haven't noticed before:
ffmpeg-3.2: libavutil rdepends on libvdpau, but it isn't a build dependency, missing libvdpau in DEPENDS or PACKAGECONFIG? [build-deps]

> 
> Signed-off-by: Khem Raj <raj.khem@gmail.com>
> ---
>  meta-oe/recipes-graphics/libva/libva_1.7.3.bb | 48 +++++++++++++++++++++++++++
>  1 file changed, 48 insertions(+)
>  create mode 100644 meta-oe/recipes-graphics/libva/libva_1.7.3.bb
> 
> diff --git a/meta-oe/recipes-graphics/libva/libva_1.7.3.bb b/meta-oe/recipes-graphics/libva/libva_1.7.3.bb
> new file mode 100644
> index 0000000..9994158
> --- /dev/null
> +++ b/meta-oe/recipes-graphics/libva/libva_1.7.3.bb
> @@ -0,0 +1,48 @@
> +SUMMARY = "Video Acceleration (VA) API for Linux"
> +DESCRIPTION = "Video Acceleration API (VA API) is a library (libVA) \
> +and API specification which enables and provides access to graphics \
> +hardware (GPU) acceleration for video processing on Linux and UNIX \
> +based operating systems. Accelerated processing includes video \
> +decoding, video encoding, subpicture blending and rendering. The \
> +specification was originally designed by Intel for its GMA (Graphics \
> +Media Accelerator) series of GPU hardware, the API is however not \
> +limited to GPUs or Intel specific hardware, as other hardware and \
> +manufacturers can also freely use this API for hardware accelerated \
> +video decoding."
> +
> +HOMEPAGE = "http://www.freedesktop.org/wiki/Software/vaapi"
> +BUGTRACKER = "https://bugs.freedesktop.org"
> +
> +SECTION = "x11"
> +LICENSE = "MIT"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=2e48940f94acb0af582e5ef03537800f"
> +
> +SRC_URI = "http://www.freedesktop.org/software/vaapi/releases/libva/${BP}.tar.bz2"
> +SRC_URI[md5sum] = "dafb1d7d6449e850e9eb1a099895c683"
> +SRC_URI[sha256sum] = "22bc139498065a7950d966dbdb000cad04905cbd3dc8f3541f80d36c4670b9d9"
> +
> +DEPENDS = "libdrm virtual/mesa virtual/libgles1 virtual/libgles2 virtual/egl"
> +
> +inherit autotools pkgconfig
> +
> +EXTRA_OECONF = "--disable-dummy-driver"
> +
> +PACKAGECONFIG ??= "${@bb.utils.contains("DISTRO_FEATURES", "x11", "x11", "", d)} \
> +                   ${@bb.utils.contains("DISTRO_FEATURES", "wayland", "wayland", "", d)}"
> +PACKAGECONFIG[x11] = "--enable-x11,--disable-x11,virtual/libx11 libxext libxfixes"
> +PACKAGECONFIG[wayland] = "--enable-wayland,--disable-wayland,wayland"
> +
> +PACKAGES =+ "${PN}-x11 ${PN}-tpi ${PN}-glx ${PN}-egl ${PN}-wayland"
> +
> +RDEPENDS_${PN}-tpi =+ "${PN}"
> +RDEPENDS_${PN}-x11 =+ "${PN}"
> +RDEPENDS_${PN}-glx =+ "${PN}-x11"
> +RDEPENDS_${PN}-egl =+ "${PN}-x11"
> +
> +FILES_${PN}-dbg += "${libdir}/dri/.debug"
> +
> +FILES_${PN}-x11 =+ "${libdir}/libva-x11*${SOLIBS}"
> +FILES_${PN}-tpi =+ "${libdir}/libva-tpi*${SOLIBS}"
> +FILES_${PN}-glx =+ "${libdir}/libva-glx*${SOLIBS}"
> +FILES_${PN}-egl =+ "${libdir}/libva-egl*${SOLIBS}"
> +FILES_${PN}-wayland =+ "${libdir}/libva-wayland*${SOLIBS}"
> -- 
> 2.10.2
> 
> -- 
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel@lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa@gmail.com

[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 201 bytes --]