Re: [meta-networking][PATCH] netkit-tftp: new package

[akuster808 <akuster808@gmail.com>]

On 12/12/2014 05:44 PM, Khem Raj wrote:
>
>> On Dec 12, 2014, at 5:13 PM, Armin Kuster <akuster808@gmail.com> wrote:
>>
>> Signed-off-by: Armin Kuster <akuster808@gmail.com>
>> ---
>> .../recipes-netkit/netkit-tftp/netkit-tftp_0.17.bb | 70 ++++++++++++++++++++++
>> 1 file changed, 70 insertions(+)
>> create mode 100644 meta-networking/recipes-netkit/netkit-tftp/netkit-tftp_0.17.bb
>>
>> diff --git a/meta-networking/recipes-netkit/netkit-tftp/netkit-tftp_0.17.bb b/meta-networking/recipes-netkit/netkit-tftp/netkit-tftp_0.17.bb
>> new file mode 100644
>> index 0000000..bd5c113
>> --- /dev/null
>> +++ b/meta-networking/recipes-netkit/netkit-tftp/netkit-tftp_0.17.bb
>> @@ -0,0 +1,70 @@
>> +DESCRIPTION = " tftp - Trivial file transfer protocol client \
>> +    tftpd- Trivial file transfer protocol server "
>> +SECTION = "networking"
>> +LICENSE = “BSD"
>
> which BSD clause ?

will check.

>
>> +DEPENDS = " tcp-wrappers"
>> +
>> +LIC_FILES_CHKSUM = "file://tftp/tftp.c;beginline=2;endline=3;md5=84d2cfe1e60863a7d82648734ba4d30c"
>> +
>> +SRC_URI = "${DEBIAN_MIRROR}/main/n/${BPN}/${BPN}_${PV}.orig.tar.gz;name=archive \
>> +        ${DEBIAN_MIRROR}/main/n/${BPN}/${BPN}_${PV}-18.diff.gz;name=patch18 \
>> +"
>> +
>> +SRC_URI[archive.md5sum] = "b7262c798e2ff50e29c2ff50dfd8d6a8"
>> +SRC_URI[archive.sha256sum] = "3a43c0010d4e61f412563fd83769d4667d8b8e82903526d21cb9205fe55ad14d"
>> +SRC_URI[patch18.md5sum] = "cb29e7a33dd85105ba6e6ec4f971e42c"
>> +SRC_URI[patch18.sha256sum] = "092437d27b4fa88c044ef6290372fee5ce06d223607f0e22a6e527065c8930e7"
>> +
>> +inherit autotools-brokensep
>> +
>> +do_configure () {
>> +    ./configure --prefix=${prefix}
>> +    echo "CFLAGS=${CFLAGS}" > MCONFIG
>> +}
>> +
>> +do_compile () {
>> +    oe_runmake 'CC=${CC}' 'LD=${LD}' 'LDFLAGS=${LDFLAGS}' 'CFLAGS=${CFLAGS}'
>> +}
>> +
>> +do_install () {
>> +    install -d ${D}${bindir}
>> +    install -d ${D}${sbindir}
>> +    install -d ${D}${mandir}/man1
>> +    install -d ${D}${mandir}/man8
>> +    install -d ${D}${sysconfdir}/xinetd.d
>> +
>> +    sed -i 's/install -s/install/' tftp/Makefile
>> +    sed -i 's/install -s/install/' tftpd/Makefile
>> +
>> +    oe_runmake 'INSTALLROOT=${D}' 'BINMODE=0755' \
>> +    'DAEMONMODE=0755' 'MANMODE=0644' \
>> +    'BINDIR=${bindir}' 'SBINDIR=${sbindir}' \
>> +    'MANDIR=${mandir}' install
>> +
>> +    # create the xinetd config file
>> +    cat >tftp.conf <<EOF
>> + service tftp
>> + {
>> +    disable        = no
>> +    socket_type    = dgram
>> +    port           = 69
>> +    protocol       = udp
>> +    wait           = yes
>> +    user           = nobody
>> +    server         = ${sbindir}/in.tftpd
>> +    server_args    = /tftpboot
>> + }
>> +EOF
>
> may be this can be a separate file ? since then we can override it via bbappend if needed

sounds good.

>
>> +    install tftp.conf ${D}/${sysconfdir}/xinetd.d/tftp
>> +}
>> +
>> +INSANE_SKIP_${PN} = "already-stripped”
>
> Not nice, we loose the debuggability just replace install -s in its makefiles with install
> or may be just setting INSTALL variable is enough.

I will double check this.

thanks for the feedback.

- Armin
>
>> +
>> +PACKAGES = "${PN}-client ${PN}-server ${PN}-doc ${BPN}-dbg"
>> +FILES_${PN}-client = "${bindir}/*"
>> +FILES_${PN}-server = "${sbindir}/* ${sysconfdir}/xinetd.d/*"
>> +FILES_${PN}-doc = "${mandir}"
>> +FILES_${PN}-dbg = "${prefix}/src/debug \
>> +            ${bindir}/.debug ${sbindir}/.debug"
>> +
>> +RDEPENDS_${PN}-server = "tcp-wrappers xinetd"
>> --
>> 1.9.1
>>
>> --
>> _______________________________________________
>> Openembedded-devel mailing list
>> Openembedded-devel@lists.openembedded.org
>> http://lists.openembedded.org/mailman/listinfo/openembedded-devel
>