Re: [Qemu-devel] qemu/pc-bios README openbios-sparc32 openbios-s...

["Blue Swirl" <blauwirbel@gmail.com>]

[-- Attachment #1: Type: text/plain, Size: 475 bytes --]

On 4/15/07, Stefan Weil <weil@mail.berlios.de> wrote:
> The Sparc64 image is much larger than the Sparc32 image,
> but the size command displays a much smaller text and data size
> (about the same size as for the Sparc32 image).
>
> Maybe it contains some unneeded parts?

Thanks for the report. There is indeed a whole lot of unused space
between ELF header and start of .text segment.

But I don't see what in the ldscript (attached) causes the gap to
appear. Suggestions?

[-- Attachment #2: ldscript --]
[-- Type: application/octet-stream, Size: 1610 bytes --]

OUTPUT_FORMAT(elf64-sparc)
OUTPUT_ARCH(sparc:v9)

/* Qemu ELF loader can't handle very complex files, so we put ELFBoot
info to rodata and put initctx to data.*/

ENTRY(trap_table)

/* Initial load address
 */
BASE_ADDR = 0x000001fff0000000;

/* 16KB heap and stack */
HEAP_SIZE = 16384;
STACK_SIZE = 16384;
VMEM_SIZE = 128 * 1024;
IOMEM_SIZE = 256 * 1024 + 768 * 1024;

SECTIONS
{
    . = BASE_ADDR;

    /* Start of the program. 
     * Now the version string is in the note, we must include it
     * in the program. Otherwise we lose the string after relocation. */
    _start = .;

    /* Normal sections */
    .text ALIGN(65536): {
        *(.text.vectors)
        *(.text)
        *(.text.*)
    }
    .rodata ALIGN(65536): {
        _rodata = .;
	sound_drivers_start = .;
	*(.rodata.sound_drivers)
	sound_drivers_end = .;
	*(.rodata)
	*(.rodata.*)
        *(.note.ELFBoot)
    }
    .data ALIGN(65536): {
        _data = .;
        *(.data)
        *(.data.*)
    }

    .bss ALIGN(4096): {
        _bss = .;
	*(.bss)
	*(.bss.*)
	*(COMMON)

	/* Put heap and stack here, so they are included in PT_LOAD segment
	 * and the bootloader is aware of it. */

	. = ALIGN(16);
	_heap = .;
	. += HEAP_SIZE;
	. = ALIGN(16);
	_eheap = .;

	. = ALIGN(4096);
	_vmem = .;
	. += VMEM_SIZE;
        _evmem = .;

	_stack = .;
	. += STACK_SIZE;
	. = ALIGN(16);
	_estack = .;
    }

    . = ALIGN(4096);
    _end = .;
    _iomem = _end + IOMEM_SIZE;

    /* We discard .note sections other than .note.ELFBoot,
     * because some versions of GCC generates useless ones. */

    /DISCARD/ : { *(.comment*) *(.note.*) }
}