All of lore.kernel.org
 help / color / mirror / Atom feed
* [meta-oe][PATCHv2] libsdl3: add recipe
@ 2025-03-13 12:03 Markus Volk
  2025-03-13 12:44 ` [oe] " Gyorgy Sarvari
  0 siblings, 1 reply; 8+ messages in thread
From: Markus Volk @ 2025-03-13 12:03 UTC (permalink / raw)
  To: openembedded-devel

Signed-off-by: Markus Volk <f_l_k@t-online.de>
---
 .../recipes-graphics/libsdl3/libsdl3_3.2.8.bb | 83 +++++++++++++++++++
 1 file changed, 83 insertions(+)
 create mode 100644 meta-oe/recipes-graphics/libsdl3/libsdl3_3.2.8.bb

diff --git a/meta-oe/recipes-graphics/libsdl3/libsdl3_3.2.8.bb b/meta-oe/recipes-graphics/libsdl3/libsdl3_3.2.8.bb
new file mode 100644
index 0000000000..9c4fa317a2
--- /dev/null
+++ b/meta-oe/recipes-graphics/libsdl3/libsdl3_3.2.8.bb
@@ -0,0 +1,83 @@
+SUMMARY = "Simple DirectMedia Layer"
+DESCRIPTION = "Simple DirectMedia Layer is a cross-platform multimedia \
+library designed to provide low level access to audio, keyboard, mouse, \
+joystick, 3D hardware via OpenGL, and 2D video framebuffer."
+HOMEPAGE = "http://www.libsdl.org"
+BUGTRACKER = "http://bugzilla.libsdl.org/"
+
+SECTION = "libs"
+
+LICENSE = "Zlib & BSD-2-Clause"
+LIC_FILES_CHKSUM = "\
+    file://LICENSE.txt;md5=cbf0e3161523f9a9315b6b915c5c4457 \
+    file://src/hidapi/LICENSE.txt;md5=7c3949a631240cb6c31c50f3eb696077 \
+    file://src/hidapi/LICENSE-bsd.txt;md5=b5fa085ce0926bb50d0621620a82361f \
+    file://src/video/yuv2rgb/LICENSE;md5=79f8f3418d91531e05f0fc94ca67e071 \
+"
+
+# arm-neon adds MIT license
+LICENSE:append = " ${@bb.utils.contains('PACKAGECONFIG', 'arm-neon', '& MIT', '', d)}"
+LIC_FILES_CHKSUM:append = " ${@bb.utils.contains('PACKAGECONFIG', 'arm-neon', 'file://src/video/arm/pixman-arm-neon-asm.h;md5=9a9cc1e51abbf1da58f4d9528ec9d49b;beginline=1;endline=24', '', d)}"
+
+PROVIDES = "virtual/libsdl3"
+
+SRC_URI = "http://www.libsdl.org/release/SDL3-${PV}.tar.gz"
+
+S = "${WORKDIR}/SDL3-${PV}"
+
+SRC_URI[sha256sum] = "13388fabb361de768ecdf2b65e52bb27d1054cae6ccb6942ba926e378e00db03"
+
+inherit cmake lib_package binconfig-disabled pkgconfig upstream-version-is-even
+
+CVE_PRODUCT = "simple_directmedia_layer sdl"
+
+EXTRA_OECMAKE = " \
+	-DSDL_OSS_DEFAULT=OFF \
+	-DSDL_DISKAUDIO=OFF \
+	-DSDL_DUMMYVIDEO=OFF \
+	-DSDL_RPI=OFF \
+	-DSDL_PTHREADS=ON \
+	-DSDL_RPATH=OFF \
+	-DSDL_SNDIO=OFF \
+	-DSDL_X11_XCURSOR=OFF \
+	-DSDL_X11_XDBE=OFF \
+	-DSDL_X11_XFIXES=OFF \
+	-DSDL_X11_XINPUT=OFF \
+	-DSDL_X11_XRANDR=OFF \
+	-DSDL_X11_XSCRNSAVER=OFF \
+	-DSDL_X11_XSHAPE=OFF \
+"
+
+# opengl packageconfig factored out to make it easy for distros
+# and BSP layers to pick either (desktop) opengl, gles2, or no GL
+PACKAGECONFIG_GL ?= "${@bb.utils.filter('DISTRO_FEATURES', 'opengl', d)}"
+
+PACKAGECONFIG:class-native = "x11 ${PACKAGECONFIG_GL}"
+PACKAGECONFIG:class-nativesdk = "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)} ${PACKAGECONFIG_GL}"
+PACKAGECONFIG ??= " \
+	${PACKAGECONFIG_GL} \
+	${@bb.utils.filter('DISTRO_FEATURES', 'alsa pulseaudio pipewire x11 vulkan', d)} \
+	${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'wayland gles2', '', d)} \
+	${@bb.utils.contains("TUNE_FEATURES", "neon","arm-neon","",d)} \
+"
+PACKAGECONFIG[alsa]       = "-DSDL_ALSA=ON,-DSDL_ALSA=OFF,alsa-lib,"
+PACKAGECONFIG[arm-neon]   = "-DSDL_ARMNEON=ON,-DSDL_ARMNEON=OFF"
+PACKAGECONFIG[gles2]      = "-DSDL_OPENGLES=ON,-DSDL_OPENGLES=OFF,virtual/libgles2"
+PACKAGECONFIG[jack]       = "-DSDL_JACK=ON,-DSDL_JACK=OFF,jack"
+PACKAGECONFIG[kmsdrm]     = "-DSDL_KMSDRM=ON,-DSDL_KMSDRM=OFF,libdrm virtual/libgbm"
+# The hidraw support doesn't catch Xbox, PS4 and Nintendo controllers,
+#  so we'll just use libusb when it's available.
+PACKAGECONFIG[libusb] = "-DSDL_HIDAPI_LIBUSB=ON,-DSDL_HIDAPI_LIBUSB=OFF,libusb1"
+PACKAGECONFIG[libdecor] = "-DSDL_WAYLAND_LIBDECOR=ON,-DSDL_WAYLAND_LIBDECOR=OFF,libdecor,libdecor"
+PACKAGECONFIG[opengl]     = "-DSDL_OPENGL=ON,-DSDL_OPENGL=OFF,virtual/egl"
+PACKAGECONFIG[pipewire] = "-DSDL_PIPEWIRE_SHARED=ON,-DSDL_PIPEWIRE_SHARED=OFF,pipewire"
+PACKAGECONFIG[pulseaudio] = "-DSDL_PULSEAUDIO=ON,-DSDL_PULSEAUDIO=OFF,pulseaudio"
+PACKAGECONFIG[vulkan]    = "-DSDL_VULKAN=ON -DSDL_RENDER_VULKAN=ON,-DSDL_VULKAN=OFF -DSDL_RENDER_VULKAN=OFF"
+PACKAGECONFIG[wayland]    = "-DSDL_WAYLAND=ON,-DSDL_WAYLAND=OFF,wayland-native wayland wayland-protocols libxkbcommon"
+PACKAGECONFIG[x11]        = "-DSDL_X11=ON,-DSDL_X11=OFF,virtual/libx11 libxext libxrandr libxrender"
+
+CFLAGS:append:class-native = " -DNO_SHARED_MEMORY"
+
+FILES:${PN} += "${datadir}/licenses/SDL3/LICENSE.txt"
+
+BBCLASSEXTEND = "native nativesdk"
-- 
2.48.1



^ permalink raw reply related	[flat|nested] 8+ messages in thread
[parent not found: <182C5B28D7D9F838.16826@lists.openembedded.org>]
end of thread, other threads:[~2025-03-17 14:15 UTC | newest]

Thread overview: 8+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2025-03-13 12:03 [meta-oe][PATCHv2] libsdl3: add recipe Markus Volk
2025-03-13 12:44 ` [oe] " Gyorgy Sarvari
2025-03-13 14:10   ` Markus Volk
     [not found] <182C5B28D7D9F838.16826@lists.openembedded.org>
2025-03-13 12:04 ` Markus Volk
2025-03-17 11:18   ` Martin Jansa
2025-03-17 12:58     ` Markus Volk
     [not found]     ` <182D9870774557FF.29351@lists.openembedded.org>
2025-03-17 14:08       ` Markus Volk
2025-03-17 14:14         ` Martin Jansa

This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.