Re: [PATCH v2] lksctp-tools: Add recipe for lksctp

[Denys Dmytriyenko <denys@ti.com>]

On Sat, Feb 22, 2014 at 09:46:39PM -0500, Sam Nelson wrote:
> - The linux kernel Stream control transmission protocol
> - Original recipe by Jingting Zhou
> 
> Signed-off-by: Sam Nelson <sam.nelson@ti.com>
> 
> ---
> Updated RREPLACES_${PN}
> Fix build issue with .so
> ---
> ---
>  .../recipes-bsp/lksctp-tools/lksctp-tools_1.0.7.bb |   51 ++++++++++++++++++++
>  1 file changed, 51 insertions(+)
>  create mode 100755 meta-arago-extras/recipes-bsp/lksctp-tools/lksctp-tools_1.0.7.bb
> 
> diff --git a/meta-arago-extras/recipes-bsp/lksctp-tools/lksctp-tools_1.0.7.bb b/meta-arago-extras/recipes-bsp/lksctp-tools/lksctp-tools_1.0.7.bb
> new file mode 100755
> index 0000000..5c75552
> --- /dev/null
> +++ b/meta-arago-extras/recipes-bsp/lksctp-tools/lksctp-tools_1.0.7.bb
> @@ -0,0 +1,51 @@
> +DESCRIPTION = "The Linux Kernel Stream Control Transmission Protocol (lksctp) project"
> +SECTION = "libs"
> +PRIORITY = "optional"

PRIORITY no longer exists in Yocto, that was only applicable to OE-Classic


> +LICENSE = "LGPLv2"
> +LIC_FILES_CHKSUM = "file://src/include/netinet/sctp.h;md5=8089fbe48b63b73c8d091bee750b2ebc"

Entire file? Could be Ok, just checking if you rather want just the header 
instead.


> +
> +INC_PR = "r0"
> +PR = "${INC_PR}.0"

There's no .inc file, so no need to use INC_PR.


> +
> +SRC_URI = "${SOURCEFORGE_MIRROR}/lksctp/lksctp-tools-${PV}.tar.gz"
> +
> +SRC_URI[md5sum] = "047562b40537eb3be5d5ec3ae0a2198b"
> +SRC_URI[sha256sum] = "e920e89d110cff9847f1d86a1d7a23a156a8abcc9e65a35655d687fd08377595"
> +
> +S = "${WORKDIR}/${BPN}-${PV}"
> +
> +BBCLASSEXTEND = "native"
> +
> +inherit autotools pkgconfig binconfig
> +
> +do_install_append_virtclass-native() {
> +	:
> +}

I don't get it - you requested native build with BBCLASSEXTEND and then you 
disable do_install for it? Why? Actually, it's not even overwrite, it's append 
and it doesn't make any sense...


> +
> +RREPLACES_${PN} = "lksctp"

And by this point I decided to find where this recipe really comes from... :) 
Well, it appears it was available back in OE-Classic and had all those same 
strange things. But, some of those may be just cruft from previous revisions, 
so we should clean it up...

So, let's see:

1. Drop PRIORITY
2. May want to fix LIC_FILES_CHKSUM to not checksum the entire file
3. Drop INC_PR
4. Question - is this a native/host package, or just the target. If only 
target, drop BBLASSEXTEND
5. If 4 is true, also drop do_install_append_virtclass-native()
6. Drop RREPLACES
7. Try dropping LEAD_SONAME, but may still be required due to nonstandard lib
8. PACKAGES defines ${PN}-withsctp and ${PN}-utils, but FILES_* lists don't 
match
9. Probably want ${PN}-utils to be changed to just ${PN}, as PN=lksctp-tools

Let me know if you have any questions.

-- 
Denys


> +
> +LEAD_SONAME = "libsctp.so"
> +
> +PACKAGES =+ "${PN}-withsctp ${PN}-utils"
> +
> +FILES_${PN} = "${libexecdir}/* ${libdir}/lib*${SOLIBS} \
> +            ${sysconfdir} ${sharedstatedir} ${localstatedir} \
> +            ${base_libdir}/*${SOLIBS}"
> +
> +FILES_${PN}-dev += " \
> +  ${datadir}/lksctp-tools/checksctp.c \
> +  ${datadir}/lksctp-tools/sctp_socket.c \
> +  ${datadir}/lksctp-tools/sctp_bind.c \
> +  ${datadir}/lksctp-tools/sctp_darn.c \
> +  ${datadir}/lksctp-tools/sctp_load_libs.c \
> +  ${datadir}/lksctp-tools/sctp_sockopt.c \
> +  ${datadir}/lksctp-tools/sctp_socket.h \
> +  ${datadir}/lksctp-tools/sctp_test.c \
> +  ${datadir}/lksctp-tools/sctp_darn.h \
> +  ${libdir}/lksctp-tools/lib*.so"
> +
> +FILES_${PN}-utils = " \
> +  ${bindir}/sctp_test \
> +  ${bindir}/sctp_darn \
> +  ${bindir}/checksctp \
> +  ${bindir}/withsctp"
> -- 
> 1.7.9.5
> 
> _______________________________________________
> meta-arago mailing list
> meta-arago@arago-project.org
> http://arago-project.org/cgi-bin/mailman/listinfo/meta-arago