[PATCH v2 1/2] ti-cgt-pru: Add version 2.1.1

[PATCH v2 1/2] ti-cgt-pru: Add version 2.1.1

[Jacob Stiffler]

* TI PRU Code Generation Tools

Signed-off-by: Jacob Stiffler <j-stiffler@ti.com>
---
v2 changes:
* Modify commit message

 recipes-ti/devtools/ti-cgt-pru_2.1.1.bb | 45 +++++++++++++++++++++++++++++++++
 recipes-ti/includes/ti-paths.inc        |  3 +++
 2 files changed, 48 insertions(+)
 create mode 100644 recipes-ti/devtools/ti-cgt-pru_2.1.1.bb

diff --git a/recipes-ti/devtools/ti-cgt-pru_2.1.1.bb b/recipes-ti/devtools/ti-cgt-pru_2.1.1.bb
new file mode 100644
index 0000000..3cffd24
--- /dev/null
+++ b/recipes-ti/devtools/ti-cgt-pru_2.1.1.bb
@@ -0,0 +1,45 @@
+DESCRIPTION = "TI PRU Code Generation Tools"
+HOMEPAGE = "https://www-a.ti.com/downloads/sds_support/TICodegenerationTools/download.htm"
+LICENSE = "(TI-TSPA & Thai-Open-Source-Software-Center) & BSD-3-Clause & BSL-1.0 & Hewlett-Packard & AFL-3.0 & MIT & BSD-2-Clause & PD"
+
+LIC_FILES_CHKSUM = "file://ti-cgt-pru_${PV}/LICENSE.txt;md5=b6311962635a4f15630e36ec2d875eca"
+LIC_FILES_CHKSUM_class-target = "file://usr/share/doc/ti/cgt-pru/LICENSE.txt;md5=b6311962635a4f15630e36ec2d875eca"
+
+require recipes-ti/includes/ti-paths.inc
+require recipes-ti/includes/ti-unpack.inc
+
+BINFILE = "ti_cgt_pru_${PV}_linux_installer_x86.bin"
+BINFILE_NAME = "cgt-pru-x86"
+TI_BIN_UNPK_ARGS = "--prefix ${S}"
+TI_BIN_UNPK_CMDS = ""
+
+BINFILE_class-target = "ti_cgt_pru_${PV}_armlinuxa8hf_busybox_installer.sh"
+BINFILE_NAME_class-target = "cgt-pru-arm"
+
+SRC_URI = "http://software-dl.ti.com/codegen/esd/cgt_public_sw/PRU/${PV}/${BINFILE};name=${BINFILE_NAME}"
+
+SRC_URI[cgt-pru-x86.md5sum] = "d9923acea12dc41fc975c381804bd5ed"
+SRC_URI[cgt-pru-x86.sha256sum] = "bbea68a6e793156cfb4874777bfd41a32b20172d3a8f61db6aed33a697a58e30"
+
+SRC_URI[cgt-pru-arm.md5sum] = "3b97df4966715bdb50f9a9fc58fe6b24"
+SRC_URI[cgt-pru-arm.sha256sum] = "819a4680296fabf1ae0d4e0184276f8ab5324621d35388026d1b678ea71040c9"
+
+do_install() {
+    install -d ${D}${TI_CGT_PRU_INSTALL_DIR_RECIPE}
+    cp -r ${S}/ti-cgt-pru_${PV}/. \
+          ${D}${TI_CGT_PRU_INSTALL_DIR_RECIPE}/
+}
+
+do_install_class-target() {
+    ${WORKDIR}/${BINFILE} --prefix ${D}
+}
+
+FILES_${PN} += "${datadir}/ti/*"
+
+FILES_${PN}-dbg = "${TI_CGT_PRU_INSTALL_DIR_RECIPE}/bin/.debug \
+                   ${TI_CGT_PRU_INSTALL_DIR_RECIPE}/lib/.debug \
+"
+
+INSANE_SKIP_${PN} += "arch staticdev"
+
+BBCLASSEXTEND = "native nativesdk"
diff --git a/recipes-ti/includes/ti-paths.inc b/recipes-ti/includes/ti-paths.inc
index 8880591..ad4ff78 100644
--- a/recipes-ti/includes/ti-paths.inc
+++ b/recipes-ti/includes/ti-paths.inc
@@ -48,6 +48,8 @@ export OSAL_INSTALL_DIR_RECIPE       = "${installdir}/ti-osal-tree"
 export M4_TOOLCHAIN_INSTALL_DIR_RECIPE    = "${installdir}/ti-cgt-arm"
 export CCSV6_INSTALL_DIR_RECIPE           = "${installdir}/ccsv6"
 export GCC_ARM_NONE_TOOLCHAIN_RECIPE      = "${installdir}/gcc-arm-none-eabi"
+export TI_CGT_PRU_INSTALL_DIR_RECIPE      = "${installdir}/cgt-pru"
+
 
 # This is where the tools will end up in sysroot
 export BIOS_INSTALL_DIR       = "${STAGING_DIR_TARGET}${BIOS_INSTALL_DIR_RECIPE}"
@@ -86,6 +88,7 @@ export OSAL_INSTALL_DIR       = "${STAGING_DIR_TARGET}${OSAL_INSTALL_DIR_RECIPE}
 export M4_TOOLCHAIN_INSTALL_DIR    = "${STAGING_DIR_NATIVE}${M4_TOOLCHAIN_INSTALL_DIR_RECIPE}"
 export CCSV6_INSTALL_DIR           = "${STAGING_DIR_NATIVE}${CCSV6_INSTALL_DIR_RECIPE}"
 export GCC_ARM_NONE_TOOLCHAIN      = "${STAGING_DIR_NATIVE}${GCC_ARM_NONE_TOOLCHAIN_RECIPE}"
+export TI_CGT_PRU_INSTALL_DIR      = "${STAGING_DIR_NATIVE}${TI_CGT_PRU_INSTALL_DIR_RECIPE}"
 
 DSPSUFFIX_omapl137 = "x674"
 DSPSUFFIX_omapl138 = "x674"
-- 
1.9.1

[PATCH v2 2/2] pru-icss: Add PRU software package version 4.0.0.0

[Jacob Stiffler]

Signed-off-by: Jacob Stiffler <j-stiffler@ti.com>
---
v2 changes:
* Remove SRCPV from PV, drop BASE_PV
* Add COMPATIBLE_MACHINES, remove dummy do_install()
* Use ti-paths.inc's "TI_CGT_PRU_INSTALL_DIR" to get toolchain path

 recipes-bsp/pru/pru-icss_git.bb | 66 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 recipes-bsp/pru/pru-icss_git.bb

diff --git a/recipes-bsp/pru/pru-icss_git.bb b/recipes-bsp/pru/pru-icss_git.bb
new file mode 100644
index 0000000..75179a5
--- /dev/null
+++ b/recipes-bsp/pru/pru-icss_git.bb
@@ -0,0 +1,66 @@
+DESCRIPTION = "Programmable Real-time Unit Software Package"
+HOMEPAGE = "http://processors.wiki.ti.com/index.php/PRU-ICSS"
+LICENSE = "BSD-3-Clause & GPL-2.0 & PD"
+
+LIC_FILES_CHKSUM = "file://PRU-Package-v4.0-Manifest.html;md5=5ea937e4ff2c924a735d42e61ad8cbe3"
+
+BRANCH = "master"
+SRC_URI = "git://git.ti.com/pru-software-support-package/pru-software-support-package.git;protocol=git;branch=${BRANCH}"
+SRCREV = "476289eb7c3a91977bae84aea55c56f3120b48ea"
+
+PV = "4.0.0.0"
+PR = "r0"
+
+require recipes-ti/includes/ti-paths.inc
+
+COMPATIBLE_MACHINE = "am335x-evm|am437x-evm|am57xx-evm"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+DEPENDS = "ti-cgt-pru-native"
+
+S = "${WORKDIR}/git"
+
+export PRU_CGT = "${TI_CGT_PRU_INSTALL_DIR}"
+
+SUBDIRS = "examples pru_cape/pru_fw lib/src labs"
+
+do_compile() {
+    for dir in ${SUBDIRS}
+    do
+        make -C ${S}/$dir
+    done
+}
+
+do_install_am335x-evm() {
+    install -d ${D}/lib/firmware
+    for i in 0 1
+    do
+        install -m 0644 ${S}/examples/am335x/PRU_RPMsg_Echo_Interrupt${i}/gen/PRU_RPMsg_Echo_Interrupt${i}.out \
+                        ${D}/lib/firmware/am335x-pru${i}-fw
+    done
+}
+
+do_install_am437x-evm() {
+    install -d ${D}/lib/firmware
+    for i in 0 1
+    do
+        install -m 0644 ${S}/examples/am437x/PRU_RPMsg_Echo_Interrupt${i}/gen/PRU_RPMsg_Echo_Interrupt${i}.out \
+                        ${D}/lib/firmware/am437x-pru1_${i}-fw
+    done
+}
+
+do_install_am57xx-evm() {
+    install -d ${D}/lib/firmware
+    for i in 1 2
+    do
+        for j in 0 1
+        do
+            install -m 0644 ${S}/examples/am572x/PRU_RPMsg_Echo_Interrupt${i}_${j}/gen/PRU_RPMsg_Echo_Interrupt${i}_${j}.out \
+                            ${D}/lib/firmware/am57xx-pru${i}_${j}-fw
+        done
+    done
+}
+
+FILES_${PN} += "/lib/firmware"
+
+INSANE_SKIP_${PN} = "arch"
-- 
1.9.1

Re: [PATCH v2 2/2] pru-icss: Add PRU software package version 4.0.0.0

[Denys Dmytriyenko]

On Thu, Oct 29, 2015 at 12:09:49PM -0400, Jacob Stiffler wrote:
> Signed-off-by: Jacob Stiffler <j-stiffler@ti.com>
> ---
> v2 changes:
> * Remove SRCPV from PV, drop BASE_PV
> * Add COMPATIBLE_MACHINES, remove dummy do_install()
> * Use ti-paths.inc's "TI_CGT_PRU_INSTALL_DIR" to get toolchain path
> 
>  recipes-bsp/pru/pru-icss_git.bb | 66 +++++++++++++++++++++++++++++++++++++++++
>  1 file changed, 66 insertions(+)
>  create mode 100644 recipes-bsp/pru/pru-icss_git.bb
> 
> diff --git a/recipes-bsp/pru/pru-icss_git.bb b/recipes-bsp/pru/pru-icss_git.bb
> new file mode 100644
> index 0000000..75179a5
> --- /dev/null
> +++ b/recipes-bsp/pru/pru-icss_git.bb
> @@ -0,0 +1,66 @@
> +DESCRIPTION = "Programmable Real-time Unit Software Package"
> +HOMEPAGE = "http://processors.wiki.ti.com/index.php/PRU-ICSS"
> +LICENSE = "BSD-3-Clause & GPL-2.0 & PD"
> +
> +LIC_FILES_CHKSUM = "file://PRU-Package-v4.0-Manifest.html;md5=5ea937e4ff2c924a735d42e61ad8cbe3"
> +
> +BRANCH = "master"
> +SRC_URI = "git://git.ti.com/pru-software-support-package/pru-software-support-package.git;protocol=git;branch=${BRANCH}"
> +SRCREV = "476289eb7c3a91977bae84aea55c56f3120b48ea"
> +
> +PV = "4.0.0.0"
> +PR = "r0"
> +
> +require recipes-ti/includes/ti-paths.inc
> +
> +COMPATIBLE_MACHINE = "am335x-evm|am437x-evm|am57xx-evm"

Well, the problem with this is exclusion of compatible non-EVM targets. Why 
not use SOC family instead here in COMPATIBLE_MACHINE as well as below 
do_install overrides?


> +PACKAGE_ARCH = "${MACHINE_ARCH}"
> +
> +DEPENDS = "ti-cgt-pru-native"
> +
> +S = "${WORKDIR}/git"
> +
> +export PRU_CGT = "${TI_CGT_PRU_INSTALL_DIR}"
> +
> +SUBDIRS = "examples pru_cape/pru_fw lib/src labs"
> +
> +do_compile() {
> +    for dir in ${SUBDIRS}
> +    do
> +        make -C ${S}/$dir
> +    done
> +}
> +
> +do_install_am335x-evm() {
> +    install -d ${D}/lib/firmware
> +    for i in 0 1
> +    do
> +        install -m 0644 ${S}/examples/am335x/PRU_RPMsg_Echo_Interrupt${i}/gen/PRU_RPMsg_Echo_Interrupt${i}.out \
> +                        ${D}/lib/firmware/am335x-pru${i}-fw
> +    done
> +}
> +
> +do_install_am437x-evm() {
> +    install -d ${D}/lib/firmware
> +    for i in 0 1
> +    do
> +        install -m 0644 ${S}/examples/am437x/PRU_RPMsg_Echo_Interrupt${i}/gen/PRU_RPMsg_Echo_Interrupt${i}.out \
> +                        ${D}/lib/firmware/am437x-pru1_${i}-fw
> +    done
> +}
> +
> +do_install_am57xx-evm() {
> +    install -d ${D}/lib/firmware
> +    for i in 1 2
> +    do
> +        for j in 0 1
> +        do
> +            install -m 0644 ${S}/examples/am572x/PRU_RPMsg_Echo_Interrupt${i}_${j}/gen/PRU_RPMsg_Echo_Interrupt${i}_${j}.out \
> +                            ${D}/lib/firmware/am57xx-pru${i}_${j}-fw
> +        done
> +    done
> +}
> +
> +FILES_${PN} += "/lib/firmware"
> +
> +INSANE_SKIP_${PN} = "arch"
> -- 
> 1.9.1
> 
> -- 
> _______________________________________________
> meta-ti mailing list
> meta-ti@yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-ti