From ead6d03a868112aa17126daecbb3899e0376d4cd Mon Sep 17 00:00:00 2001
From: Thomas Elste <thomas.elste@imms.de>
Date: Mon, 21 Jun 2010 16:57:44 +0200
Subject: [PATCH] qwt: Add version 5.2.1

Add recipe for current version of Qwt. This new version uses qt4-classes
instead of palmtop. Different bb-files for Qt and Qt-Embedded
variant are provided. Qwt examples are also build. They get deployed in
extra packages.

Signed-off-by: Thomas Elste <thomas.elste@imms.de>
---
 recipes/qwt/qwt-e_5.2.1.bb |    8 ++++++++
 recipes/qwt/qwt.inc        |   35 +++++++++++++++++++++++++++++++++++
 recipes/qwt/qwt_5.2.1.bb   |    8 ++++++++
 3 files changed, 51 insertions(+), 0 deletions(-)
 create mode 100644 recipes/qwt/qwt-e_5.2.1.bb
 create mode 100644 recipes/qwt/qwt.inc
 create mode 100644 recipes/qwt/qwt_5.2.1.bb

diff --git a/recipes/qwt/qwt-e_5.2.1.bb b/recipes/qwt/qwt-e_5.2.1.bb
new file mode 100644
index 0000000..09b31ed
--- /dev/null
+++ b/recipes/qwt/qwt-e_5.2.1.bb
@@ -0,0 +1,8 @@
+QWT_VARIANT = "e"
+require qwt.inc
+
+PR = "${INC_PR}.1"
+
+SRC_URI[md5sum] = "4a595b8db0ec3856b117836c1d60cb27"
+SRC_URI[sha256sum] = "e2b8bb755404cb3dc99e61f3e2d7262152193488f5fbe88524eb698e11ac569f"
+
diff --git a/recipes/qwt/qwt.inc b/recipes/qwt/qwt.inc
new file mode 100644
index 0000000..5fff79d
--- /dev/null
+++ b/recipes/qwt/qwt.inc
@@ -0,0 +1,35 @@
+DESCRIPTION = "Qt Widget Extension for Technical Applications"
+HOMEPAGE = "http://qwt.sourceforge.net/"
+SECTION = "libs"
+PRIORITY = "optional"
+LICENSE = "GPL"
+INC_PR = "r0"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/qwt/qwt-${PV}.tar.bz2"
+
+inherit qt4${QWT_VARIANT}
+
+S = "${WORKDIR}/qwt-${PV}"
+
+EXTRA_OEMAKE = "${PARALLEL_MAKE}"
+
+do_configure_prepend() {
+        # set install path and doc path, enable examples
+        sed -i \
+                -e 's/\(INSTALLBASE *= \)\/usr.*/\1\/usr/' \
+                -e 's/\(doc.path.*\/\).*/\1share\/doc\/qwt-${PV}/' \
+                -e 's/#CONFIG     += QwtExamples/CONFIG += QwtExamples/' \
+                qwtconfig.pri
+}
+
+do_install() {
+        oe_runmake install INSTALL_ROOT=${D}
+        install -d ${D}${bindir}/qwt-examples-${QWT_VARIANT}
+        install examples/bin/* ${D}${bindir}/qwt-examples-${QWT_VARIANT}
+}
+
+PACKAGES =+ "${PN}-examples ${PN}-examples-dbg"
+FILES_${PN} = "${libdir}/*"
+FILES_${PN}-examples = "${bindir}/qwt-examples-${QWT_VARIANT}/*"
+FILES_${PN}-examples-dbg = "${bindir}/qwt-examples-${QWT_VARIANT}"
+
diff --git a/recipes/qwt/qwt_5.2.1.bb b/recipes/qwt/qwt_5.2.1.bb
new file mode 100644
index 0000000..a1142f0
--- /dev/null
+++ b/recipes/qwt/qwt_5.2.1.bb
@@ -0,0 +1,8 @@
+QWT_VARIANT = "x11"
+require qwt.inc
+
+PR = "${INC_PR}.1"
+
+SRC_URI[md5sum] = "4a595b8db0ec3856b117836c1d60cb27"
+SRC_URI[sha256sum] = "e2b8bb755404cb3dc99e61f3e2d7262152193488f5fbe88524eb698e11ac569f"
+
-- 
1.7.1