[PATCH 1/2] ti-syslink: Add TI Syslink for TI816x and TI814x devices

[PATCH 1/2] ti-syslink: Add TI Syslink for TI816x and TI814x devices

[Siddharth Heroor]

From: Siddharth Heroor <heroor@ti.com>

* Syslink is an Inter Processor communication layer for ARM/DSP devices.

Signed-off-by: Siddharth Heroor <heroor@ti.com>
---
 recipes/ti/ti-syslink.inc |  183 +++++++++++++++++++++++++++++++++++++++++++++
 1 files changed, 183 insertions(+), 0 deletions(-)
 create mode 100644 recipes/ti/ti-syslink.inc

diff --git a/recipes/ti/ti-syslink.inc b/recipes/ti/ti-syslink.inc
new file mode 100644
index 0000000..651d840
--- /dev/null
+++ b/recipes/ti/ti-syslink.inc
@@ -0,0 +1,183 @@
+DESCRIPTION = "SYSLINK Inter-Processor Communications (IPC) for TI ARM/DSP processors"
+HOMEPAGE = "http://software-dl.ti.com/dsps/dsps_public_sw/SysLink/index.html"
+SECTION = "devel"
+LICENSE = "BSD"
+
+require ti-paths.inc
+require ti-staging.inc
+
+COMPATIBLE_MACHINE = "(ti816x|ti814x)"
+
+PROVIDES = "ti-syslink-module"
+PROVIDES += "ti-syslink-examples"
+
+# This package builds a kernel module, use kernel PR as base and append a local version
+PR = "${MACHINE_KERNEL_PR}"
+PR_append = "j"
+
+S = "${WORKDIR}/syslink_${PV}"
+
+SRC_URI = "http://software-dl.ti.com/dsps/dsps_public_sw/SysLink/${PV}/exports/syslink_${PV}.tar.gz;name=syslinktarball"
+
+DEPENDS = "ti-sysbios ti-xdctools ti-cgt6x ti-ipc" 
+DEPENDS += "virtual/kernel" 
+
+# Define Syslink variables. 
+SYSLINKHLOSSAMPLES  = "procMgr frameq gateMP heapBufMP heapMemMP listMP messageQ notify ringIO ringIO_gpp sharedRegion"
+SYSLINKPLATFORM    ?= "TI81XX"
+SYSLINKSUFFIX      ?= "xe674"
+SYSLINKLOADER      ?= "ELF"
+
+SYSLINKVARIANT_ti816x  = "TI816X"
+SYSLINKVARIANT_ti814x  = "TI814X"
+SYSLINKVARIANT     ?= "<UNDEFINED_SYSLINKVARIANT>"
+
+# Export additional variables needed by build
+XDCTARGETS         ?= "ti.targets.elf.C674"
+export XDCTARGETS
+
+SYSLINK_ROOT = "${S}"
+export SYSLINK_ROOT
+
+XDCPATH = "${IPC_INSTALL_DIR}/packages;${SYSBIOS_INSTALL_DIR}/packages" 
+export XDCPATH
+
+XDCBUILDCFG="${SYSLINK_ROOT}/config.bld"
+export XDCBUILDCFG
+
+do_configure() {
+    # Update config.bld with rootDir paths for CodeGen Tools
+    # Build only C674 Elf.
+    sed -i \
+        -e s:^C674_ELF.rootDir.*:C674_ELF.rootDir\ =\ \"${CODEGEN_INSTALL_DIR}\":g \
+        -e s:C64P_COFF,://C64P_COFF:g \
+        -e s:C64P_ELF,://C64P_ELF:g \
+	-e s:C674_COFF,://C674_COFF:g \
+        -e s:C674_ELF,:C674_ELF:g \
+        -e s:M3_ELF,://M3_ELF:g \
+        -e s:A8_ELF$://A8_ELF:g \
+        -e 's/"ti.platforms.evmDA830:dsp",//g' \
+        ${S}/config.bld
+}
+
+do_prepsources () {
+    # Prepare the tree for rebuilding - clean and generate interfaces
+    cd ${SYSLINK_ROOT}/ti/syslink    
+    ${XDC_INSTALL_DIR}/xdc .make -PR .
+    ${XDC_INSTALL_DIR}/xdc clean -PR .
+    ${XDC_INSTALL_DIR}/xdc .interfaces -PR .
+}
+
+addtask prepsources after do_configure before do_compile
+
+do_compile() {
+    unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS
+
+    # Build the gpp (hlos) kernel space
+    cd ${S}/ti/syslink/utils/hlos/knl/Linux && make \
+        ARCH="${TARGET_ARCH}" \
+        CROSS_COMPILE="${TARGET_PREFIX}" \
+        SYSLINK_PLATFORM="${SYSLINKPLATFORM}" \
+        SYSLINK_VARIANT="${SYSLINKVARIANT}" \
+        SYSLINK_LOADER="${SYSLINKLOADER}" \
+        SYSLINK_PKGPATH="${IPC_INSTALL_DIR}/packages" \
+        KDIR="${STAGING_KERNEL_DIR}"
+
+    # Build the gpp (hlos) kernel space samples. 
+    for sample in ${SYSLINKHLOSSAMPLES}; do
+        cd ${S}/ti/syslink/samples/hlos/$sample/knl/Linux && make \
+            ARCH="${TARGET_ARCH}" \
+            CROSS_COMPILE="${TARGET_PREFIX}" \
+            SYSLINK_PLATFORM="${SYSLINKPLATFORM}" \
+            SYSLINK_VARIANT="${SYSLINKVARIANT}" \
+            SYSLINK_LOADER="${SYSLINKLOADER}" \
+            SYSLINK_PKGPATH="${IPC_INSTALL_DIR}/packages" \
+            SYSLINK_SDK=EZSDK \
+            KDIR="${STAGING_KERNEL_DIR}"
+    done
+
+    # Build the gpp (hlos) user space
+    cd ${S}/ti/syslink/utils/hlos/usr/Linux && make \
+        ARCH="${TARGET_ARCH}" \
+        CROSS_COMPILE="${TARGET_PREFIX}" \
+        TOOLCHAIN_PREFIX="${TOOLCHAIN_PATH}/bin/${TARGET_PREFIX}" \
+        SYSLINK_PLATFORM="${SYSLINKPLATFORM}" \
+        SYSLINK_VARIANT="${SYSLINKVARIANT}" \
+        SYSLINK_LOADER="${SYSLINKLOADER}" \
+        SYSLINK_PKGPATH="${IPC_INSTALL_DIR}/packages"
+
+    # Build the gpp (hlos) user space samples 
+    # First build the common lib for samples.
+    cd ${S}/ti/syslink/samples/hlos/common/usr/Linux && make \
+        ARCH="${TARGET_ARCH}" \
+        CROSS_COMPILE="${TARGET_PREFIX}" \
+        TOOLCHAIN_PREFIX="${TOOLCHAIN_PATH}/bin/${TARGET_PREFIX}" \
+        SYSLINK_PLATFORM="${SYSLINKPLATFORM}" \
+        SYSLINK_VARIANT="${SYSLINKVARIANT}" \
+        SYSLINK_LOADER="${SYSLINKLOADER}" \
+        SYSLINK_SDK=EZSDK \
+        SYSLINK_PKGPATH="${IPC_INSTALL_DIR}/packages"
+
+    for sample in ${SYSLINKHLOSSAMPLES}; do
+        cd ${S}/ti/syslink/samples/hlos/$sample/usr/Linux && make \
+            ARCH="${TARGET_ARCH}" \
+            CROSS_COMPILE="${TARGET_PREFIX}" \
+            TOOLCHAIN_PREFIX="${TOOLCHAIN_PATH}/bin/${TARGET_PREFIX}" \
+            SYSLINK_PLATFORM="${SYSLINKPLATFORM}" \
+            SYSLINK_VARIANT="${SYSLINKVARIANT}" \
+            SYSLINK_LOADER="${SYSLINKLOADER}" \
+            SYSLINK_SDK=EZSDK \
+            SYSLINK_PKGPATH="${IPC_INSTALL_DIR}/packages"
+    done
+
+    # Build the dsp/arm (rtos) code (system)
+    cd ${S}/ti/syslink && \
+        ${XDC_INSTALL_DIR}/xdc -P \
+	 `${XDC_INSTALL_DIR}/bin/xdcpkg ${SYSLINK_ROOT}/ti/syslink | grep -v samples`
+
+    # Build the dsp/arm (rtos) code (samples)
+    export XDCARGS="profile=debug"
+    cd ${S}/ti/syslink && \
+        ${XDC_INSTALL_DIR}/xdc --jobs=${BB_NUMBER_THREADS} -P \
+	 `${XDC_INSTALL_DIR}/bin/xdcpkg ${SYSLINK_ROOT}/ti/syslink | grep samples`
+}
+
+do_install () {
+    # Install the hlos kernel module
+    install -d ${D}/lib/modules/${KERNEL_VERSION}/kernel/drivers/dsp
+    install -m 0755 ${S}/ti/syslink/bin/${SYSLINKVARIANT}/syslink.ko ${D}/lib/modules/${KERNEL_VERSION}/kernel/drivers/dsp/
+
+    # Install the hlos examples
+    install -d ${D}/${installdir}/ti-syslink-examples
+    install -m 0755 ${S}/ti/syslink/bin/${SYSLINKVARIANT}/samples/* ${D}/${installdir}/ti-syslink-examples/
+
+    # Install the rtos examples
+    cd ${S}/ti/syslink/samples/rtos
+    for i in $(find . -name "*.${SYSLINKSUFFIX}"); do
+        install -d ${D}/${installdir}/ti-syslink-examples/`dirname ${i} | cut -f4 -d /`
+        install ${i} ${D}/${installdir}/ti-syslink-examples/`dirname ${i} | cut -f4 -d /`
+    done
+
+    # Install/Stage the Source Tree
+    install -d ${D}${SYSLINK_INSTALL_DIR_RECIPE}
+    cp -pPrf ${S}/* ${D}${SYSLINK_INSTALL_DIR_RECIPE}
+}
+
+PACKAGES += "ti-syslink-module"
+FILES_ti-syslink-module = "/lib/modules/${KERNEL_VERSION}/kernel/drivers/dsp/syslink.ko" 
+RDEPENDS_ti-syslink-module += "update-modules"
+
+pkg_postinst_ti-syslink-module () {
+#!/bin/sh
+if [ -n "$D" ]; then
+	exit 1
+fi
+
+depmod -a
+update-modules || true
+}
+
+pkg_postrm_ti-syslink-module () {
+#!/bin/sh
+update-modules || true
+}
-- 
1.7.0.4

[PATCH 2/2] ti-syslink: Add release 02.00.00.68.

[Siddharth Heroor]

From: Siddharth Heroor <heroor@ti.com>


Signed-off-by: Siddharth Heroor <heroor@ti.com>
---
 recipes/ti/ti-syslink_02.00.00.68.bb |   12 ++++++++++++
 1 files changed, 12 insertions(+), 0 deletions(-)
 create mode 100644 recipes/ti/ti-syslink_02.00.00.68.bb

diff --git a/recipes/ti/ti-syslink_02.00.00.68.bb b/recipes/ti/ti-syslink_02.00.00.68.bb
new file mode 100644
index 0000000..6ae07ae
--- /dev/null
+++ b/recipes/ti/ti-syslink_02.00.00.68.bb
@@ -0,0 +1,12 @@
+require ti-syslink.inc
+
+PV = "02_00_00_68"
+
+# This release appends a beta tag to PV.
+PVExtra = "_beta1"
+S = "${WORKDIR}/syslink_${PV}${PVExtra}"
+
+SRC_URI = "http://software-dl.ti.com/dsps/dsps_public_sw/SysLink/${PV}${PVExtra}/exports/syslink_${PV}${PVExtra}.tar.gz;name=syslinktarball"
+
+SRC_URI[syslinktarball.md5sum] = "468034372124f70f82b60cfb5f11c8e8"
+SRC_URI[syslinktarball.sha256sum] = "ed574dcb3a5477cfbc69a1c9e768d5197291cb057d19fd791e16e1c89af3e8e1"
-- 
1.7.0.4

Re: [PATCH 1/2] ti-syslink: Add TI Syslink for TI816x and TI814x devices

[Koen Kooi]

-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1

On 05-04-11 17:10, Siddharth Heroor wrote:
> From: Siddharth Heroor <heroor@ti.com>
> 
> * Syslink is an Inter Processor communication layer for ARM/DSP devices.

NAK!

1) This has way too much copy/paste crud from dsplink that needs to get
cleaned up, some highlights:

> +PROVIDES = "ti-syslink-module"
> +PROVIDES += "ti-syslink-examples"
> +PR_append = "j"

2) inconsistent whitespace every where, do_compile is the worst

3) This really needs to get split into 2 recipes: one for the kernel
modules using module.bbclass and one for the userspace bits.

4) The platform defines seem to be better suited for e.g. ti-paths.inc

> 
> Signed-off-by: Siddharth Heroor <heroor@ti.com>
> ---
>  recipes/ti/ti-syslink.inc |  183 +++++++++++++++++++++++++++++++++++++++++++++
>  1 files changed, 183 insertions(+), 0 deletions(-)
>  create mode 100644 recipes/ti/ti-syslink.inc
> 
> diff --git a/recipes/ti/ti-syslink.inc b/recipes/ti/ti-syslink.inc
> new file mode 100644
> index 0000000..651d840
> --- /dev/null
> +++ b/recipes/ti/ti-syslink.inc
> @@ -0,0 +1,183 @@
> +DESCRIPTION = "SYSLINK Inter-Processor Communications (IPC) for TI ARM/DSP processors"
> +HOMEPAGE = "http://software-dl.ti.com/dsps/dsps_public_sw/SysLink/index.html"
> +SECTION = "devel"
> +LICENSE = "BSD"
> +
> +require ti-paths.inc
> +require ti-staging.inc
> +
> +COMPATIBLE_MACHINE = "(ti816x|ti814x)"
> +

> +
> +# This package builds a kernel module, use kernel PR as base and append a local version
> +PR = "${MACHINE_KERNEL_PR}"

> +
> +S = "${WORKDIR}/syslink_${PV}"
> +
> +SRC_URI = "http://software-dl.ti.com/dsps/dsps_public_sw/SysLink/${PV}/exports/syslink_${PV}.tar.gz;name=syslinktarball"
> +
> +DEPENDS = "ti-sysbios ti-xdctools ti-cgt6x ti-ipc" 
> +DEPENDS += "virtual/kernel" 
> +
> +# Define Syslink variables. 
> +SYSLINKHLOSSAMPLES  = "procMgr frameq gateMP heapBufMP heapMemMP listMP messageQ notify ringIO ringIO_gpp sharedRegion"
> +SYSLINKPLATFORM    ?= "TI81XX"
> +SYSLINKSUFFIX      ?= "xe674"
> +SYSLINKLOADER      ?= "ELF"
> +
> +SYSLINKVARIANT_ti816x  = "TI816X"
> +SYSLINKVARIANT_ti814x  = "TI814X"
> +SYSLINKVARIANT     ?= "<UNDEFINED_SYSLINKVARIANT>"
> +
> +# Export additional variables needed by build
> +XDCTARGETS         ?= "ti.targets.elf.C674"
> +export XDCTARGETS
> +
> +SYSLINK_ROOT = "${S}"
> +export SYSLINK_ROOT
> +
> +XDCPATH = "${IPC_INSTALL_DIR}/packages;${SYSBIOS_INSTALL_DIR}/packages" 
> +export XDCPATH
> +
> +XDCBUILDCFG="${SYSLINK_ROOT}/config.bld"
> +export XDCBUILDCFG
> +
> +do_configure() {
> +    # Update config.bld with rootDir paths for CodeGen Tools
> +    # Build only C674 Elf.
> +    sed -i \
> +        -e s:^C674_ELF.rootDir.*:C674_ELF.rootDir\ =\ \"${CODEGEN_INSTALL_DIR}\":g \
> +        -e s:C64P_COFF,://C64P_COFF:g \
> +        -e s:C64P_ELF,://C64P_ELF:g \
> +	-e s:C674_COFF,://C674_COFF:g \
> +        -e s:C674_ELF,:C674_ELF:g \
> +        -e s:M3_ELF,://M3_ELF:g \
> +        -e s:A8_ELF$://A8_ELF:g \
> +        -e 's/"ti.platforms.evmDA830:dsp",//g' \
> +        ${S}/config.bld
> +}
> +
> +do_prepsources () {
> +    # Prepare the tree for rebuilding - clean and generate interfaces
> +    cd ${SYSLINK_ROOT}/ti/syslink    
> +    ${XDC_INSTALL_DIR}/xdc .make -PR .
> +    ${XDC_INSTALL_DIR}/xdc clean -PR .
> +    ${XDC_INSTALL_DIR}/xdc .interfaces -PR .
> +}
> +
> +addtask prepsources after do_configure before do_compile
> +
> +do_compile() {
> +    unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS
> +
> +    # Build the gpp (hlos) kernel space
> +    cd ${S}/ti/syslink/utils/hlos/knl/Linux && make \
> +        ARCH="${TARGET_ARCH}" \
> +        CROSS_COMPILE="${TARGET_PREFIX}" \
> +        SYSLINK_PLATFORM="${SYSLINKPLATFORM}" \
> +        SYSLINK_VARIANT="${SYSLINKVARIANT}" \
> +        SYSLINK_LOADER="${SYSLINKLOADER}" \
> +        SYSLINK_PKGPATH="${IPC_INSTALL_DIR}/packages" \
> +        KDIR="${STAGING_KERNEL_DIR}"
> +
> +    # Build the gpp (hlos) kernel space samples. 
> +    for sample in ${SYSLINKHLOSSAMPLES}; do
> +        cd ${S}/ti/syslink/samples/hlos/$sample/knl/Linux && make \
> +            ARCH="${TARGET_ARCH}" \
> +            CROSS_COMPILE="${TARGET_PREFIX}" \
> +            SYSLINK_PLATFORM="${SYSLINKPLATFORM}" \
> +            SYSLINK_VARIANT="${SYSLINKVARIANT}" \
> +            SYSLINK_LOADER="${SYSLINKLOADER}" \
> +            SYSLINK_PKGPATH="${IPC_INSTALL_DIR}/packages" \
> +            SYSLINK_SDK=EZSDK \
> +            KDIR="${STAGING_KERNEL_DIR}"
> +    done
> +
> +    # Build the gpp (hlos) user space
> +    cd ${S}/ti/syslink/utils/hlos/usr/Linux && make \
> +        ARCH="${TARGET_ARCH}" \
> +        CROSS_COMPILE="${TARGET_PREFIX}" \
> +        TOOLCHAIN_PREFIX="${TOOLCHAIN_PATH}/bin/${TARGET_PREFIX}" \
> +        SYSLINK_PLATFORM="${SYSLINKPLATFORM}" \
> +        SYSLINK_VARIANT="${SYSLINKVARIANT}" \
> +        SYSLINK_LOADER="${SYSLINKLOADER}" \
> +        SYSLINK_PKGPATH="${IPC_INSTALL_DIR}/packages"
> +
> +    # Build the gpp (hlos) user space samples 
> +    # First build the common lib for samples.
> +    cd ${S}/ti/syslink/samples/hlos/common/usr/Linux && make \
> +        ARCH="${TARGET_ARCH}" \
> +        CROSS_COMPILE="${TARGET_PREFIX}" \
> +        TOOLCHAIN_PREFIX="${TOOLCHAIN_PATH}/bin/${TARGET_PREFIX}" \
> +        SYSLINK_PLATFORM="${SYSLINKPLATFORM}" \
> +        SYSLINK_VARIANT="${SYSLINKVARIANT}" \
> +        SYSLINK_LOADER="${SYSLINKLOADER}" \
> +        SYSLINK_SDK=EZSDK \
> +        SYSLINK_PKGPATH="${IPC_INSTALL_DIR}/packages"
> +
> +    for sample in ${SYSLINKHLOSSAMPLES}; do
> +        cd ${S}/ti/syslink/samples/hlos/$sample/usr/Linux && make \
> +            ARCH="${TARGET_ARCH}" \
> +            CROSS_COMPILE="${TARGET_PREFIX}" \
> +            TOOLCHAIN_PREFIX="${TOOLCHAIN_PATH}/bin/${TARGET_PREFIX}" \
> +            SYSLINK_PLATFORM="${SYSLINKPLATFORM}" \
> +            SYSLINK_VARIANT="${SYSLINKVARIANT}" \
> +            SYSLINK_LOADER="${SYSLINKLOADER}" \
> +            SYSLINK_SDK=EZSDK \
> +            SYSLINK_PKGPATH="${IPC_INSTALL_DIR}/packages"
> +    done
> +
> +    # Build the dsp/arm (rtos) code (system)
> +    cd ${S}/ti/syslink && \
> +        ${XDC_INSTALL_DIR}/xdc -P \
> +	 `${XDC_INSTALL_DIR}/bin/xdcpkg ${SYSLINK_ROOT}/ti/syslink | grep -v samples`
> +
> +    # Build the dsp/arm (rtos) code (samples)
> +    export XDCARGS="profile=debug"
> +    cd ${S}/ti/syslink && \
> +        ${XDC_INSTALL_DIR}/xdc --jobs=${BB_NUMBER_THREADS} -P \
> +	 `${XDC_INSTALL_DIR}/bin/xdcpkg ${SYSLINK_ROOT}/ti/syslink | grep samples`
> +}
> +
> +do_install () {
> +    # Install the hlos kernel module
> +    install -d ${D}/lib/modules/${KERNEL_VERSION}/kernel/drivers/dsp
> +    install -m 0755 ${S}/ti/syslink/bin/${SYSLINKVARIANT}/syslink.ko ${D}/lib/modules/${KERNEL_VERSION}/kernel/drivers/dsp/
> +
> +    # Install the hlos examples
> +    install -d ${D}/${installdir}/ti-syslink-examples
> +    install -m 0755 ${S}/ti/syslink/bin/${SYSLINKVARIANT}/samples/* ${D}/${installdir}/ti-syslink-examples/
> +
> +    # Install the rtos examples
> +    cd ${S}/ti/syslink/samples/rtos
> +    for i in $(find . -name "*.${SYSLINKSUFFIX}"); do
> +        install -d ${D}/${installdir}/ti-syslink-examples/`dirname ${i} | cut -f4 -d /`
> +        install ${i} ${D}/${installdir}/ti-syslink-examples/`dirname ${i} | cut -f4 -d /`
> +    done
> +
> +    # Install/Stage the Source Tree
> +    install -d ${D}${SYSLINK_INSTALL_DIR_RECIPE}
> +    cp -pPrf ${S}/* ${D}${SYSLINK_INSTALL_DIR_RECIPE}
> +}
> +
> +PACKAGES += "ti-syslink-module"
> +FILES_ti-syslink-module = "/lib/modules/${KERNEL_VERSION}/kernel/drivers/dsp/syslink.ko" 
> +RDEPENDS_ti-syslink-module += "update-modules"
> +
> +pkg_postinst_ti-syslink-module () {
> +#!/bin/sh
> +if [ -n "$D" ]; then
> +	exit 1
> +fi
> +
> +depmod -a
> +update-modules || true
> +}
> +
> +pkg_postrm_ti-syslink-module () {
> +#!/bin/sh
> +update-modules || true
> +}

-----BEGIN PGP SIGNATURE-----
Version: GnuPG v1.4.5 (Darwin)

iD8DBQFNm0BJMkyGM64RGpERAqy5AJ9T3vsdHIinTlVPOLVPVzqheFzqIgCcCVnW
qCNQqh3vixfM9CqJH0quZL0=
=Vgxn
-----END PGP SIGNATURE-----

Re: [PATCH 1/2] ti-syslink: Add TI Syslink for TI816x and TI814x devices

[Siddharth Heroor]

On Tue, Apr 5, 2011 at 9:46 PM, Koen Kooi <koen@dominion.thruhere.net> wrote:
> -----BEGIN PGP SIGNED MESSAGE-----
> Hash: SHA1
>
> On 05-04-11 17:10, Siddharth Heroor wrote:
>> From: Siddharth Heroor <heroor@ti.com>
>>
>> * Syslink is an Inter Processor communication layer for ARM/DSP devices.
>
> NAK!
>
> 1) This has way too much copy/paste crud from dsplink that needs to get
> cleaned up, some highlights:
Yes, I did follow precedence and use what was already present in OE.

>
>> +PROVIDES = "ti-syslink-module"
>> +PROVIDES += "ti-syslink-examples"
>> +PR_append = "j"
>
> 2) inconsistent whitespace every where, do_compile is the worst
>
> 3) This really needs to get split into 2 recipes: one for the kernel
> modules using module.bbclass and one for the userspace bits.

I can split the examples and libraries into two recipes, but we may need the
kernel module and libraries to be staged together. What would you suggest
I do to keep them together when staging?

>
> 4) The platform defines seem to be better suited for e.g. ti-paths.inc

Would moving all the defines into a separate ti-syslink-env.inc be good or does
it have to be in ti-paths.inc. I'm not keen on keep all the syslink
defines in ti-paths.inc
as its unrelated to the other recipes that use ti-paths.inc.

-- 
Sid

Re: [PATCH 1/2] ti-syslink: Add TI Syslink for TI816x and TI814x devices

[Koen Kooi]

-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1

On 06-04-11 04:42, Siddharth Heroor wrote:
> On Tue, Apr 5, 2011 at 9:46 PM, Koen Kooi <koen@dominion.thruhere.net> wrote:
>> -----BEGIN PGP SIGNED MESSAGE-----
>> Hash: SHA1
>>
>> On 05-04-11 17:10, Siddharth Heroor wrote:
>>> From: Siddharth Heroor <heroor@ti.com>
>>>
>>> * Syslink is an Inter Processor communication layer for ARM/DSP devices.
>>
>> NAK!
>>
>> 1) This has way too much copy/paste crud from dsplink that needs to get
>> cleaned up, some highlights:
> Yes, I did follow precedence and use what was already present in OE.
> 
>>
>>> +PROVIDES = "ti-syslink-module"
>>> +PROVIDES += "ti-syslink-examples"
>>> +PR_append = "j"
>>
>> 2) inconsistent whitespace every where, do_compile is the worst
>>
>> 3) This really needs to get split into 2 recipes: one for the kernel
>> modules using module.bbclass and one for the userspace bits.
> 
> I can split the examples and libraries into two recipes, but we may need the
> kernel module and libraries to be staged together. What would you suggest
> I do to keep them together when staging?

You don't need to stage the kernel modules, only the symbol map. And I
doubt even that is necessary looking at the syslink diagrams.

>> 4) The platform defines seem to be better suited for e.g. ti-paths.inc
> 
> Would moving all the defines into a separate ti-syslink-env.inc be good or does
> it have to be in ti-paths.inc. I'm not keen on keep all the syslink
> defines in ti-paths.inc
> as its unrelated to the other recipes that use ti-paths.inc.

And a related question, why is this version of syslink so convoluted
compared to
http://cgit.openembedded.org/cgit.cgi/openembedded/tree/recipes/ti/ti-syslink_git.bb
?
-----BEGIN PGP SIGNATURE-----
Version: GnuPG v1.4.5 (Darwin)

iD8DBQFNnBYtMkyGM64RGpERArn6AKCKCyr22nEDOFPTahnnhsqvvNQbWwCePna9
AplUQiJ0epW8GZ/rzsSBoOo=
=Jrak
-----END PGP SIGNATURE-----