Re: [meta-oe][PATCH] mpv: Media Player

[Gary Thomas <gary@mlbassoc.com>]

On 2016-03-09 20:15, Martin Jansa wrote:
> On Wed, Mar 09, 2016 at 07:20:33AM +0100, Gary Thomas wrote:
>> mpv is a fork of mplayer2 and MPlayer. It shares some features with the former projects while introducing many more.
>>
>> Signed-off-by: Gary Thomas <gary@mlbassoc.com>
>> ---
>>   meta-oe/recipes-multimedia/mplayer/mpv_0.15.0.bb | 60 ++++++++++++++++++++++++
>>   1 file changed, 60 insertions(+)
>>   create mode 100644 meta-oe/recipes-multimedia/mplayer/mpv_0.15.0.bb
>>
>> diff --git a/meta-oe/recipes-multimedia/mplayer/mpv_0.15.0.bb b/meta-oe/recipes-multimedia/mplayer/mpv_0.15.0.bb
>> new file mode 100644
>> index 0000000..37e4b02
>> --- /dev/null
>> +++ b/meta-oe/recipes-multimedia/mplayer/mpv_0.15.0.bb
>> @@ -0,0 +1,60 @@
>> +SUMMARY = "Open Source multimedia player"
>> +SECTION = "multimedia"
>> +HOMEPAGE = "http://www.mpv.io/"
>> +DEPENDS = "zlib ffmpeg jpeg virtual/libx11 xsp libxv libxscrnsaver"
>> +
>> +# Depends on xsp, libxv, virtual/libx11, libxscrnsaver
>> +REQUIRED_DISTRO_FEATURES = "x11"
>> +
>> +LICENSE = "GPLv2+"
>> +LIC_FILES_CHKSUM = "file://LICENSE;md5=91f1cb870c1cc2d31351a4d2595441cb"
>> +
>> +SRC_URI = "https://github.com/mpv-player/mpv/archive/v${PV}.tar.gz;name=mpv \
>> +           http://www.freehackers.org/~tnagy/release/waf-1.8.12;name=waf \
>> +"
>> +SRC_URI[mpv.md5sum] = "9042bd3fbff2bc8ba0b7fadaa4a22101"
>> +SRC_URI[mpv.sha256sum] = "7d31217ba8572f364fcea2955733f821374ae6d8c6d8f22f8bc63c44c0400bdc"
>> +SRC_URI[waf.md5sum] = "cef4ee82206b1843db082d0b0506bf71"
>> +SRC_URI[waf.sha256sum] = "01bf2beab2106d1558800c8709bc2c8e496d3da4a2ca343fe091f22fca60c98b"
>> +
>> +EXTRA_OECONF = " \
>> +    --prefix=${D}/usr \
> why not ${prefix} and does it really need to be prefixed with ${D}
> (unlike mandir bellow)? Ugly waf.
>
>> +    --mandir=${mandir} \
>> +    --target=${SIMPLE_TARGET_SYS} \
>> +    --disable-gl \
>> +    --disable-libsmbclient \
>> +    --disable-libass \
>> +    --disable-lua \
>> +    --disable-libass-osd \
>> +    --disable-encoding \
>> +    --disable-libbluray \
>> +    --disable-dvdread \
>> +    --disable-dvdnav \
>> +    --disable-cdda \
>> +    --disable-enca \
>> +    --disable-libguess \
>> +    --disable-uchardet \
>> +    --disable-rubberband \
>> +    --disable-lcms2 \
>> +    --disable-vapoursynth \
>> +    --disable-vapoursynth-lazy \
>> +    --enable-libarchive \
>> +"
>> +
>> +do_configure() {
>> +    if [ ! -L ../waf ]; then
>> +        chmod a+x ../waf-1.8.12
>> +	ln -s waf-1.8.12 ../waf
>> +    fi
>> +    ../waf configure ${EXTRA_OECONF}
>> +}
>> +
>> +do_compile () {
>> +    ../waf build
>> +}
>> +
>> +do_install() {
>> +    ../waf install
>> +}
>> +
>> +FILES_${PN} += "/usr/"
>
> ${prefix}?
>
> Does it install files in strange directories not covered by standard
> FILES?
>

Use of ${prefix} does seem correct, I've updated the recipe.
Patch v2 has been dispatched, including a required update to
the libass package which was necessary to get a fully functional
mpv.

-- 
------------------------------------------------------------
Gary Thomas                 |  Consulting for the
MLB Associates              |    Embedded world
------------------------------------------------------------