[U-Boot] [PATCH 1/7] MIPS: add unified u-boot.lds file

* [U-Boot] [PATCH 1/7] MIPS: add unified u-boot.lds file
@ 2013-01-29  8:31 Gabor Juhos
  2013-01-29  8:31 ` [U-Boot] [PATCH 2/7] MIPS: qemu-mips: use the unified u-boot.lds script Gabor Juhos
                   ` (6 more replies)
  0 siblings, 7 replies; 12+ messages in thread
From: Gabor Juhos @ 2013-01-29  8:31 UTC (permalink / raw)
  To: u-boot

The patch adds an unified linker script file which
can be used for all currently supported MIPS targets.

Signed-off-by: Gabor Juhos <juhosg@openwrt.org>
Cc: Daniel Schwierzeck <daniel.schwierzeck@googlemail.com>
Cc: Vlad Lungu <vlad@comsys.ro>
Cc: Thomas Sailer <sailer@scs.ch>
Cc: Stefan Roese <sr@denx.de>
Cc: Wolfgang Denk <wd@denx.de>
Cc: Thomas Lange <thomas@corelatus.se>
Cc: Xiangfu Liu <xiangfu@openmobilefree.net>
---
 arch/mips/cpu/u-boot.lds |   90 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 90 insertions(+)
 create mode 100644 arch/mips/cpu/u-boot.lds

diff --git a/arch/mips/cpu/u-boot.lds b/arch/mips/cpu/u-boot.lds
new file mode 100644
index 0000000..988764d
--- /dev/null
+++ b/arch/mips/cpu/u-boot.lds
@@ -0,0 +1,90 @@
+/*
+ * (C) Copyright 2003
+ * Wolfgang Denk Engineering, <wd@denx.de>
+ *
+ * See file CREDITS for list of people who contributed to this
+ * project.
+ *
+ * This program is free software; you can redistribute it and/or
+ * modify it under the terms of the GNU General Public License as
+ * published by the Free Software Foundation; either version 2 of
+ * the License, or (at your option) any later version.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU General Public License for more details.
+ *
+ * You should have received a copy of the GNU General Public License
+ * along with this program; if not, write to the Free Software
+ * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
+ * MA 02111-1307 USA
+ */
+
+#if defined(CONFIG_64BIT)
+#define ELF_FMT		elf64
+#define PTR_COUNT_SHIFT	3
+#else
+#define ELF_FMT		elf32
+#define PTR_COUNT_SHIFT	2
+#endif
+
+#if defined(CONFIG_SYS_LITTLE_ENDIAN)
+#define ELF_ENDIAN	tradlittlemips
+#else
+#define ELF_ENDIAN	tradbigmips
+#endif
+
+#define _MIPS_FORMAT2(x)	#x
+#define _MIPS_FORMAT(x,y)	_MIPS_FORMAT2(x-y)
+
+#define MIPS_FORMAT		_MIPS_FORMAT(ELF_FMT,ELF_ENDIAN)
+
+OUTPUT_FORMAT(MIPS_FORMAT, MIPS_FORMAT, MIPS_FORMAT)
+OUTPUT_ARCH(mips)
+ENTRY(_start)
+SECTIONS
+{
+	. = 0x00000000;
+
+	. = ALIGN(4);
+	.text       :
+	{
+	  *(.text*)
+	}
+
+	. = ALIGN(4);
+	.rodata  : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
+
+	. = ALIGN(4);
+	.data  : { *(.data*) }
+
+	. = .;
+	_gp = ALIGN(16) +0x7ff0;
+
+	.got  : {
+		__got_start = .;
+		*(.got)
+		__got_end = .;
+	}
+
+	. = ALIGN(4);
+	.sdata  : { *(.sdata*) }
+
+	. = ALIGN(4);
+	.u_boot_list : {
+		#include <u-boot.lst>
+	}
+
+	uboot_end_data = .;
+
+	num_got_entries = (__got_end - __got_start) >> PTR_COUNT_SHIFT;
+
+	. = ALIGN(4);
+	.sbss  : { *(.sbss*) }
+	.bss : {
+		*(.bss*)
+		. = ALIGN(4);
+	}
+	uboot_end = .;
+}
-- 
1.7.10

^ permalink raw reply related	[flat|nested] 12+ messages in thread