* [PATCH v2] ipsecmgr: Add recipes for ipsec manager module and libraries
@ 2015-02-04 3:13 Sam Nelson
2015-02-10 20:33 ` Denys Dmytriyenko
0 siblings, 1 reply; 2+ messages in thread
From: Sam Nelson @ 2015-02-04 3:13 UTC (permalink / raw)
To: meta-ti
- Provides module and libraries to offload IPSec security
policy & associated security association to NETCP for
crypto operations
Signed-off-by: Sam Nelson <sam.nelson@ti.com>
---
recipes-bsp/ipsecmgr/ipsecmgr-mod_git.bb | 26 ++++++++++++++++++++++++++
recipes-bsp/ipsecmgr/ipsecmgr.inc | 10 ++++++++++
recipes-bsp/ipsecmgr/ipsecmgr_git.bb | 30 ++++++++++++++++++++++++++++++
3 files changed, 66 insertions(+)
create mode 100644 recipes-bsp/ipsecmgr/ipsecmgr-mod_git.bb
create mode 100644 recipes-bsp/ipsecmgr/ipsecmgr.inc
create mode 100644 recipes-bsp/ipsecmgr/ipsecmgr_git.bb
diff --git a/recipes-bsp/ipsecmgr/ipsecmgr-mod_git.bb b/recipes-bsp/ipsecmgr/ipsecmgr-mod_git.bb
new file mode 100644
index 0000000..bbaa271
--- /dev/null
+++ b/recipes-bsp/ipsecmgr/ipsecmgr-mod_git.bb
@@ -0,0 +1,26 @@
+SUMMARY = "IPSec Manager kernel module"
+DESCRIPTION = "Provides Module to offload IPSec security policy & associated security association to NETCP for crypto operations"
+
+include ipsecmgr.inc
+
+MACHINE_KERNEL_PR_append = "a+gitr${SRCPV}"
+PR = "${MACHINE_KERNEL_PR}"
+
+MODULE_BUILD_DIR = "${S}/src/module"
+
+EXTRA_OEMAKE += "KDIR="${STAGING_KERNEL_DIR}""
+
+inherit module
+
+do_compile() {
+# Compile kernel module
+ cd ${MODULE_BUILD_DIR}
+ oe_runmake clean
+ oe_runmake
+}
+
+do_install() {
+# Install kernel module
+ cd ${MODULE_BUILD_DIR}
+ oe_runmake INSTALL_MOD_PATH="${D}" install
+}
diff --git a/recipes-bsp/ipsecmgr/ipsecmgr.inc b/recipes-bsp/ipsecmgr/ipsecmgr.inc
new file mode 100644
index 0000000..cbc63c0
--- /dev/null
+++ b/recipes-bsp/ipsecmgr/ipsecmgr.inc
@@ -0,0 +1,10 @@
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://ipsecmgr_snoop.h;beginline=1;endline=33;md5=f7eadca4fb5599f508dc11fa1e752919"
+
+BRANCH="master"
+SRC_URI = "git://arago-project.org/git/projects/ipsecmgr.git;protocol=git;branch=${BRANCH}"
+#Commit ID corresponding to DEV.IPSECMGR.01.01.00.03
+SRCREV = "1ea8355ae9142311901c842c97a58d2846b308e6"
+PV = "01.01.00.03"
+
+S = "${WORKDIR}/git"
diff --git a/recipes-bsp/ipsecmgr/ipsecmgr_git.bb b/recipes-bsp/ipsecmgr/ipsecmgr_git.bb
new file mode 100644
index 0000000..a4739ce
--- /dev/null
+++ b/recipes-bsp/ipsecmgr/ipsecmgr_git.bb
@@ -0,0 +1,30 @@
+SUMMARY = "IPSec Manager libraries"
+DESCRIPTION = "Provides library to offload IPSec security policy & associated security association to NETCP for crypto operations"
+
+include ipsecmgr.inc
+
+DEPENDS = "libnl-xfrm"
+
+LIB_BUILD_DIR = "${S}/build"
+LIB_INC_DIR = "${S}/"
+UTILS_LIB_INC_DIR = "${S}/utils/iface/"
+
+CFLAGS += "-I${STAGING_INCDIR}/libnl3"
+
+do_compile() {
+# Compile the library
+ cd ${LIB_BUILD_DIR}
+ make clean
+ make all
+}
+
+do_install() {
+# Install libraries
+ install -d ${D}${libdir}/
+ install -c -m 666 ${LIB_BUILD_DIR}/libipsecmgr_snoop.a ${D}${libdir}/
+ install -c -m 666 ${LIB_BUILD_DIR}/libipsecmgr_ipc.a ${D}${libdir}/
+ install -c -m 666 ${LIB_BUILD_DIR}/libipsecmgr_syslog.a ${D}${libdir}/
+ install -d ${D}${includedir}/
+ install -c -m 666 ${LIB_INC_DIR}/*.h ${D}${includedir}/
+ install -c -m 666 ${UTILS_LIB_INC_DIR}/*.h ${D}${includedir}/
+}
--
1.7.9.5
^ permalink raw reply related [flat|nested] 2+ messages in thread
* Re: [PATCH v2] ipsecmgr: Add recipes for ipsec manager module and libraries
2015-02-04 3:13 [PATCH v2] ipsecmgr: Add recipes for ipsec manager module and libraries Sam Nelson
@ 2015-02-10 20:33 ` Denys Dmytriyenko
0 siblings, 0 replies; 2+ messages in thread
From: Denys Dmytriyenko @ 2015-02-10 20:33 UTC (permalink / raw)
To: Sam Nelson; +Cc: meta-ti
On Tue, Feb 03, 2015 at 10:13:54PM -0500, Sam Nelson wrote:
> - Provides module and libraries to offload IPSec security
> policy & associated security association to NETCP for
> crypto operations
>
> Signed-off-by: Sam Nelson <sam.nelson@ti.com>
> ---
> recipes-bsp/ipsecmgr/ipsecmgr-mod_git.bb | 26 ++++++++++++++++++++++++++
> recipes-bsp/ipsecmgr/ipsecmgr.inc | 10 ++++++++++
> recipes-bsp/ipsecmgr/ipsecmgr_git.bb | 30 ++++++++++++++++++++++++++++++
> 3 files changed, 66 insertions(+)
> create mode 100644 recipes-bsp/ipsecmgr/ipsecmgr-mod_git.bb
> create mode 100644 recipes-bsp/ipsecmgr/ipsecmgr.inc
> create mode 100644 recipes-bsp/ipsecmgr/ipsecmgr_git.bb
>
> diff --git a/recipes-bsp/ipsecmgr/ipsecmgr-mod_git.bb b/recipes-bsp/ipsecmgr/ipsecmgr-mod_git.bb
> new file mode 100644
> index 0000000..bbaa271
> --- /dev/null
> +++ b/recipes-bsp/ipsecmgr/ipsecmgr-mod_git.bb
> @@ -0,0 +1,26 @@
> +SUMMARY = "IPSec Manager kernel module"
> +DESCRIPTION = "Provides Module to offload IPSec security policy & associated security association to NETCP for crypto operations"
> +
> +include ipsecmgr.inc
> +
> +MACHINE_KERNEL_PR_append = "a+gitr${SRCPV}"
> +PR = "${MACHINE_KERNEL_PR}"
> +
> +MODULE_BUILD_DIR = "${S}/src/module"
Set S to point there to avoid cd-ing to that directory in do_compile and
do_install steps.
> +EXTRA_OEMAKE += "KDIR="${STAGING_KERNEL_DIR}""
> +
> +inherit module
> +
> +do_compile() {
> +# Compile kernel module
> + cd ${MODULE_BUILD_DIR}
> + oe_runmake clean
> + oe_runmake
Set MAKE_TARGETS to "all" or empty (depending on your Makefile) and drop
do_compile completely.
> +}
> +
> +do_install() {
> +# Install kernel module
> + cd ${MODULE_BUILD_DIR}
> + oe_runmake INSTALL_MOD_PATH="${D}" install
> +}
This one expects modules_install target, so you'd need just last line, but
drop "cd"...
> diff --git a/recipes-bsp/ipsecmgr/ipsecmgr.inc b/recipes-bsp/ipsecmgr/ipsecmgr.inc
> new file mode 100644
> index 0000000..cbc63c0
> --- /dev/null
> +++ b/recipes-bsp/ipsecmgr/ipsecmgr.inc
> @@ -0,0 +1,10 @@
> +LICENSE = "BSD-3-Clause"
> +LIC_FILES_CHKSUM = "file://ipsecmgr_snoop.h;beginline=1;endline=33;md5=f7eadca4fb5599f508dc11fa1e752919"
> +
> +BRANCH="master"
> +SRC_URI = "git://arago-project.org/git/projects/ipsecmgr.git;protocol=git;branch=${BRANCH}"
> +#Commit ID corresponding to DEV.IPSECMGR.01.01.00.03
> +SRCREV = "1ea8355ae9142311901c842c97a58d2846b308e6"
> +PV = "01.01.00.03"
> +
> +S = "${WORKDIR}/git"
> diff --git a/recipes-bsp/ipsecmgr/ipsecmgr_git.bb b/recipes-bsp/ipsecmgr/ipsecmgr_git.bb
> new file mode 100644
> index 0000000..a4739ce
> --- /dev/null
> +++ b/recipes-bsp/ipsecmgr/ipsecmgr_git.bb
> @@ -0,0 +1,30 @@
> +SUMMARY = "IPSec Manager libraries"
> +DESCRIPTION = "Provides library to offload IPSec security policy & associated security association to NETCP for crypto operations"
> +
> +include ipsecmgr.inc
> +
> +DEPENDS = "libnl-xfrm"
Since you submitted this libnl-xfrm dependency to meta-arago, you have to
either move ipsecmgr to meta-arago as well, or move libnl-xfrm to meta-ti...
In other words, meta-ti layer doesn't have dependency on meta-arago, so you
can't depend on anything in meta-arago from meta-ti. The other way around is
allowed.
> +
> +LIB_BUILD_DIR = "${S}/build"
> +LIB_INC_DIR = "${S}/"
> +UTILS_LIB_INC_DIR = "${S}/utils/iface/"
> +
> +CFLAGS += "-I${STAGING_INCDIR}/libnl3"
> +
> +do_compile() {
> +# Compile the library
> + cd ${LIB_BUILD_DIR}
> + make clean
> + make all
> +}
> +
> +do_install() {
> +# Install libraries
> + install -d ${D}${libdir}/
> + install -c -m 666 ${LIB_BUILD_DIR}/libipsecmgr_snoop.a ${D}${libdir}/
> + install -c -m 666 ${LIB_BUILD_DIR}/libipsecmgr_ipc.a ${D}${libdir}/
> + install -c -m 666 ${LIB_BUILD_DIR}/libipsecmgr_syslog.a ${D}${libdir}/
> + install -d ${D}${includedir}/
> + install -c -m 666 ${LIB_INC_DIR}/*.h ${D}${includedir}/
> + install -c -m 666 ${UTILS_LIB_INC_DIR}/*.h ${D}${includedir}/
> +}
> --
> 1.7.9.5
>
> --
> _______________________________________________
> meta-ti mailing list
> meta-ti@yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-ti
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2015-02-10 20:33 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2015-02-04 3:13 [PATCH v2] ipsecmgr: Add recipes for ipsec manager module and libraries Sam Nelson
2015-02-10 20:33 ` Denys Dmytriyenko
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.