[meta-oe][PATCH v2] bpftool: add new recipe

[meta-oe][PATCH v2] bpftool: add new recipe

[Daniel Díaz]

The bpftool allows for inspection and simple manipulation of
eBPF programs and maps, so common in the kernel selftests.

Signed-off-by: Daniel Díaz <daniel.diaz@linaro.org>
---
v2: Drop superfluous chown

 meta-oe/recipes-kernel/bpftool/bpftool.bb | 31 +++++++++++++++++++++++++++++++
 1 file changed, 31 insertions(+)
 create mode 100644 meta-oe/recipes-kernel/bpftool/bpftool.bb

diff --git a/meta-oe/recipes-kernel/bpftool/bpftool.bb b/meta-oe/recipes-kernel/bpftool/bpftool.bb
new file mode 100644
index 0000000..fd0653a
--- /dev/null
+++ b/meta-oe/recipes-kernel/bpftool/bpftool.bb
@@ -0,0 +1,31 @@
+SUMMARY = "Inspect and manipulate eBPF programs and maps"
+DESCRIPTION = "bpftool is a kernel tool for inspection and simple manipulation \
+of eBPF programs and maps."
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/GPL-2.0;md5=801f80980d171dd6425610833a22dbe6"
+DEPENDS = "binutils elfutils"
+PROVIDES = "virtual/bpftool"
+
+inherit bash-completion kernelsrc kernel-arch
+
+do_populate_lic[depends] += "virtual/kernel:do_patch"
+
+EXTRA_OEMAKE = "-C ${S}/tools/bpf/bpftool O=${B} CROSS=${TARGET_PREFIX} CC="${CC}" LD="${LD}" AR=${AR} ARCH=${ARCH}"
+
+do_configure[depends] += "virtual/kernel:do_shared_workdir"
+
+do_compile() {
+    oe_runmake
+}
+
+do_install() {
+    oe_runmake DESTDIR=${D} install
+}
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+python do_package_prepend() {
+    d.setVar('PKGV', d.getVar("KERNEL_VERSION", True).split("-")[0])
+}
+
+B = "${WORKDIR}/${BPN}-${PV}"
-- 
2.7.4

Re: [meta-oe][PATCH v2] bpftool: add new recipe

[Trevor Woerner]

This recipe only works for kernels > 4.14-ish.
Some BSP layers aren't there yet (e.g. meta-qcom, meta-raspberrypi)
Is there an elegant way to handle this situation?

Re: [meta-oe][PATCH v2] bpftool: add new recipe

[akuster808]

On 09/18/2018 09:23 PM, Trevor Woerner wrote:
> This recipe only works for kernels > 4.14-ish.
> Some BSP layers aren't there yet (e.g. meta-qcom, meta-raspberrypi)
> Is there an elegant way to handle this situation?
Can you rdpends on a kernel version ?

Re: [meta-oe][PATCH v2] bpftool: add new recipe

[Trevor Woerner]

On Wed, Sep 19, 2018 at 12:36 AM, akuster808 <akuster808@gmail.com> wrote:

> On 09/18/2018 09:23 PM, Trevor Woerner wrote:
> > This recipe only works for kernels > 4.14-ish.
> > Some BSP layers aren't there yet (e.g. meta-qcom, meta-raspberrypi)
> > Is there an elegant way to handle this situation?
> Can you rdpends on a kernel version ?
>

Interesting, I hadn't noticed versioned RDEPENDS before.

I'm not sure what I'd use as the package. linux? linux-image? I've tried a
bunch of variations on the following incantation, but nothing seems to
trigger (testing specifically with rpi):

RDEPENDS_${PN} = "kernel-image-zimage (>= 4.15)"

Re: [meta-oe][PATCH v2] bpftool: add new recipe

[Trevor Woerner]

On Wed, Jun 27, 2018 at 1:43 PM, Daniel Díaz <daniel.diaz@linaro.org> wrote:

> +PROVIDES = "virtual/bpftool"
>

I'm curious about the above PROVIDES line. Are there more bpftools other
than the one in the linux kernel sources?