All of lore.kernel.org
 help / color / mirror / Atom feed
* [meta-multimedia][PATCH] updated mpd to current upstream stable
@ 2014-03-16 22:48 stephen.arnold42
  2014-03-16 22:48 ` [meta-xfce][PATCH] Fixed libxfce4ui recipe - updated depends, set SRCREV to 4.10.0 tag, added missing inherit and pre-config task stephen.arnold42
  2014-03-17  0:02 ` [meta-multimedia][PATCH] updated mpd to current upstream stable Martin Jansa
  0 siblings, 2 replies; 6+ messages in thread
From: stephen.arnold42 @ 2014-03-16 22:48 UTC (permalink / raw)
  To: openembedded-devel

---
 .../recipes-multimedia/musicpd/mpd_0.18.8.bb       | 59 ++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 meta-multimedia/recipes-multimedia/musicpd/mpd_0.18.8.bb

diff --git a/meta-multimedia/recipes-multimedia/musicpd/mpd_0.18.8.bb b/meta-multimedia/recipes-multimedia/musicpd/mpd_0.18.8.bb
new file mode 100644
index 0000000..b6882af
--- /dev/null
+++ b/meta-multimedia/recipes-multimedia/musicpd/mpd_0.18.8.bb
@@ -0,0 +1,59 @@
+SUMMARY = "Music Player Daemon"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
+HOMEPAGE ="http://www.musicpd.org"
+
+DEPENDS = "alsa-lib libsamplerate0 libsndfile1 libvorbis libogg faad2 ffmpeg curl sqlite bzip2 pulseaudio"
+
+SRC_URI = " \
+    http://www.musicpd.org/download/${PN}/stable/${P}.tar.xz \
+    file://mpd.conf.in \
+"
+
+SRC_URI[md5sum] = "7bbe1caf5abe404dc985ca4f44984b1f"
+SRC_URI[sha256sum] = "5366378e548fb77996cc33b0e15165ddd84f1e496bdd04616bd593aecdc26450"
+
+inherit autotools useradd systemd
+
+EXTRA_OECONF = "enable_bzip2=yes"
+EXTRA_OECONF += "${@base_contains('DISTRO_FEATURES', 'systemd', '--with-systemdsystemunitdir=${systemd_unitdir}/system/', '--without-systemdsystemunitdir', d)}"
+
+PACKAGECONFIG[mad] = "--enable-mad,--disable-mad,libmad"
+PACKAGECONFIG[id3tag] = "--enable-id3,--disable-id3,libid3tag"
+PACKAGECONFIG[lame] = "--enable-lame-encoder,--disable-lame-encoder,lame"
+
+do_install_append() {
+    install -d ${D}/${localstatedir}/lib/mpd/music
+    chmod 775 ${D}/${localstatedir}/lib/mpd/music
+    install -d ${D}/${localstatedir}/lib/mpd/playlists
+    chown -R mpd ${D}/${localstatedir}/lib/mpd
+    chown mpd:mpd ${D}/${localstatedir}/lib/mpd/music
+
+    install -d ${D}/${sysconfdir}
+    install -m 644 ${WORKDIR}/mpd.conf.in ${D}/${sysconfdir}/mpd.conf
+    sed -i \
+        -e 's|%music_directory%|${localstatedir}/lib/mpd/music|' \
+        -e 's|%playlist_directory%|${localstatedir}/lib/mpd/playlists|' \
+        -e 's|%db_file%|${localstatedir}/lib/mpd/mpd.db|' \
+        -e 's|%log_file%|${localstatedir}/log/mpd.log|' \
+        -e 's|%state_file%|${localstatedir}/lib/mpd/state|' \
+        ${D}/${sysconfdir}/mpd.conf
+
+    if [ -e ${D}/${systemd_unitdir}/system/mpd.service ] ; then
+        sed -i \
+            's|^ExecStart=.*|ExecStart=${bindir}/mpd --no-daemon|' \
+            ${D}/${systemd_unitdir}/system/mpd.service
+    fi
+}
+
+RPROVIDES_${PN} += "${PN}-systemd"
+RREPLACES_${PN} += "${PN}-systemd"
+RCONFLICTS_${PN} += "${PN}-systemd"
+SYSTEMD_SERVICE_${PN} = "mpd.service"
+
+USERADD_PACKAGES = "${PN}"
+USERADD_PARAM_${PN} = " \
+    --system --no-create-home \
+    --home ${localstatedir}/lib/mpd \
+    --groups audio \
+    --user-group mpd"
-- 
1.8.5.3



^ permalink raw reply related	[flat|nested] 6+ messages in thread
end of thread, other threads:[~2014-03-17  6:41 UTC | newest]

Thread overview: 6+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-03-16 22:48 [meta-multimedia][PATCH] updated mpd to current upstream stable stephen.arnold42
2014-03-16 22:48 ` [meta-xfce][PATCH] Fixed libxfce4ui recipe - updated depends, set SRCREV to 4.10.0 tag, added missing inherit and pre-config task stephen.arnold42
2014-03-17  6:40   ` Khem Raj
2014-03-17  0:02 ` [meta-multimedia][PATCH] updated mpd to current upstream stable Martin Jansa
2014-03-17  0:24   ` Stephen Arnold
2014-03-17  0:40     ` Martin Jansa

This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.