[PATCH 00/13] Confusing and invalid conditional appends

[PATCH 00/13] Confusing and invalid conditional appends

[Michal Sieron]

This patchset fixes several findings for variable assignments of form:
    A:someoverride += "foo"
and transforms them into:
    A:append:someoverride = " foo"

It is a continuation of similar changes in openembedded-core [1], which
are currently in master-next.

In most of those cases I assume the original intent was to have a
conditional append, but what was actually happening was append to
a conditional override.

Changes I made, which weren't simple syntax conversions:
1. gnome-bluetooth3 - typo fix
2. libgusb - invalid append changed to actual assignment (like libffi in
   openembedded-core)
3. postgresql - here EXTRA_OECONF's value was being overridden
4. graphviz - value was overridden, but shouldn't have impact
5. syzkaller - dropping qemu-system-native dependency

[1]: https://lists.openembedded.org/g/openembedded-core/message/233335

Signed-off-by: Michal Sieron <michalwsieron@gmail.com>
---
Michal Sieron (13):
      meta-python: Convert confusing appends to override syntax
      gnome-bluetooth3: Fix RRECOMMENS typo
      aufs-util: Convert confusing append to override syntax
      accountsservice: Convert confusing append to override syntax
      pipewire: Convert confusing appends to override syntax
      postfix: Convert confusing appends to override syntax
      libgusb: Convert confusing append to assignment
      postgresql: Fix append overriding value
      graphviz: Fix append overriding value
      syzkaller: Drop qemu-system-native dependency
      syzkaller: Fix appends overriding values
      pcsc-lite: Convert confusing append to override syntax
      flatbuffers: Convert confusing append to override syntax

 meta-filesystems/recipes-utils/aufs-util/aufs-util_git.bb             | 2 +-
 meta-gnome/recipes-gnome/gnome-bluetooth/gnome-bluetooth3_3.34.5.bb   | 2 +-
 meta-gnome/recipes-support/accountsservice/accountsservice_23.13.9.bb | 2 +-
 meta-multimedia/recipes-multimedia/pipewire/pipewire_1.6.2.bb         | 2 +-
 meta-networking/recipes-daemons/postfix/postfix_3.10.8.bb             | 4 ++--
 meta-oe/recipes-dbs/postgresql/postgresql.inc                         | 2 +-
 meta-oe/recipes-devtools/flatbuffers/flatbuffers.bb                   | 2 +-
 meta-oe/recipes-graphics/graphviz/graphviz_14.1.4.bb                  | 2 +-
 meta-oe/recipes-support/libgusb/libgusb_0.4.9.bb                      | 2 +-
 meta-oe/recipes-support/pcsc-lite/pcsc-lite_2.0.3.bb                  | 2 +-
 meta-oe/recipes-test/syzkaller/syzkaller-licenses.inc                 | 4 ++--
 meta-oe/recipes-test/syzkaller/syzkaller_git.bb                       | 4 ----
 meta-python/recipes-devtools/python/python3-astroid_4.1.2.bb          | 4 ++--
 meta-python/recipes-devtools/python/python3-humanfriendly_10.0.bb     | 2 +-
 meta-python/recipes-devtools/python/python3-msgpack_1.1.2.bb          | 2 +-
 meta-python/recipes-devtools/python/python3-progress_1.6.1.bb         | 2 +-
 meta-python/recipes-devtools/python/python3-wrapt_2.1.2.bb            | 2 +-
 meta-python/recipes-devtools/python/python3-yamlloader_1.6.0.bb       | 2 +-
 meta-python/recipes-devtools/python/python3-zopeinterface_8.2.bb      | 2 +-
 .../recipes-extended/python-pyparted/python3-pyparted_3.13.0.bb       | 2 +-
 meta-python/recipes-extended/pywbemtools/python3-pywbemtools_1.3.1.bb | 2 +-
 21 files changed, 23 insertions(+), 27 deletions(-)
---
base-commit: c3c094cf8d8df28c7db0f44890e092aee395cb99
change-id: 20260329-fix-confusing-appends-eada2ec9ac4a

Best regards,
--  
Michal Sieron <michalwsieron@gmail.com>

[PATCH 01/13] meta-python: Convert confusing appends to override syntax

[Michal Sieron]

While in this case `RDEPENDS:class-target +=` wouldn't result in any
unwanted override, there is no guarantee there won't be a change, which
would be hidden by this override. To avoid any surprises in the future
let's use `:append:class-target =` syntax here.

Signed-off-by: Michal Sieron <michalwsieron@gmail.com>
---
 meta-python/recipes-devtools/python/python3-astroid_4.1.2.bb          | 4 ++--
 meta-python/recipes-devtools/python/python3-humanfriendly_10.0.bb     | 2 +-
 meta-python/recipes-devtools/python/python3-msgpack_1.1.2.bb          | 2 +-
 meta-python/recipes-devtools/python/python3-progress_1.6.1.bb         | 2 +-
 meta-python/recipes-devtools/python/python3-wrapt_2.1.2.bb            | 2 +-
 meta-python/recipes-devtools/python/python3-yamlloader_1.6.0.bb       | 2 +-
 meta-python/recipes-devtools/python/python3-zopeinterface_8.2.bb      | 2 +-
 .../recipes-extended/python-pyparted/python3-pyparted_3.13.0.bb       | 2 +-
 meta-python/recipes-extended/pywbemtools/python3-pywbemtools_1.3.1.bb | 2 +-
 9 files changed, 10 insertions(+), 10 deletions(-)

diff --git a/meta-python/recipes-devtools/python/python3-astroid_4.1.2.bb b/meta-python/recipes-devtools/python/python3-astroid_4.1.2.bb
index d75b14c49f..1e7372f692 100644
--- a/meta-python/recipes-devtools/python/python3-astroid_4.1.2.bb
+++ b/meta-python/recipes-devtools/python/python3-astroid_4.1.2.bb
@@ -20,7 +20,7 @@ FILES:${PN}-tests += " \
     ${PYTHON_SITEPACKAGES_DIR}/astroid/__pycache__/test* \
 "
 
-RDEPENDS:${PN}:class-target += "\
+RDEPENDS:${PN}:append:class-target = " \
     python3-lazy-object-proxy \
     python3-logging \
     python3-six \
@@ -29,7 +29,7 @@ RDEPENDS:${PN}:class-target += "\
     python3-typing-extensions \
 "
 
-RDEPENDS:${PN}-tests:class-target += "\
+RDEPENDS:${PN}-tests:append:class-target = " \
     python3-unittest \
     python3-xml \
 "
diff --git a/meta-python/recipes-devtools/python/python3-humanfriendly_10.0.bb b/meta-python/recipes-devtools/python/python3-humanfriendly_10.0.bb
index b32fe2e1d0..184ce28c1a 100644
--- a/meta-python/recipes-devtools/python/python3-humanfriendly_10.0.bb
+++ b/meta-python/recipes-devtools/python/python3-humanfriendly_10.0.bb
@@ -10,7 +10,7 @@ SRC_URI[sha256sum] = "6b0b831ce8f15f7300721aa49829fc4e83921a9a301cc7f606be6686a2
 
 inherit pypi setuptools3
 
-RDEPENDS:${PN}:class-target += " \
+RDEPENDS:${PN}:append:class-target = " \
     python3-datetime \
     python3-fcntl \
     python3-io \
diff --git a/meta-python/recipes-devtools/python/python3-msgpack_1.1.2.bb b/meta-python/recipes-devtools/python/python3-msgpack_1.1.2.bb
index 85ec93695d..5b201a7554 100644
--- a/meta-python/recipes-devtools/python/python3-msgpack_1.1.2.bb
+++ b/meta-python/recipes-devtools/python/python3-msgpack_1.1.2.bb
@@ -8,7 +8,7 @@ PTEST_PYTEST_DIR = "test"
 
 SRC_URI[sha256sum] = "3b60763c1373dd60f398488069bcdc703cd08a711477b5d480eecc9f9626f47e"
 
-RDEPENDS:${PN}:class-target += "\
+RDEPENDS:${PN}:append:class-target = " \
     python3-io \
 "
 
diff --git a/meta-python/recipes-devtools/python/python3-progress_1.6.1.bb b/meta-python/recipes-devtools/python/python3-progress_1.6.1.bb
index 57c0748a5c..9ec4ec2b66 100644
--- a/meta-python/recipes-devtools/python/python3-progress_1.6.1.bb
+++ b/meta-python/recipes-devtools/python/python3-progress_1.6.1.bb
@@ -7,7 +7,7 @@ SRC_URI[sha256sum] = "c1ba719f862ce885232a759eab47971fe74dfc7bb76ab8a51ef5940bad
 
 inherit pypi python_setuptools_build_meta
 
-RDEPENDS:${PN}:class-target += " \
+RDEPENDS:${PN}:append:class-target = " \
     python3-datetime \
     python3-math \
 "
diff --git a/meta-python/recipes-devtools/python/python3-wrapt_2.1.2.bb b/meta-python/recipes-devtools/python/python3-wrapt_2.1.2.bb
index 70652048f3..ee57717a5c 100644
--- a/meta-python/recipes-devtools/python/python3-wrapt_2.1.2.bb
+++ b/meta-python/recipes-devtools/python/python3-wrapt_2.1.2.bb
@@ -13,7 +13,7 @@ RDEPENDS:${PN}-ptest += " \
 	python3-misc \
 "
 
-RDEPENDS:${PN}:class-target += "\
+RDEPENDS:${PN}:append:class-target = " \
     python3-stringold \
     python3-threading \
 "
diff --git a/meta-python/recipes-devtools/python/python3-yamlloader_1.6.0.bb b/meta-python/recipes-devtools/python/python3-yamlloader_1.6.0.bb
index 4844e10de1..281c73eec4 100644
--- a/meta-python/recipes-devtools/python/python3-yamlloader_1.6.0.bb
+++ b/meta-python/recipes-devtools/python/python3-yamlloader_1.6.0.bb
@@ -11,6 +11,6 @@ DEPENDS += "\
     python3-hatch-vcs-native \
 "
 
-RDEPENDS:${PN}:class-target += "\
+RDEPENDS:${PN}:append:class-target = " \
     python3-pyyaml \
 "
diff --git a/meta-python/recipes-devtools/python/python3-zopeinterface_8.2.bb b/meta-python/recipes-devtools/python/python3-zopeinterface_8.2.bb
index 1446d15935..690c2d26aa 100644
--- a/meta-python/recipes-devtools/python/python3-zopeinterface_8.2.bb
+++ b/meta-python/recipes-devtools/python/python3-zopeinterface_8.2.bb
@@ -11,7 +11,7 @@ PACKAGES =. "${PN}-test "
 
 RPROVIDES:${PN} += "zope-interfaces"
 
-RDEPENDS:${PN}:class-target += "python3-datetime"
+RDEPENDS:${PN}:append:class-target = " python3-datetime"
 RDEPENDS:${PN}-test += "python3-unittest python3-doctest"
 
 FILES:${PN}-dbg += "${PYTHON_SITEPACKAGES_DIR}/*.egg/*/*/.debug"
diff --git a/meta-python/recipes-extended/python-pyparted/python3-pyparted_3.13.0.bb b/meta-python/recipes-extended/python-pyparted/python3-pyparted_3.13.0.bb
index 0f7065f5ae..ab0fe8c602 100644
--- a/meta-python/recipes-extended/python-pyparted/python3-pyparted_3.13.0.bb
+++ b/meta-python/recipes-extended/python-pyparted/python3-pyparted_3.13.0.bb
@@ -15,7 +15,7 @@ inherit pkgconfig pypi setuptools3
 
 DEPENDS += "parted"
 
-RDEPENDS:${PN}:class-target += " \
+RDEPENDS:${PN}:append:class-target = " \
     parted (>= 2.3) \
     python3-codecs \
     python3-math \
diff --git a/meta-python/recipes-extended/pywbemtools/python3-pywbemtools_1.3.1.bb b/meta-python/recipes-extended/pywbemtools/python3-pywbemtools_1.3.1.bb
index f02c96e405..83156cfddf 100644
--- a/meta-python/recipes-extended/pywbemtools/python3-pywbemtools_1.3.1.bb
+++ b/meta-python/recipes-extended/pywbemtools/python3-pywbemtools_1.3.1.bb
@@ -8,7 +8,7 @@ SRC_URI[sha256sum] = "7fb1c32e358d55c2c6966a071c8ecc0ca81de3d32944a67cc646c57b1a
 
 inherit pypi setuptools3
 
-RDEPENDS:${PN}:class-target += "\
+RDEPENDS:${PN}:append:class-target = " \
     python3-ply \
     python3-pyyaml \
     python3-six \

-- 
2.53.0

[PATCH 02/13] gnome-bluetooth3: Fix RRECOMMENS typo

[Michal Sieron]

Signed-off-by: Michal Sieron <michalwsieron@gmail.com>
---
 meta-gnome/recipes-gnome/gnome-bluetooth/gnome-bluetooth3_3.34.5.bb | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/meta-gnome/recipes-gnome/gnome-bluetooth/gnome-bluetooth3_3.34.5.bb b/meta-gnome/recipes-gnome/gnome-bluetooth/gnome-bluetooth3_3.34.5.bb
index 1ceff5ffcf..8490e3d161 100644
--- a/meta-gnome/recipes-gnome/gnome-bluetooth/gnome-bluetooth3_3.34.5.bb
+++ b/meta-gnome/recipes-gnome/gnome-bluetooth/gnome-bluetooth3_3.34.5.bb
@@ -34,6 +34,6 @@ do_install:append() {
 FILES:${PN} += "${datadir}/gnome-bluetooth"
 
 # offer alternate bluetooth-sendto
-RRECOMMENS:${PN} += "gnome-bluetooth"
+RRECOMMENDS:${PN} += "gnome-bluetooth"
 
 RDEPENDS:${PN} += "bluez5"

-- 
2.53.0

[PATCH 03/13] aufs-util: Convert confusing append to override syntax

[Michal Sieron]

While in this case `RRECOMMENDS:class-target +=` wouldn't result in any
unwanted override, there is no guarantee there won't be a change, which
would be hidden by this override. To avoid any surprises in the future
let's use `:append:class-target =` syntax here.

Signed-off-by: Michal Sieron <michalwsieron@gmail.com>
---
 meta-filesystems/recipes-utils/aufs-util/aufs-util_git.bb | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/meta-filesystems/recipes-utils/aufs-util/aufs-util_git.bb b/meta-filesystems/recipes-utils/aufs-util/aufs-util_git.bb
index 61ec508b43..0abbc9ef50 100644
--- a/meta-filesystems/recipes-utils/aufs-util/aufs-util_git.bb
+++ b/meta-filesystems/recipes-utils/aufs-util/aufs-util_git.bb
@@ -63,6 +63,6 @@ do_install:class-native () {
     done
 }
 
-RRECOMMENDS:${PN}:class-target += "kernel-module-aufs"
+RRECOMMENDS:${PN}:append:class-target = " kernel-module-aufs"
 
 BBCLASSEXTEND = "native"

-- 
2.53.0

[PATCH 04/13] accountsservice: Convert confusing append to override syntax

[Michal Sieron]

While in this case `EXTRA_OEMESON:libc-musl +=` wouldn't result in any
unwanted override, there is no guarantee there won't be a change, which
would be hidden by this override. To avoid any surprises in the future
let's use `:append:libc-musl =` syntax here.

Signed-off-by: Michal Sieron <michalwsieron@gmail.com>
---
 meta-gnome/recipes-support/accountsservice/accountsservice_23.13.9.bb | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/meta-gnome/recipes-support/accountsservice/accountsservice_23.13.9.bb b/meta-gnome/recipes-support/accountsservice/accountsservice_23.13.9.bb
index c024ae3f92..f0c68ed62a 100644
--- a/meta-gnome/recipes-support/accountsservice/accountsservice_23.13.9.bb
+++ b/meta-gnome/recipes-support/accountsservice/accountsservice_23.13.9.bb
@@ -24,7 +24,7 @@ SRC_URI:append:libc-musl = " \
 	file://0002-musl-add-missing-fgetspent_r.patch \
 "
 
-EXTRA_OEMESON:libc-musl += "-Dwtmpfile=/var/log/wtmp -Dtests=false"
+EXTRA_OEMESON:append:libc-musl = " -Dwtmpfile=/var/log/wtmp -Dtests=false"
 
 SRC_URI[sha256sum] = "adda4cdeae24fa0992e7df3ffff9effa7090be3ac233a3edfdf69d5a9c9b924f"
 

-- 
2.53.0

[PATCH 05/13] pipewire: Convert confusing appends to override syntax

[Michal Sieron]

While in this case `RRECOMMENDS:class-target +=` wouldn't result in any
unwanted override, there is no guarantee there won't be a change, which
would be hidden by this override. To avoid any surprises in the future
let's use `:append:class-target =` syntax here.

Signed-off-by: Michal Sieron <michalwsieron@gmail.com>
---
 meta-multimedia/recipes-multimedia/pipewire/pipewire_1.6.2.bb | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/meta-multimedia/recipes-multimedia/pipewire/pipewire_1.6.2.bb b/meta-multimedia/recipes-multimedia/pipewire/pipewire_1.6.2.bb
index 6914a4a0ad..1e5e5f0399 100644
--- a/meta-multimedia/recipes-multimedia/pipewire/pipewire_1.6.2.bb
+++ b/meta-multimedia/recipes-multimedia/pipewire/pipewire_1.6.2.bb
@@ -282,7 +282,7 @@ FILES:${PN} = " \
     ${bindir}/pipewire-vulkan \
 "
 
-RRECOMMENDS:${PN}:class-target += " \
+RRECOMMENDS:${PN}:append:class-target = " \
 	pipewire-modules-meta \
 	pipewire-spa-plugins-meta \
 "

-- 
2.53.0

[PATCH 06/13] postfix: Convert confusing appends to override syntax

[Michal Sieron]

While in this case `RDEPENDS:class-target +=` wouldn't result in any
unwanted override, there is no guarantee there won't be a change, which
would be hidden by this override. To avoid any surprises in the future
let's use `:append:class-target =` syntax here.

Signed-off-by: Michal Sieron <michalwsieron@gmail.com>
---
 meta-networking/recipes-daemons/postfix/postfix_3.10.8.bb | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)

diff --git a/meta-networking/recipes-daemons/postfix/postfix_3.10.8.bb b/meta-networking/recipes-daemons/postfix/postfix_3.10.8.bb
index 2423e17169..a66ecc0b5d 100644
--- a/meta-networking/recipes-daemons/postfix/postfix_3.10.8.bb
+++ b/meta-networking/recipes-daemons/postfix/postfix_3.10.8.bb
@@ -240,8 +240,8 @@ pkg_postinst_ontarget:${PN}-cfg () {
 }
 
 PACKAGES =+ "${PN}-cfg"
-RDEPENDS:${PN}-cfg:class-target += "${PN}-bin"
-RDEPENDS:${PN}:class-target += "${PN}-cfg"
+RDEPENDS:${PN}-cfg:append:class-target = " ${PN}-bin"
+RDEPENDS:${PN}:append:class-target = " ${PN}-cfg"
 # Exclude .debug directories from the main package
 FILES:${PN}-bin += "${localstatedir} ${bindir}/* ${sbindir}/* \
                ${libexecdir}/* ${systemd_unitdir}/*"

-- 
2.53.0

[PATCH 07/13] libgusb: Convert confusing append to assignment

[Michal Sieron]

While in this case override caused by `EXTRA_OEMESON:class-native +=` is
desirable, the `+=` can be confusing. Let's avoid that and use explicit
assignment.

Signed-off-by: Michal Sieron <michalwsieron@gmail.com>
---
 meta-oe/recipes-support/libgusb/libgusb_0.4.9.bb | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/meta-oe/recipes-support/libgusb/libgusb_0.4.9.bb b/meta-oe/recipes-support/libgusb/libgusb_0.4.9.bb
index 9007574fc6..25750247f8 100644
--- a/meta-oe/recipes-support/libgusb/libgusb_0.4.9.bb
+++ b/meta-oe/recipes-support/libgusb/libgusb_0.4.9.bb
@@ -10,7 +10,7 @@ inherit meson gobject-introspection gi-docgen gettext vala pkgconfig
 PACKAGECONFIG:class-target ??= "${@bb.utils.contains('GI_DATA_ENABLED', 'True', 'vapi', '', d)}"
 PACKAGECONFIG[vapi] = "-Dvapi=true,-Dvapi=false"
 
-EXTRA_OEMESON:class-native += "-Dtests=false  -Dintrospection=false"
+EXTRA_OEMESON:class-native = "-Dtests=false  -Dintrospection=false"
 
 GIDOCGEN_MESON_OPTION = 'docs'
 

-- 
2.53.0

[PATCH 08/13] postgresql: Fix append overriding value

[Michal Sieron]

`EXTRA_OECONF:sh4 += "--disable-spinlocks"` was supposed to simply
disable unsupported spinlocks, but was also overriding other
configuration defined in EXTRA_OECONF above.

Signed-off-by: Michal Sieron <michalwsieron@gmail.com>
---
 meta-oe/recipes-dbs/postgresql/postgresql.inc | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/meta-oe/recipes-dbs/postgresql/postgresql.inc b/meta-oe/recipes-dbs/postgresql/postgresql.inc
index 6858015478..07cd121511 100644
--- a/meta-oe/recipes-dbs/postgresql/postgresql.inc
+++ b/meta-oe/recipes-dbs/postgresql/postgresql.inc
@@ -78,7 +78,7 @@ EXTRA_OECONF += "--disable-rpath \
     --datadir=${datadir}/${BPN} \
     --sysconfdir=${sysconfdir}/${BPN} \
 "
-EXTRA_OECONF:sh4 += "--disable-spinlocks"
+EXTRA_OECONF:append:sh4 = " --disable-spinlocks"
 
 DEBUG_OPTIMIZATION:remove:mips = " -Og"
 DEBUG_OPTIMIZATION:append:mips = " -O"

-- 
2.53.0

[PATCH 09/13] graphviz: Fix append overriding value

[Michal Sieron]

It actually overrides value of FILES:${PN} instead of appending.
In this case SDKPATHNATIVE is the prefix so everything was still
working, but let's convert it to a proper conditional append.

Signed-off-by: Michal Sieron <michalwsieron@gmail.com>
---
 meta-oe/recipes-graphics/graphviz/graphviz_14.1.4.bb | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/meta-oe/recipes-graphics/graphviz/graphviz_14.1.4.bb b/meta-oe/recipes-graphics/graphviz/graphviz_14.1.4.bb
index bfc59c3ca1..a5f08d0c85 100644
--- a/meta-oe/recipes-graphics/graphviz/graphviz_14.1.4.bb
+++ b/meta-oe/recipes-graphics/graphviz/graphviz_14.1.4.bb
@@ -68,7 +68,7 @@ do_install:append:class-nativesdk() {
     install -d ${D}${SDKPATHNATIVE}/post-relocate-setup.d
     install -m 0755 ${UNPACKDIR}/graphviz-setup.sh ${D}${SDKPATHNATIVE}/post-relocate-setup.d
 }
-FILES:${PN}:class-nativesdk += "${SDKPATHNATIVE}"
+FILES:${PN}:append:class-nativesdk = " ${SDKPATHNATIVE}"
 
 # create /usr/lib/graphviz/config6
 graphviz_sstate_postinst() {

-- 
2.53.0

[PATCH 10/13] syzkaller: Drop qemu-system-native dependency

[Michal Sieron]

Either I am missing something or it isn't needed in the build time and
should maybe be a RRECOMMENDS:${PN}?

Signed-off-by: Michal Sieron <michalwsieron@gmail.com>
Cc: Stefan Wiehler <me@sephalon.net>
---
 meta-oe/recipes-test/syzkaller/syzkaller_git.bb | 4 ----
 1 file changed, 4 deletions(-)

diff --git a/meta-oe/recipes-test/syzkaller/syzkaller_git.bb b/meta-oe/recipes-test/syzkaller/syzkaller_git.bb
index e35a8a77be..bdd4cf6a40 100644
--- a/meta-oe/recipes-test/syzkaller/syzkaller_git.bb
+++ b/meta-oe/recipes-test/syzkaller/syzkaller_git.bb
@@ -6,8 +6,6 @@ LICENSE = "Apache-2.0"
 LIC_FILES_CHKSUM = "file://src/${GO_IMPORT}/LICENSE;md5=5335066555b14d832335aa4660d6c376"
 require ${BPN}-licenses.inc
 
-DEPENDS:class-native += "qemu-system-native"
-
 SRC_URI = "git://${GO_IMPORT};protocol=https;destsuffix=${GO_SRCURI_DESTSUFFIX};branch=master"
 SRCREV = "22ec1469fe8c0ba256de07e8f97fa7b375b522bd"
 require ${BPN}-go-mods.inc
@@ -39,8 +37,6 @@ GOBUILDFLAGS:remove = "-buildmode=pie"
 
 LDFLAGS:append:class-target = "${@bb.utils.contains_any("TC_CXX_RUNTIME", "llvm android", " -lc++", " -lstdc++", d)}"
 
-DEPENDS:class-native += "qemu-system-native"
-
 compile_native() {
     export HOSTOS="${GOHOSTOS}"
     export HOSTARCH="${GOHOSTARCH}"

-- 
2.53.0

[PATCH 11/13] syzkaller: Fix appends overriding values

[Michal Sieron]

Those LIC_FILES_CHKSUM:class-native(sdk) were actually overriding the
rest of LIC_FILES_CHKSUM.

Signed-off-by: Michal Sieron <michalwsieron@gmail.com>
---
 meta-oe/recipes-test/syzkaller/syzkaller-licenses.inc | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)

diff --git a/meta-oe/recipes-test/syzkaller/syzkaller-licenses.inc b/meta-oe/recipes-test/syzkaller/syzkaller-licenses.inc
index af118a4dd4..65306a17d0 100644
--- a/meta-oe/recipes-test/syzkaller/syzkaller-licenses.inc
+++ b/meta-oe/recipes-test/syzkaller/syzkaller-licenses.inc
@@ -79,5 +79,5 @@ LIC_FILES_CHKSUM_HOST = "\
     file://pkg/mod/google.golang.org/appengine/v2@v2.0.6/LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57;spdx=Apache-2.0 \
 "
 
-LIC_FILES_CHKSUM:class-native += "${LIC_FILES_CHKSUM_HOST}"
-LIC_FILES_CHKSUM:class-nativesdk += "${LIC_FILES_CHKSUM_HOST}"
+LIC_FILES_CHKSUM:append:class-native = " ${LIC_FILES_CHKSUM_HOST}"
+LIC_FILES_CHKSUM:append:class-nativesdk = " ${LIC_FILES_CHKSUM_HOST}"

-- 
2.53.0

[PATCH 12/13] pcsc-lite: Convert confusing append to override syntax

[Michal Sieron]

While in this case `RPROVIDES:${PN}:class-native +=` wouldn't
result in any unwanted override, there is no guarantee there won't be a
change, which would be hidden by this override. To avoid any surprises
in the future let's use `:append:class-native =` syntax here.

Signed-off-by: Michal Sieron <michalwsieron@gmail.com>
---
 meta-oe/recipes-support/pcsc-lite/pcsc-lite_2.0.3.bb | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/meta-oe/recipes-support/pcsc-lite/pcsc-lite_2.0.3.bb b/meta-oe/recipes-support/pcsc-lite/pcsc-lite_2.0.3.bb
index 169630d319..9e3c98bb97 100644
--- a/meta-oe/recipes-support/pcsc-lite/pcsc-lite_2.0.3.bb
+++ b/meta-oe/recipes-support/pcsc-lite/pcsc-lite_2.0.3.bb
@@ -34,7 +34,7 @@ PACKAGES = "${PN} ${PN}-dbg ${PN}-dev ${PN}-lib ${PN}-doc ${PN}-spy ${PN}-spy-de
 
 RRECOMMENDS:${PN} = "ccid"
 RRECOMMENDS:${PN}:class-native = ""
-RPROVIDES:${PN}:class-native += "pcsc-lite-lib-native"
+RPROVIDES:${PN}:append:class-native = " pcsc-lite-lib-native"
 
 FILES:${PN} = "${sbindir}/pcscd \
                ${datadir}/polkit-1"

-- 
2.53.0

[PATCH 13/13] flatbuffers: Convert confusing append to override syntax

[Michal Sieron]

While in this case `SYSROOT_PREPROCESS_FUNCS:class-target +=` wouldn't
result in any unwanted override, there is no guarantee there won't be a
change, which would be hidden by this override. To avoid any surprises
in the future let's use `:append:class-target =` syntax here.

Signed-off-by: Michal Sieron <michalwsieron@gmail.com>
---
 meta-oe/recipes-devtools/flatbuffers/flatbuffers.bb | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/meta-oe/recipes-devtools/flatbuffers/flatbuffers.bb b/meta-oe/recipes-devtools/flatbuffers/flatbuffers.bb
index c51a49ba01..289330ee04 100644
--- a/meta-oe/recipes-devtools/flatbuffers/flatbuffers.bb
+++ b/meta-oe/recipes-devtools/flatbuffers/flatbuffers.bb
@@ -25,7 +25,7 @@ inherit cmake python3native
 rm_flatc_cmaketarget_for_target() {
     rm -f "${SYSROOT_DESTDIR}/${libdir}/cmake/flatbuffers/FlatcTargets.cmake"
 }
-SYSROOT_PREPROCESS_FUNCS:class-target += "rm_flatc_cmaketarget_for_target"
+SYSROOT_PREPROCESS_FUNCS:append:class-target = " rm_flatc_cmaketarget_for_target"
 
 FILES:${PN}-compiler = "${bindir}"
 

-- 
2.53.0