[master/scarthgap][PATCH v2 0/5] Add recipe to package MessageQ Application and Firmware

[master/scarthgap][PATCH v2 0/5] Add recipe to package MessageQ Application and Firmware

[Beleswar Padhi]

The MessageQ IPC Application and Firmwares share the same source repository. The
pre-built MessageQ firmwares are available in ti-linux-firmware repository. Add
a recipe to package the firmwares in root and boot partition for AM57xx SoCs.
Also, add a recipe to build _ONLY_ the application (app_host) from source and
package it in rootfs.

This removes dependency on meta-ti-extras layer. As discussed here[0]

v2: Changelog:
1. Build only the application host, not the firmwares in PATCH 01.
2. Bump ALTERNATE_PRIORITY to 30 for ti-rtos-messageq-test-fw package to
override symlinks from ti-ipc-rtos package in PATCH 02.

Link to v1:
https://lore.kernel.org/all/20250801150037.2650736-1-b-padhi@ti.com/

Note:
1. Currently, there is a dependency on XDS tools even to build the app_host.
This is because of the way files are organized in the source repository[1].
There is no separate folder for separate OS'es. All are put together under one
directory, and 'xs' is used to pick and zip the appropriate files according to
the HOSTOS. Unless that cleanup happens, this dependency will exist. Or is there
a way?
2. The firmware PR is not yet merged into ti-linux-firmware repo yet

[0]: https://lore.kernel.org/all/20250315020224.3100249-1-denis@denix.org/
[1]: https://git.ti.com/cgit/ipc/ipc-examples/tree/src/examples/templates/ex02_messageq/host 
[2]: https://git.ti.com/cgit/ipc/ipc-examples/tree/src/examples/templates/makefile#n265

Thanks,
Beleswar

Beleswar Padhi (5):
  ti-ipc-examples-linux: Add a recipe to build messageq app_host
  ti-rtos-messageq-test-fw: Add a recipe to package prebuilt IPC
    firmware
  conf: omap-a15.inc: Update package for wic dependency
  meta-ti-extras: ti-ipc-rtos: Remove deploy task
  ti-ipc.inc: Bump SRCREV to latest for ipcdev project

 meta-ti-bsp/conf/machine/include/omap-a15.inc |  2 +-
 .../recipes-bsp/ti-linux-fw/ti-linux-fw.inc   |  1 +
 .../ti-rtos-messageq-test-fw_git.bb           | 67 ++++++++++++++++++
 meta-ti-bsp/recipes-ti/ipc/ti-ipc.inc         |  4 +-
 .../ipc/ti-ipc-examples-linux_git.bb          | 68 +++++++++++++++++++
 .../recipes-ti/ipc/ti-ipc-rtos_git.bb         | 12 ----
 6 files changed, 139 insertions(+), 15 deletions(-)
 create mode 100644 meta-ti-bsp/recipes-bsp/ti-rtos-fw/ti-rtos-messageq-test-fw_git.bb
 create mode 100644 meta-ti-extras/recipes-ti/ipc/ti-ipc-examples-linux_git.bb

-- 
2.34.1

[master/scarthgap][PATCH v2 1/5] ti-ipc-examples-linux: Add a recipe to build messageq app_host

[Beleswar Padhi]

Add a recipe to build the Application Host (for A15 core) to demonstrate
IPC with remote processors through messageq firmware. Also package this
in the /usr/bin directory for testing IPC. This recipe only builds the
app_host, and the firmwares are available in ti-linux-firmware
repository.

Signed-off-by: Beleswar Padhi <b-padhi@ti.com>
---
 .../ipc/ti-ipc-examples-linux_git.bb          | 68 +++++++++++++++++++
 1 file changed, 68 insertions(+)
 create mode 100644 meta-ti-extras/recipes-ti/ipc/ti-ipc-examples-linux_git.bb

diff --git a/meta-ti-extras/recipes-ti/ipc/ti-ipc-examples-linux_git.bb b/meta-ti-extras/recipes-ti/ipc/ti-ipc-examples-linux_git.bb
new file mode 100644
index 00000000..3a64409e
--- /dev/null
+++ b/meta-ti-extras/recipes-ti/ipc/ti-ipc-examples-linux_git.bb
@@ -0,0 +1,68 @@
+DESCRIPTION = "TI Inter Processor Communication (IPC) MessageQ Application for
+Linux Host"
+
+require recipes-ti/ipc/ti-ipc-common.inc
+require ti-ipc-rtos.inc
+
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://${S_ipc-examples}/src/makefile;beginline=1;endline=30;md5=a52324bd5033bb49ea07bade1244ac9a"
+
+INSANE_SKIP:${PN} += "arch"
+
+IPC_INSTALL_DIR = "${STAGING_DIR_TARGET}/usr/share/ti/ti-ipc-tree"
+INHIBIT_PACKAGE_STRIP = "1"
+
+DEPENDS = "ti-ipc ti-ipc-rtos ti-xdctools-native zip-native"
+
+EX02_PATH = "examples/DRA7XX_linux_elf/ex02_messageq/host"
+
+do_compile() {
+  cd ${S_ipc-examples}/src
+  oe_runmake .examples \
+    IPCTOOLS="${S_ipc-metadata}/src/etc"
+
+  for alt_platform in ${ALT_PLATFORM}; do
+    oe_runmake .examples "PLATFORM=${alt_platform}" \
+      IPCTOOLS="${S_ipc-metadata}/src/etc"
+  done
+
+  if [  "${PLATFORM}" != "UNKNOWN" ]; then
+    oe_runmake extract HOSTOS="linux" IPC_INSTALL_DIR="${IPC_INSTALL_DIR}"
+
+    if [ ! -z ${ALT_PLATFORM} ]; then
+      oe_runmake extract PLATFORM="${ALT_PLATFORM}" HOSTOS="linux" \
+         IPC_INSTALL_DIR="${IPC_INSTALL_DIR}"
+    fi
+    oe_runmake -C ${EX02_PATH} all HOSTOS="linux" \
+      LINUX_SYSROOT_DIR="${STAGING_INCDIR}" \
+      IPC_INSTALL_DIR="${IPC_INSTALL_DIR}"
+
+    if [ ! -z ${ALT_PLATFORM} ]; then
+      oe_runmake -C ${EX02_PATH} all HOSTOS="linux" \
+        LINUX_SYSROOT_DIR="${STAGING_INCDIR}" \
+        IPC_INSTALL_DIR="${IPC_INSTALL_DIR}" \
+        PLATFORM="${ALT_PLATFORM}"
+    fi
+  fi
+}
+
+do_install() {
+  cd ${S_ipc-examples}/src
+
+  if [  "${PLATFORM}" != "UNKNOWN" ]; then
+    # Install directory for linux examples
+    install -d ${D}${bindir}/ipc/examples/ex02_messageq
+    oe_runmake -C ${EX02_PATH} install IPC_INSTALL_DIR="${IPC_INSTALL_DIR}" \
+      LINUX_SYSROOT_DIR="${STAGING_INCDIR}" \
+      HOSTOS="linux" EXEC_DIR="${D}/${bindir}/ipc/examples/ex02_messageq"
+
+    if [ ! -z ${ALT_PLATFORM} ]; then
+      oe_runmake -C ${EX02_PATH} install IPC_INSTALL_DIR="${IPC_INSTALL_DIR}" \
+        LINUX_SYSROOT_DIR="${STAGING_INCDIR}" \
+        HOSTOS="linux" EXEC_DIR="${D}/${bindir}/ipc/examples/ex02_messageq" \
+        PLATFORM="${ALT_PLATFORM}"
+    fi
+  fi
+}
+
+FILES:${PN} += "${bindir}/*"
-- 
2.34.1

[master/scarthgap][PATCH v2 2/5] ti-rtos-messageq-test-fw: Add a recipe to package prebuilt IPC firmware

[Beleswar Padhi]

The messageq IPC firmware example for AM57xx SoCs is available in
ti-linux-firmware repository. Add a recipe to package the prebuilt
messageq firmware into the rootfs. Additionally, make sure the firmware
for IPU1 rproc is copied into boot partition as well for Early Boot use
cases.

Signed-off-by: Beleswar Padhi <b-padhi@ti.com>
---
 .../recipes-bsp/ti-linux-fw/ti-linux-fw.inc   |  1 +
 .../ti-rtos-messageq-test-fw_git.bb           | 67 +++++++++++++++++++
 2 files changed, 68 insertions(+)
 create mode 100644 meta-ti-bsp/recipes-bsp/ti-rtos-fw/ti-rtos-messageq-test-fw_git.bb

diff --git a/meta-ti-bsp/recipes-bsp/ti-linux-fw/ti-linux-fw.inc b/meta-ti-bsp/recipes-bsp/ti-linux-fw/ti-linux-fw.inc
index 47ce5616..6787018e 100644
--- a/meta-ti-bsp/recipes-bsp/ti-linux-fw/ti-linux-fw.inc
+++ b/meta-ti-bsp/recipes-bsp/ti-linux-fw/ti-linux-fw.inc
@@ -19,6 +19,7 @@ TI_SYSFW_VERSION = "11.01.05"
 TI_HSM_DEMO_FW_VERSION = "11.00.09"
 TAD5212_FW_VERSION = "1.0.0.0"
 TI_PKA_FW_VERSION = "2.1.0"
+TI_IPC_EXAMPLES_FW_VERSION = "3.52.00.01"
 
 TI_LINUX_FW_SRCREV ?= "e89a348f4618a26812fb353a04ed9532ef890a2f"
 SRCREV = "${TI_LINUX_FW_SRCREV}"
diff --git a/meta-ti-bsp/recipes-bsp/ti-rtos-fw/ti-rtos-messageq-test-fw_git.bb b/meta-ti-bsp/recipes-bsp/ti-rtos-fw/ti-rtos-messageq-test-fw_git.bb
new file mode 100644
index 00000000..980fe5cc
--- /dev/null
+++ b/meta-ti-bsp/recipes-bsp/ti-rtos-fw/ti-rtos-messageq-test-fw_git.bb
@@ -0,0 +1,67 @@
+SUMMARY = "TI MessageQ prebuilt binary firmware images"
+
+LICENSE = "TI-TFL"
+LIC_FILES_CHKSUM = "file://${THISDIR}/../../licenses/TI-TFL;md5=a1b59cb7ba626b9dbbcbf00f3fbc438a"
+
+COMPATIBLE_MACHINE = "am57xx"
+
+inherit update-alternatives
+inherit deploy
+
+require recipes-bsp/ti-linux-fw/ti-linux-fw.inc
+
+PV = "${TI_IPC_EXAMPLES_FW_VERSION}"
+PR = "${INC_PR}.0"
+
+INSTALL_IPC_FW_DIR = "${nonarch_base_libdir}/firmware/ipc"
+
+IPU_1_FW = "messageq_server_ipu1.xem4"
+IPU_2_FW = "messageq_server_ipu2.xem4"
+DSP_1_FW = "messageq_server_dsp1.xe66"
+DSP_2_FW = "messageq_server_dsp2.xe66"
+
+IPU_1_FW_DIR = "ti_platforms_evmDRA7XX_ipu1"
+IPU_2_FW_DIR = "ti_platforms_evmDRA7XX_ipu2"
+DSP_1_FW_DIR = "ti_platforms_evmDRA7XX_dsp1"
+DSP_2_FW_DIR = "ti_platforms_evmDRA7XX_dsp2"
+
+do_install() {
+    # Install Firmware
+    install -d ${D}${INSTALL_IPC_FW_DIR}/${IPU_1_FW_DIR}
+    install -d ${D}${INSTALL_IPC_FW_DIR}/${IPU_2_FW_DIR}
+    install -d ${D}${INSTALL_IPC_FW_DIR}/${DSP_1_FW_DIR}
+    install -d ${D}${INSTALL_IPC_FW_DIR}/${DSP_2_FW_DIR}
+
+    install -m 0644 ${S}/ti-ipc/am57xx/${IPU_1_FW} ${D}${INSTALL_IPC_FW_DIR}/${IPU_1_FW_DIR}
+    install -m 0644 ${S}/ti-ipc/am57xx/${IPU_2_FW} ${D}${INSTALL_IPC_FW_DIR}/${IPU_2_FW_DIR}
+    install -m 0644 ${S}/ti-ipc/am57xx/${DSP_1_FW} ${D}${INSTALL_IPC_FW_DIR}/${DSP_1_FW_DIR}
+    install -m 0644 ${S}/ti-ipc/am57xx/${DSP_2_FW} ${D}${INSTALL_IPC_FW_DIR}/${DSP_2_FW_DIR}
+}
+
+do_deploy() {
+    install -d ${DEPLOYDIR}/ipc
+    install -m 0644 ${S}/ti-ipc/am57xx/${IPU_1_FW} ${DEPLOYDIR}/ipc/dra7-ipu1-fw.xem4
+}
+
+addtask deploy after do_install
+
+# Set up names for the firmwares
+
+ALTERNATIVE:${PN} = "\
+                    dra7-ipu1-fw.xem4 \
+                    dra7-ipu2-fw.xem4 \
+                    dra7-dsp1-fw.xe66 \
+                    dra7-dsp2-fw.xe66 \
+                    "
+
+ALTERNATIVE_LINK_NAME[dra7-ipu1-fw.xem4] = "${nonarch_base_libdir}/firmware/dra7-ipu1-fw.xem4"
+ALTERNATIVE_LINK_NAME[dra7-ipu2-fw.xem4] = "${nonarch_base_libdir}/firmware/dra7-ipu2-fw.xem4"
+ALTERNATIVE_LINK_NAME[dra7-dsp1-fw.xe66] = "${nonarch_base_libdir}/firmware/dra7-dsp1-fw.xe66"
+ALTERNATIVE_LINK_NAME[dra7-dsp2-fw.xe66] = "${nonarch_base_libdir}/firmware/dra7-dsp2-fw.xe66"
+
+ALTERNATIVE_TARGET[dra7-ipu1-fw.xem4] = "${INSTALL_IPC_FW_DIR}/${IPU_1_FW_DIR}/${IPU_1_FW}"
+ALTERNATIVE_TARGET[dra7-ipu2-fw.xem4] = "${INSTALL_IPC_FW_DIR}/${IPU_2_FW_DIR}/${IPU_2_FW}"
+ALTERNATIVE_TARGET[dra7-dsp1-fw.xe66] = "${INSTALL_IPC_FW_DIR}/${DSP_1_FW_DIR}/${DSP_1_FW}"
+ALTERNATIVE_TARGET[dra7-dsp2-fw.xe66] = "${INSTALL_IPC_FW_DIR}/${DSP_2_FW_DIR}/${DSP_2_FW}"
+
+ALTERNATIVE_PRIORITY = "30"
-- 
2.34.1

[master/scarthgap][PATCH v2 3/5] conf: omap-a15.inc: Update package for wic dependency

[Beleswar Padhi]

The pre-built messageq IPC firmware is available in ti-linux-firmware
and packaged in ti-rtos-messageq-test-fw recipe in the meta-ti-bsp
layer. Update the dependency in machine conf to the above recipe. This
removes any dependency on meta-ti-extras layer.

Signed-off-by: Beleswar Padhi <b-padhi@ti.com>
---
 meta-ti-bsp/conf/machine/include/omap-a15.inc | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/meta-ti-bsp/conf/machine/include/omap-a15.inc b/meta-ti-bsp/conf/machine/include/omap-a15.inc
index 3b8eb0fd..2179476f 100644
--- a/meta-ti-bsp/conf/machine/include/omap-a15.inc
+++ b/meta-ti-bsp/conf/machine/include/omap-a15.inc
@@ -48,4 +48,4 @@ IMAGE_FSTYPES += "tar.xz wic.xz wic.bmap"
 WKS_FILE ?= "sdimage-2part.wks"
 IMAGE_BOOT_FILES ?= "${SPL_BINARY} u-boot.${UBOOT_SUFFIX} ${UBOOT_EXTLINUX_BOOT_FILES} ipc/dra7-ipu1-fw.xem4;dra7-ipu1-fw.xem4"
 do_image_wic[depends] += "virtual/bootloader:do_deploy"
-do_image_wic[depends] += "ti-ipc-rtos:do_deploy"
+do_image_wic[depends] += "ti-rtos-messageq-test-fw:do_deploy"
-- 
2.34.1

[master/scarthgap][PATCH v2 4/5] meta-ti-extras: ti-ipc-rtos: Remove deploy task

[Beleswar Padhi]

The pre-built messageq IPC firmware is packaged into rootfs and boot
partition as part of ti-rtos-messageq-test-fw recipe in the meta-ti-bsp
layers. There is no need to deploy the vayu IPC firmware anymore. Remove
the deploy task.

Signed-off-by: Beleswar Padhi <b-padhi@ti.com>
---
 meta-ti-extras/recipes-ti/ipc/ti-ipc-rtos_git.bb | 12 ------------
 1 file changed, 12 deletions(-)

diff --git a/meta-ti-extras/recipes-ti/ipc/ti-ipc-rtos_git.bb b/meta-ti-extras/recipes-ti/ipc/ti-ipc-rtos_git.bb
index 853fa117..d2ac6276 100644
--- a/meta-ti-extras/recipes-ti/ipc/ti-ipc-rtos_git.bb
+++ b/meta-ti-extras/recipes-ti/ipc/ti-ipc-rtos_git.bb
@@ -2,7 +2,6 @@ require recipes-ti/ipc/ti-ipc.inc
 require recipes-ti/ipc/ti-ipc-common.inc
 require ti-ipc-rtos.inc
 
-inherit deploy
 inherit update-alternatives
 
 DEPENDS = "ti-xdctools-native ti-sysbios doxygen-native zip-native"
@@ -100,17 +99,6 @@ ALTERNATIVE_TARGET[dra7-dsp2-fw.xe66] = "${nonarch_base_libdir}/firmware/ipc/ti_
 ALTERNATIVE_TARGET[dra7-ipu1-fw.xem4] = "${nonarch_base_libdir}/firmware/ipc/ti_platforms_evmDRA7XX_ipu1/test_omx_ipu1_vayu.xem4"
 ALTERNATIVE_TARGET[dra7-ipu2-fw.xem4] = "${nonarch_base_libdir}/firmware/ipc/ti_platforms_evmDRA7XX_ipu2/test_omx_ipu2_vayu.xem4"
 
-do_deploy() {
-  install -d ${DEPLOYDIR}
-}
-
-do_deploy:append:omap-a15() {
-  install -d ${DEPLOYDIR}/ipc
-  install -m 0644 ${S}/packages/ti/ipc/tests/bin/ti_platforms_evmDRA7XX_ipu1/test_omx_ipu1_vayu.xem4 ${DEPLOYDIR}/ipc/dra7-ipu1-fw.xem4
-}
-
-addtask deploy after do_install
-
 # Disable the "buildpaths" check while we figure out how we are
 # going to address this issue.
 #
-- 
2.34.1

[master/scarthgap][PATCH v2 5/5] ti-ipc.inc: Bump SRCREV to latest for ipcdev project

[Beleswar Padhi]

The latest tag in ipcdev project is 3.52.00.01. Update SRCREV to the
latest tag.

Signed-off-by: Beleswar Padhi <b-padhi@ti.com>
---
 meta-ti-bsp/recipes-ti/ipc/ti-ipc.inc | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)

diff --git a/meta-ti-bsp/recipes-ti/ipc/ti-ipc.inc b/meta-ti-bsp/recipes-ti/ipc/ti-ipc.inc
index c6dfc517..8a8bd1de 100644
--- a/meta-ti-bsp/recipes-ti/ipc/ti-ipc.inc
+++ b/meta-ti-bsp/recipes-ti/ipc/ti-ipc.inc
@@ -9,8 +9,8 @@ TI_IPC_GIT_URI = "git://git.ti.com/git/ipc/ipcdev.git"
 TI_IPC_GIT_PROTOCOL = "https"
 TI_IPC_GIT_BRANCH = "master"
 
-#Corresponds to 3.51.00.00A
-TI_IPC_SRCREV = "7a6e343a208d2849139b7272a67abc01db806e00"
+#Corresponds to 3.52.00.01
+TI_IPC_SRCREV = "7f76e5cc15c634b70efee18d1aa0474d603224a6"
 
 BRANCH = "${TI_IPC_GIT_BRANCH}"
 SRC_URI = "${TI_IPC_GIT_URI};protocol=${TI_IPC_GIT_PROTOCOL};branch=${BRANCH};name=ipcdev"
-- 
2.34.1

Re: [master/scarthgap][PATCH v2 0/5] Add recipe to package MessageQ Application and Firmware

[PRC Automation]

meta-ti / na / 20250806170442.243461-1-b-padhi

PRC Results: PASS

-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-
  check-yocto-patches: PASS
-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-
Patches
----------------------------------------
All patches passed



-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-
  apply-yocto-patch: PASS
-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-


-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-
  check-yocto-repo: PASS
-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-

Re: [master/scarthgap][PATCH v2 4/5] meta-ti-extras: ti-ipc-rtos: Remove deploy task

[Aniket Limaye]

Beleswar,

On 06/08/25 22:34, Beleswar Padhi wrote:
> The pre-built messageq IPC firmware is packaged into rootfs and boot
> partition as part of ti-rtos-messageq-test-fw recipe in the meta-ti-bsp
> layers. There is no need to deploy the vayu IPC firmware anymore. Remove
> the deploy task.
> 
> Signed-off-by: Beleswar Padhi <b-padhi@ti.com>
> ---

This patch might need to be squashed into the previous 2 patches.

Without this patch, 2 recipes will be deploying to the same filename 
${DEPLOYDIR}/ipc/dra7-ipu1-fw.xem4 which will fail builds I believe

Regards,
Aniket


>   meta-ti-extras/recipes-ti/ipc/ti-ipc-rtos_git.bb | 12 ------------
>   1 file changed, 12 deletions(-)
> 
> diff --git a/meta-ti-extras/recipes-ti/ipc/ti-ipc-rtos_git.bb b/meta-ti-extras/recipes-ti/ipc/ti-ipc-rtos_git.bb
> index 853fa117..d2ac6276 100644
> --- a/meta-ti-extras/recipes-ti/ipc/ti-ipc-rtos_git.bb
> +++ b/meta-ti-extras/recipes-ti/ipc/ti-ipc-rtos_git.bb
> @@ -2,7 +2,6 @@ require recipes-ti/ipc/ti-ipc.inc
>   require recipes-ti/ipc/ti-ipc-common.inc
>   require ti-ipc-rtos.inc
>   
> -inherit deploy
>   inherit update-alternatives
>   
>   DEPENDS = "ti-xdctools-native ti-sysbios doxygen-native zip-native"
> @@ -100,17 +99,6 @@ ALTERNATIVE_TARGET[dra7-dsp2-fw.xe66] = "${nonarch_base_libdir}/firmware/ipc/ti_
>   ALTERNATIVE_TARGET[dra7-ipu1-fw.xem4] = "${nonarch_base_libdir}/firmware/ipc/ti_platforms_evmDRA7XX_ipu1/test_omx_ipu1_vayu.xem4"
>   ALTERNATIVE_TARGET[dra7-ipu2-fw.xem4] = "${nonarch_base_libdir}/firmware/ipc/ti_platforms_evmDRA7XX_ipu2/test_omx_ipu2_vayu.xem4"
>   
> -do_deploy() {
> -  install -d ${DEPLOYDIR}
> -}
> -
> -do_deploy:append:omap-a15() {
> -  install -d ${DEPLOYDIR}/ipc
> -  install -m 0644 ${S}/packages/ti/ipc/tests/bin/ti_platforms_evmDRA7XX_ipu1/test_omx_ipu1_vayu.xem4 ${DEPLOYDIR}/ipc/dra7-ipu1-fw.xem4
> -}
> -
> -addtask deploy after do_install
> -
>   # Disable the "buildpaths" check while we figure out how we are
>   # going to address this issue.
>   #

Re: [master/scarthgap][PATCH v2 1/5] ti-ipc-examples-linux: Add a recipe to build messageq app_host

[Aniket Limaye]

Beleswar,

On 06/08/25 22:34, Beleswar Padhi wrote:
> Add a recipe to build the Application Host (for A15 core) to demonstrate
> IPC with remote processors through messageq firmware. Also package this
> in the /usr/bin directory for testing IPC. This recipe only builds the
> app_host, and the firmwares are available in ti-linux-firmware
> repository.
> 
> Signed-off-by: Beleswar Padhi <b-padhi@ti.com>
> ---
>   .../ipc/ti-ipc-examples-linux_git.bb          | 68 +++++++++++++++++++
>   1 file changed, 68 insertions(+)
>   create mode 100644 meta-ti-extras/recipes-ti/ipc/ti-ipc-examples-linux_git.bb
> 
> diff --git a/meta-ti-extras/recipes-ti/ipc/ti-ipc-examples-linux_git.bb b/meta-ti-extras/recipes-ti/ipc/ti-ipc-examples-linux_git.bb
> new file mode 100644
> index 00000000..3a64409e
> --- /dev/null
> +++ b/meta-ti-extras/recipes-ti/ipc/ti-ipc-examples-linux_git.bb
> @@ -0,0 +1,68 @@
> +DESCRIPTION = "TI Inter Processor Communication (IPC) MessageQ Application for
> +Linux Host"
> +
> +require recipes-ti/ipc/ti-ipc-common.inc
> +require ti-ipc-rtos.inc
> +
> +LICENSE = "BSD-3-Clause"
> +LIC_FILES_CHKSUM = "file://${S_ipc-examples}/src/makefile;beginline=1;endline=30;md5=a52324bd5033bb49ea07bade1244ac9a"
> +
> +INSANE_SKIP:${PN} += "arch"

I guess this is not required since we are only building linux application?

Regards,
Aniket

> +
> +IPC_INSTALL_DIR = "${STAGING_DIR_TARGET}/usr/share/ti/ti-ipc-tree"
> +INHIBIT_PACKAGE_STRIP = "1"
> +
> +DEPENDS = "ti-ipc ti-ipc-rtos ti-xdctools-native zip-native"
> +
> +EX02_PATH = "examples/DRA7XX_linux_elf/ex02_messageq/host"
> +
> +do_compile() {
> +  cd ${S_ipc-examples}/src
> +  oe_runmake .examples \
> +    IPCTOOLS="${S_ipc-metadata}/src/etc"
> +
> +  for alt_platform in ${ALT_PLATFORM}; do
> +    oe_runmake .examples "PLATFORM=${alt_platform}" \
> +      IPCTOOLS="${S_ipc-metadata}/src/etc"
> +  done
> +
> +  if [  "${PLATFORM}" != "UNKNOWN" ]; then
> +    oe_runmake extract HOSTOS="linux" IPC_INSTALL_DIR="${IPC_INSTALL_DIR}"
> +
> +    if [ ! -z ${ALT_PLATFORM} ]; then
> +      oe_runmake extract PLATFORM="${ALT_PLATFORM}" HOSTOS="linux" \
> +         IPC_INSTALL_DIR="${IPC_INSTALL_DIR}"
> +    fi
> +    oe_runmake -C ${EX02_PATH} all HOSTOS="linux" \
> +      LINUX_SYSROOT_DIR="${STAGING_INCDIR}" \
> +      IPC_INSTALL_DIR="${IPC_INSTALL_DIR}"
> +
> +    if [ ! -z ${ALT_PLATFORM} ]; then
> +      oe_runmake -C ${EX02_PATH} all HOSTOS="linux" \
> +        LINUX_SYSROOT_DIR="${STAGING_INCDIR}" \
> +        IPC_INSTALL_DIR="${IPC_INSTALL_DIR}" \
> +        PLATFORM="${ALT_PLATFORM}"
> +    fi
> +  fi
> +}
> +
> +do_install() {
> +  cd ${S_ipc-examples}/src
> +
> +  if [  "${PLATFORM}" != "UNKNOWN" ]; then
> +    # Install directory for linux examples
> +    install -d ${D}${bindir}/ipc/examples/ex02_messageq
> +    oe_runmake -C ${EX02_PATH} install IPC_INSTALL_DIR="${IPC_INSTALL_DIR}" \
> +      LINUX_SYSROOT_DIR="${STAGING_INCDIR}" \
> +      HOSTOS="linux" EXEC_DIR="${D}/${bindir}/ipc/examples/ex02_messageq"
> +
> +    if [ ! -z ${ALT_PLATFORM} ]; then
> +      oe_runmake -C ${EX02_PATH} install IPC_INSTALL_DIR="${IPC_INSTALL_DIR}" \
> +        LINUX_SYSROOT_DIR="${STAGING_INCDIR}" \
> +        HOSTOS="linux" EXEC_DIR="${D}/${bindir}/ipc/examples/ex02_messageq" \
> +        PLATFORM="${ALT_PLATFORM}"
> +    fi
> +  fi
> +}
> +
> +FILES:${PN} += "${bindir}/*"

Re: [master/scarthgap][PATCH v2 1/5] ti-ipc-examples-linux: Add a recipe to build messageq app_host

[Andrew Davis]

On 8/6/25 12:04 PM, Beleswar Padhi wrote:
> Add a recipe to build the Application Host (for A15 core) to demonstrate
> IPC with remote processors through messageq firmware. Also package this
> in the /usr/bin directory for testing IPC. This recipe only builds the
> app_host, and the firmwares are available in ti-linux-firmware
> repository.
> 
> Signed-off-by: Beleswar Padhi <b-padhi@ti.com>
> ---
>   .../ipc/ti-ipc-examples-linux_git.bb          | 68 +++++++++++++++++++
>   1 file changed, 68 insertions(+)
>   create mode 100644 meta-ti-extras/recipes-ti/ipc/ti-ipc-examples-linux_git.bb
> 
> diff --git a/meta-ti-extras/recipes-ti/ipc/ti-ipc-examples-linux_git.bb b/meta-ti-extras/recipes-ti/ipc/ti-ipc-examples-linux_git.bb
> new file mode 100644
> index 00000000..3a64409e
> --- /dev/null
> +++ b/meta-ti-extras/recipes-ti/ipc/ti-ipc-examples-linux_git.bb
> @@ -0,0 +1,68 @@
> +DESCRIPTION = "TI Inter Processor Communication (IPC) MessageQ Application for
> +Linux Host"
> +
> +require recipes-ti/ipc/ti-ipc-common.inc
> +require ti-ipc-rtos.inc
> +
> +LICENSE = "BSD-3-Clause"
> +LIC_FILES_CHKSUM = "file://${S_ipc-examples}/src/makefile;beginline=1;endline=30;md5=a52324bd5033bb49ea07bade1244ac9a"
> +
> +INSANE_SKIP:${PN} += "arch"
> +
> +IPC_INSTALL_DIR = "${STAGING_DIR_TARGET}/usr/share/ti/ti-ipc-tree"
> +INHIBIT_PACKAGE_STRIP = "1"
> +
> +DEPENDS = "ti-ipc ti-ipc-rtos ti-xdctools-native zip-native"

Do we really depend on "ti-ipc-rtos"? Once we add pre-built IPUMM firmware
to linux-firmware, we should be able to drop the "ti-sysbios" recipe and
all the recipes that depend on it, including ti-ipc-rtos.

Andrew

> +
> +EX02_PATH = "examples/DRA7XX_linux_elf/ex02_messageq/host"
> +
> +do_compile() {
> +  cd ${S_ipc-examples}/src
> +  oe_runmake .examples \
> +    IPCTOOLS="${S_ipc-metadata}/src/etc"
> +
> +  for alt_platform in ${ALT_PLATFORM}; do
> +    oe_runmake .examples "PLATFORM=${alt_platform}" \
> +      IPCTOOLS="${S_ipc-metadata}/src/etc"
> +  done
> +
> +  if [  "${PLATFORM}" != "UNKNOWN" ]; then
> +    oe_runmake extract HOSTOS="linux" IPC_INSTALL_DIR="${IPC_INSTALL_DIR}"
> +
> +    if [ ! -z ${ALT_PLATFORM} ]; then
> +      oe_runmake extract PLATFORM="${ALT_PLATFORM}" HOSTOS="linux" \
> +         IPC_INSTALL_DIR="${IPC_INSTALL_DIR}"
> +    fi
> +    oe_runmake -C ${EX02_PATH} all HOSTOS="linux" \
> +      LINUX_SYSROOT_DIR="${STAGING_INCDIR}" \
> +      IPC_INSTALL_DIR="${IPC_INSTALL_DIR}"
> +
> +    if [ ! -z ${ALT_PLATFORM} ]; then
> +      oe_runmake -C ${EX02_PATH} all HOSTOS="linux" \
> +        LINUX_SYSROOT_DIR="${STAGING_INCDIR}" \
> +        IPC_INSTALL_DIR="${IPC_INSTALL_DIR}" \
> +        PLATFORM="${ALT_PLATFORM}"
> +    fi
> +  fi
> +}
> +
> +do_install() {
> +  cd ${S_ipc-examples}/src
> +
> +  if [  "${PLATFORM}" != "UNKNOWN" ]; then
> +    # Install directory for linux examples
> +    install -d ${D}${bindir}/ipc/examples/ex02_messageq
> +    oe_runmake -C ${EX02_PATH} install IPC_INSTALL_DIR="${IPC_INSTALL_DIR}" \
> +      LINUX_SYSROOT_DIR="${STAGING_INCDIR}" \
> +      HOSTOS="linux" EXEC_DIR="${D}/${bindir}/ipc/examples/ex02_messageq"
> +
> +    if [ ! -z ${ALT_PLATFORM} ]; then
> +      oe_runmake -C ${EX02_PATH} install IPC_INSTALL_DIR="${IPC_INSTALL_DIR}" \
> +        LINUX_SYSROOT_DIR="${STAGING_INCDIR}" \
> +        HOSTOS="linux" EXEC_DIR="${D}/${bindir}/ipc/examples/ex02_messageq" \
> +        PLATFORM="${ALT_PLATFORM}"
> +    fi
> +  fi
> +}
> +
> +FILES:${PN} += "${bindir}/*"

Re: [master/scarthgap][PATCH v2 1/5] ti-ipc-examples-linux: Add a recipe to build messageq app_host

[Beleswar Prasad Padhi]

On 07/08/25 19:24, Andrew Davis wrote:
> On 8/6/25 12:04 PM, Beleswar Padhi wrote:
>> Add a recipe to build the Application Host (for A15 core) to demonstrate
>> IPC with remote processors through messageq firmware. Also package this
>> in the /usr/bin directory for testing IPC. This recipe only builds the
>> app_host, and the firmwares are available in ti-linux-firmware
>> repository.
>>
>> Signed-off-by: Beleswar Padhi <b-padhi@ti.com>
>> ---
>>   .../ipc/ti-ipc-examples-linux_git.bb          | 68 +++++++++++++++++++
>>   1 file changed, 68 insertions(+)
>>   create mode 100644 meta-ti-extras/recipes-ti/ipc/ti-ipc-examples-linux_git.bb
>>
>> diff --git a/meta-ti-extras/recipes-ti/ipc/ti-ipc-examples-linux_git.bb b/meta-ti-extras/recipes-ti/ipc/ti-ipc-examples-linux_git.bb
>> new file mode 100644
>> index 00000000..3a64409e
>> --- /dev/null
>> +++ b/meta-ti-extras/recipes-ti/ipc/ti-ipc-examples-linux_git.bb
>> @@ -0,0 +1,68 @@
>> +DESCRIPTION = "TI Inter Processor Communication (IPC) MessageQ Application for
>> +Linux Host"
>> +
>> +require recipes-ti/ipc/ti-ipc-common.inc
>> +require ti-ipc-rtos.inc
>> +
>> +LICENSE = "BSD-3-Clause"
>> +LIC_FILES_CHKSUM = "file://${S_ipc-examples}/src/makefile;beginline=1;endline=30;md5=a52324bd5033bb49ea07bade1244ac9a"
>> +
>> +INSANE_SKIP:${PN} += "arch"
>> +
>> +IPC_INSTALL_DIR = "${STAGING_DIR_TARGET}/usr/share/ti/ti-ipc-tree"
>> +INHIBIT_PACKAGE_STRIP = "1"
>> +
>> +DEPENDS = "ti-ipc ti-ipc-rtos ti-xdctools-native zip-native"
>
> Do we really depend on "ti-ipc-rtos"? 


Sorry, missed this email. Right now, the ipc-examples build depends on the product.mak file which is from the ipcdev repo (ti-ipc-rtos recipe).
So we are dependent on this ti-ipc-rtos repo. Otherwise the builds fail.


> Once we add pre-built IPUMM firmware
> to linux-firmware, we should be able to drop the "ti-sysbios" recipe and
> all the recipes that depend on it, including ti-ipc-rtos.


There would be some work needed in the repos to be independent first before we drop these recipes.

Thanks,
Beleswar

>
> Andrew
>
>> +
>> +EX02_PATH = "examples/DRA7XX_linux_elf/ex02_messageq/host"
>> +
>> +do_compile() {
>> +  cd ${S_ipc-examples}/src
>> +  oe_runmake .examples \
>> +    IPCTOOLS="${S_ipc-metadata}/src/etc"
>> +
>> +  for alt_platform in ${ALT_PLATFORM}; do
>> +    oe_runmake .examples "PLATFORM=${alt_platform}" \
>> +      IPCTOOLS="${S_ipc-metadata}/src/etc"
>> +  done
>> +
>> +  if [  "${PLATFORM}" != "UNKNOWN" ]; then
>> +    oe_runmake extract HOSTOS="linux" IPC_INSTALL_DIR="${IPC_INSTALL_DIR}"
>> +
>> +    if [ ! -z ${ALT_PLATFORM} ]; then
>> +      oe_runmake extract PLATFORM="${ALT_PLATFORM}" HOSTOS="linux" \
>> +         IPC_INSTALL_DIR="${IPC_INSTALL_DIR}"
>> +    fi
>> +    oe_runmake -C ${EX02_PATH} all HOSTOS="linux" \
>> +      LINUX_SYSROOT_DIR="${STAGING_INCDIR}" \
>> +      IPC_INSTALL_DIR="${IPC_INSTALL_DIR}"
>> +
>> +    if [ ! -z ${ALT_PLATFORM} ]; then
>> +      oe_runmake -C ${EX02_PATH} all HOSTOS="linux" \
>> +        LINUX_SYSROOT_DIR="${STAGING_INCDIR}" \
>> +        IPC_INSTALL_DIR="${IPC_INSTALL_DIR}" \
>> +        PLATFORM="${ALT_PLATFORM}"
>> +    fi
>> +  fi
>> +}
>> +
>> +do_install() {
>> +  cd ${S_ipc-examples}/src
>> +
>> +  if [  "${PLATFORM}" != "UNKNOWN" ]; then
>> +    # Install directory for linux examples
>> +    install -d ${D}${bindir}/ipc/examples/ex02_messageq
>> +    oe_runmake -C ${EX02_PATH} install IPC_INSTALL_DIR="${IPC_INSTALL_DIR}" \
>> +      LINUX_SYSROOT_DIR="${STAGING_INCDIR}" \
>> +      HOSTOS="linux" EXEC_DIR="${D}/${bindir}/ipc/examples/ex02_messageq"
>> +
>> +    if [ ! -z ${ALT_PLATFORM} ]; then
>> +      oe_runmake -C ${EX02_PATH} install IPC_INSTALL_DIR="${IPC_INSTALL_DIR}" \
>> +        LINUX_SYSROOT_DIR="${STAGING_INCDIR}" \
>> +        HOSTOS="linux" EXEC_DIR="${D}/${bindir}/ipc/examples/ex02_messageq" \
>> +        PLATFORM="${ALT_PLATFORM}"
>> +    fi
>> +  fi
>> +}
>> +
>> +FILES:${PN} += "${bindir}/*"
>