[PATCH 0/8] Add LibArch and LinAlg

[PATCH 0/8] Add LibArch and LinAlg

[Jacob Stiffler]

Integrate Library Architecture and Framework (LibArch)
and TI Linear Algebra Library (LinAlg)

Jacob Stiffler (8):
  libarch: Add version 1.0.0.0
  libarch-examples: Add examples for libarch version 1.0.0.0
  arago-source-ipk: Enable libarch-examples-src
  linalg: Add Linear Algebra Library version 1.2.0.0
  linalg-examples: And Linear Algebra Library examples
  arago-source-ipk: Enable linalg-examples-src
  packagegroup-arago-tisdk-addons: k2hk-evm: Integrate linalg
  ti-tisdk-makefile: Add linalg-examples target

 .../conf/distro/arago-source-ipk.conf              |  7 ++
 .../packagegroup-arago-tisdk-addons-sdk-host.bb    |  3 +-
 .../packagegroup-arago-tisdk-addons-sdk-target.bb  |  3 +-
 .../packagegroup-arago-tisdk-addons.bb             |  3 +-
 .../ti-tisdk-makefile/Makefile_linalg-examples     | 39 ++++++++++++
 .../ti-tisdk-makefile/ti-tisdk-makefile_1.0.bb     |  4 +-
 .../recipes-ti/includes/arago-paths.inc            |  7 ++
 .../recipes-ti/libarch/libarch-examples_git.bb     | 36 +++++++++++
 meta-arago-extras/recipes-ti/libarch/libarch.inc   | 32 ++++++++++
 .../recipes-ti/libarch/libarch_git.bb              | 25 ++++++++
 .../recipes-ti/linalg/linalg-examples_git.bb       | 74 ++++++++++++++++++++++
 meta-arago-extras/recipes-ti/linalg/linalg.inc     | 43 +++++++++++++
 meta-arago-extras/recipes-ti/linalg/linalg_git.bb  | 23 +++++++
 13 files changed, 295 insertions(+), 4 deletions(-)
 create mode 100644 meta-arago-distro/recipes-tisdk/ti-tisdk-makefile/ti-tisdk-makefile/Makefile_linalg-examples
 create mode 100644 meta-arago-extras/recipes-ti/includes/arago-paths.inc
 create mode 100644 meta-arago-extras/recipes-ti/libarch/libarch-examples_git.bb
 create mode 100644 meta-arago-extras/recipes-ti/libarch/libarch.inc
 create mode 100644 meta-arago-extras/recipes-ti/libarch/libarch_git.bb
 create mode 100644 meta-arago-extras/recipes-ti/linalg/linalg-examples_git.bb
 create mode 100644 meta-arago-extras/recipes-ti/linalg/linalg.inc
 create mode 100644 meta-arago-extras/recipes-ti/linalg/linalg_git.bb

-- 
1.9.1

[PATCH 1/8] libarch: Add version 1.0.0.0

[Jacob Stiffler]

Signed-off-by: Jacob Stiffler <j-stiffler@ti.com>
---
 .../recipes-ti/includes/arago-paths.inc            |  5 ++++
 meta-arago-extras/recipes-ti/libarch/libarch.inc   | 32 ++++++++++++++++++++++
 .../recipes-ti/libarch/libarch_git.bb              | 25 +++++++++++++++++
 3 files changed, 62 insertions(+)
 create mode 100644 meta-arago-extras/recipes-ti/includes/arago-paths.inc
 create mode 100644 meta-arago-extras/recipes-ti/libarch/libarch.inc
 create mode 100644 meta-arago-extras/recipes-ti/libarch/libarch_git.bb

diff --git a/meta-arago-extras/recipes-ti/includes/arago-paths.inc b/meta-arago-extras/recipes-ti/includes/arago-paths.inc
new file mode 100644
index 0000000..ae3f304
--- /dev/null
+++ b/meta-arago-extras/recipes-ti/includes/arago-paths.inc
@@ -0,0 +1,5 @@
+require recipes-ti/includes/ti-paths.inc
+
+export LIBARCH_INSTALL_DIR_RECIPE    = "${installdir}/ti-libarch-tree"
+
+export LIBARCH_INSTALL_DIR    = "${STAGING_DIR_TARGET}${LIBARCH_INSTALL_DIR_RECIPE}"
diff --git a/meta-arago-extras/recipes-ti/libarch/libarch.inc b/meta-arago-extras/recipes-ti/libarch/libarch.inc
new file mode 100644
index 0000000..83e147c
--- /dev/null
+++ b/meta-arago-extras/recipes-ti/libarch/libarch.inc
@@ -0,0 +1,32 @@
+HOMEPAGE = "https://git.ti.com/library-architecture/libarch"
+LICENSE = "BSD-3-Clause"
+
+PV = "1_0_0_0"
+INC_PR = "r0"
+
+require recipes-ti/includes/arago-paths.inc
+require recipes-ti/includes/ti-staging.inc
+
+BRANCH = "master"
+LIC_FILES_CHKSUM = "file://docs/LibArch_1.0.0_manifest.html;md5=bb48cacb8827ec8d8e5a94c4f2425ee3"
+SRC_URI = "git://git.ti.com/library-architecture/libarch.git;protocol=git;branch=${BRANCH}"
+SRCREV = "c4bc65775bdb6bd8574e43d3cb7148c6bbdc8de6"
+
+COMPATIBLE_MACHINE = "k2hk-evm|am57xx"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+S = "${WORKDIR}/git"
+
+DEPENDS = "common-csl-ip-rtos ti-xdctools ti-sysbios ti-cgt6x-native ti-xdais ti-framework-components opencl opencl-monitor"
+
+export CGTROOT = "${STAGING_DIR_NATIVE}/usr/share/ti/cgt-c6x"
+export TI_OCL_CGT_INSTALL = "${STAGING_DIR_NATIVE}/usr/share/ti/cgt-c6x"
+export TI_OCL_INSTALL_DIR = "${STAGING_DIR_TARGET}/usr/share/ti/opencl"
+export XDC_DIR = "${XDC_INSTALL_DIR}"
+export BIOS_DIR= "${SYSBIOS_INSTALL_DIR}"
+export XDAIS_DIR = "${XDAIS_INSTALL_DIR}"
+export FC_DIR = "${FC_INSTALL_DIR}"
+export PDK_DIR = "${PDK_INSTALL_DIR}"
+
+TARGET_am57xx-evm = "SOC_AM572x"
+TARGET_k2hk-evm   = "SOC_K2H"
diff --git a/meta-arago-extras/recipes-ti/libarch/libarch_git.bb b/meta-arago-extras/recipes-ti/libarch/libarch_git.bb
new file mode 100644
index 0000000..18c998a
--- /dev/null
+++ b/meta-arago-extras/recipes-ti/libarch/libarch_git.bb
@@ -0,0 +1,25 @@
+DESCRIPTION = "TI Library Architecture"
+
+include libarch.inc
+
+PR = "${INC_PR}.0"
+
+do_compile() {
+    make lib TARGET=${TARGET} LIBOS=LIB_OPENCL
+    make docs
+
+    # Delete .obj files before installing
+    rm src/*.obj
+}
+
+do_install() {
+    install -d ${D}${LIBARCH_INSTALL_DIR_RECIPE}
+    cp -r docs lib include src ${D}${LIBARCH_INSTALL_DIR_RECIPE}
+    cp Makefile ${D}${LIBARCH_INSTALL_DIR_RECIPE}
+}
+
+FILES_${PN}-dev += "${LIBARCH_INSTALL_DIR_RECIPE}"
+
+# skip checking binary against ARM architecture
+INSANE_SKIP_${PN}-dev = "arch"
+ALLOW_EMPTY_${PN} = "1"
-- 
1.9.1

[PATCH 2/8] libarch-examples: Add examples for libarch version 1.0.0.0

[Jacob Stiffler]

Signed-off-by: Jacob Stiffler <j-stiffler@ti.com>
---
 .../recipes-ti/libarch/libarch-examples_git.bb     | 36 ++++++++++++++++++++++
 1 file changed, 36 insertions(+)
 create mode 100644 meta-arago-extras/recipes-ti/libarch/libarch-examples_git.bb

diff --git a/meta-arago-extras/recipes-ti/libarch/libarch-examples_git.bb b/meta-arago-extras/recipes-ti/libarch/libarch-examples_git.bb
new file mode 100644
index 0000000..62a09af
--- /dev/null
+++ b/meta-arago-extras/recipes-ti/libarch/libarch-examples_git.bb
@@ -0,0 +1,36 @@
+DESCRIPTION = "TI Library Architecture Examples"
+
+include libarch.inc
+
+PR = "${INC_PR}.0"
+
+DEPENDS += "libarch clocl-native"
+RDEPENDS_${PN} += "opencl-runtime"
+
+export LIBARCH_DIR    = "${LIBARCH_INSTALL_DIR}"
+export TARGET_ROOTDIR = "${STAGING_DIR_TARGET}"
+
+do_compile() {
+    make examples TARGET=${TARGET} LIBOS=LIB_OPENCL
+
+    # Remove object files before installing so that the binaries are not present
+    find . -name "*.obj" -type f -delete
+    find . -name "*.o" -type f -delete
+    find . -name "*.out" -type f -delete
+    find . -name "*.dsp_h" -type f -delete
+}
+
+do_install() {
+    install -d ${D}${datadir}/ti/examples/libarch
+    cp -r examples/arm+dsp ${D}${datadir}/ti/examples/libarch
+    cp -r examples/common ${D}${datadir}/ti/examples/libarch
+    cp examples/Makefile ${D}${datadir}/ti/examples/libarch
+}
+
+FILES_${PN} += "\
+    ${datadir}/ti/examples/libarch/* \ "
+
+FILES_${PN}-dbg += "\
+    ${datadir}/ti/examples/libarch/*/.debug \ "
+
+INSANE_SKIP_${PN} = "arch ldflags textrel"
-- 
1.9.1

[PATCH 3/8] arago-source-ipk: Enable libarch-examples-src

[Jacob Stiffler]

Signed-off-by: Jacob Stiffler <j-stiffler@ti.com>
---
 meta-arago-distro/conf/distro/arago-source-ipk.conf | 3 +++
 1 file changed, 3 insertions(+)

diff --git a/meta-arago-distro/conf/distro/arago-source-ipk.conf b/meta-arago-distro/conf/distro/arago-source-ipk.conf
index 95132c8..56a488f 100644
--- a/meta-arago-distro/conf/distro/arago-source-ipk.conf
+++ b/meta-arago-distro/conf/distro/arago-source-ipk.conf
@@ -347,6 +347,9 @@ SRCIPK_INSTALL_DIR_pn-openmpacc-examples = "example-applications/${PN}-${PV}"
 CREATE_SRCIPK_pn-qt-opencv-opencl-opengl-multithreaded = "1"
 SRCIPK_INSTALL_DIR_pn-qt-opencv-opencl-opengl-multithreaded = "example-applications/${PN}-${PV}"
 
+CREATE_SRCIPK_pn-libarch-examples = "1"
+SRCIPK_INSTALL_DIR_pn-libarch-examples = "example-applications/${PN}-${PV}"
+
 CREATE_SRCIPK_pn-boot-monitor = "1"
 SRCIPK_INSTALL_DIR_pn-boot-monitor = "board-support/${PN}-${PV}"
 
-- 
1.9.1

[PATCH 4/8] linalg: Add Linear Algebra Library version 1.2.0.0

[Jacob Stiffler]

Signed-off-by: Jacob Stiffler <j-stiffler@ti.com>
---
 .../recipes-ti/includes/arago-paths.inc            |  2 +
 meta-arago-extras/recipes-ti/linalg/linalg.inc     | 43 ++++++++++++++++++++++
 meta-arago-extras/recipes-ti/linalg/linalg_git.bb  | 23 ++++++++++++
 3 files changed, 68 insertions(+)
 create mode 100644 meta-arago-extras/recipes-ti/linalg/linalg.inc
 create mode 100644 meta-arago-extras/recipes-ti/linalg/linalg_git.bb

diff --git a/meta-arago-extras/recipes-ti/includes/arago-paths.inc b/meta-arago-extras/recipes-ti/includes/arago-paths.inc
index ae3f304..6867406 100644
--- a/meta-arago-extras/recipes-ti/includes/arago-paths.inc
+++ b/meta-arago-extras/recipes-ti/includes/arago-paths.inc
@@ -1,5 +1,7 @@
 require recipes-ti/includes/ti-paths.inc
 
 export LIBARCH_INSTALL_DIR_RECIPE    = "${installdir}/ti-libarch-tree"
+export LINALG_INSTALL_DIR_RECIPE     = "${installdir}/ti-linalg-tree"
 
 export LIBARCH_INSTALL_DIR    = "${STAGING_DIR_TARGET}${LIBARCH_INSTALL_DIR_RECIPE}"
+export LINALG_INSTALL_DIR     = "${STAGING_DIR_TARGET}${LINALG_INSTALL_DIR_RECIPE}"
diff --git a/meta-arago-extras/recipes-ti/linalg/linalg.inc b/meta-arago-extras/recipes-ti/linalg/linalg.inc
new file mode 100644
index 0000000..7c197b6
--- /dev/null
+++ b/meta-arago-extras/recipes-ti/linalg/linalg.inc
@@ -0,0 +1,43 @@
+HOMEPAGE = "git://git.ti.com/dense-linear-algebra-libraries/linalg.git"
+LICENSE = "BSD-3-Clause"
+
+PV = "1_2_0_0"
+INC_PR = "r0"
+
+S = "${WORKDIR}/git"
+
+require recipes-ti/includes/arago-paths.inc
+require recipes-ti/includes/ti-staging.inc
+
+BRANCH = "master"
+SRC_URI = "git://git.ti.com/dense-linear-algebra-libraries/linalg.git;protocol=git;branch=${BRANCH}"
+LIC_FILES_CHKSUM = "file://docs/LINALG_1.2.0_manifest.html;md5=f30895e41e5947c3439b1ad4cf4c8555"
+SRCREV = "4de29dac3c6fbd16df1b19876593de0afdbcb30f"
+
+DEPENDS = "common-csl-ip \
+           libarch \
+           ti-xdctools \
+           ti-ipc-rtos \
+           ti-sysbios \
+           ti-cgt6x-native \
+           ti-xdais \
+           ti-framework-components \
+           libulm \
+           openmp-rtos \
+           opencl \
+           clocl-native \
+"
+
+export TI_OCL_INSTALL_DIR = "${STAGING_DIR_TARGET}/usr/share/ti/opencl"
+export CGTROOT = "${STAGING_DIR_NATIVE}/usr/share/ti/cgt-c6x"
+export TI_OCL_CGT_INSTALL = "${STAGING_DIR_NATIVE}/usr/share/ti/cgt-c6x"
+export XDC_DIR = "${XDC_INSTALL_DIR}"
+export BIOS_DIR= "${SYSBIOS_INSTALL_DIR}"
+export XDAIS_DIR = "${XDAIS_INSTALL_DIR}"
+export FC_DIR = "${FC_INSTALL_DIR}"
+export PDK_DIR = "${PDK_INSTALL_DIR}"
+export OMP_DIR ="${OMP_INSTALL_DIR}"
+export LIBARCH_DIR = "${LIBARCH_INSTALL_DIR}"
+export TARGET_ROOTDIR="${STAGING_DIR_TARGET}"
+
+COMPATIBLE_MACHINE = "k2hk-evm"
diff --git a/meta-arago-extras/recipes-ti/linalg/linalg_git.bb b/meta-arago-extras/recipes-ti/linalg/linalg_git.bb
new file mode 100644
index 0000000..4d7a5a4
--- /dev/null
+++ b/meta-arago-extras/recipes-ti/linalg/linalg_git.bb
@@ -0,0 +1,23 @@
+DESCRIPTION = "TI Linear Algebra Library"
+
+include linalg.inc
+PR = "${INC_PR}.0"
+
+TARGET_k2hk-evm = "SOC_K2H"
+MEM_MODEL_k2hk-evm = "Large"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+do_compile() {
+   make ARMplusDSP MEM_MODEL=${MEM_MODEL} TARGET=${TARGET} LIBOS=LIB_OPENCL
+   make docs
+}
+
+do_install() {
+   make installARMplusDSPlib DESTDIR=${D}${LINALG_INSTALL_DIR_RECIPE}
+}
+
+# to create a package for LINALG
+FILES_${PN}-dev += "${LINALG_INSTALL_DIR_RECIPE}"
+
+INSANE_SKIP_${PN}-dev = "arch staticdev"
+ALLOW_EMPTY_${PN} = "1"
-- 
1.9.1

[PATCH 5/8] linalg-examples: And Linear Algebra Library examples

[Jacob Stiffler]

Signed-off-by: Jacob Stiffler <j-stiffler@ti.com>
---
 .../recipes-ti/linalg/linalg-examples_git.bb       | 74 ++++++++++++++++++++++
 1 file changed, 74 insertions(+)
 create mode 100644 meta-arago-extras/recipes-ti/linalg/linalg-examples_git.bb

diff --git a/meta-arago-extras/recipes-ti/linalg/linalg-examples_git.bb b/meta-arago-extras/recipes-ti/linalg/linalg-examples_git.bb
new file mode 100644
index 0000000..acafb36
--- /dev/null
+++ b/meta-arago-extras/recipes-ti/linalg/linalg-examples_git.bb
@@ -0,0 +1,74 @@
+DESCRIPTION = "TI Linear Algebra Library examples"
+
+include linalg.inc
+PR = "${INC_PR}.0"
+
+DEPENDS += "linalg"
+RDEPENDS_${PN} += "opencl-runtime"
+
+export LINALG_DIR = "${LINALG_INSTALL_DIR}"
+
+EXAMPLES_ROOT = "${WORKDIR}/git/linalg_example_src"
+B = "${S}"
+
+LINALG_EXAMPLE_LIST = "dgemm_test \
+                       dsyrk_test \
+                       eig \
+                       gemm_bench \
+                       ludinv \
+                       matmpy \
+                       ztrmm_test \
+                       ztrsm_test \
+"
+
+python do_unpack_append() {
+    import shutil
+
+    git_dir = d.expand("${WORKDIR}/git/examples/arm+dsp")
+    s = d.getVar("EXAMPLES_ROOT", True)
+
+    os.makedirs(s)
+    shutil.copy(os.path.join(git_dir,"Makefile"),s)
+    shutil.copy(os.path.join(git_dir,"make.inc"),s)
+    shutil.copy(os.path.join(git_dir,"run_tests_evm.sh"),s)
+    for example in d.getVar("LINALG_EXAMPLE_LIST").split():
+        shutil.copytree(os.path.join(git_dir,example), os.path.join(s,example))
+}
+
+EXTRA_OEMAKE = " TARGET_ROOTDIR=${STAGING_DIR_HOST} TI_OCL_CGT_INSTALL=${STAGING_DIR_NATIVE}/usr/share/ti/cgt-c6x"
+
+do_compile() {
+    cd ${EXAMPLES_ROOT}
+    oe_runmake
+    # Remove object files before installing so that the binaries are not present
+    find . -name "*.obj" -type f -delete
+    find . -name "*.o" -type f -delete
+}
+
+do_install() {
+    install -d ${D}${datadir}/ti/examples/linalg
+
+    install ${EXAMPLES_ROOT}/Makefile ${D}${datadir}/ti/examples/linalg
+    install ${EXAMPLES_ROOT}/make.inc ${D}${datadir}/ti/examples/linalg
+    install ${EXAMPLES_ROOT}/run_tests_evm.sh ${D}${datadir}/ti/examples/linalg
+
+    cd ${EXAMPLES_ROOT}
+    for linalg_example in ${LINALG_EXAMPLE_LIST}; do
+        install -d ${D}${datadir}/ti/examples/linalg/${linalg_example}
+        cp -rv ${EXAMPLES_ROOT}/${linalg_example}/. ${D}${datadir}/ti/examples/linalg/${linalg_example}
+    done
+}
+
+FILES_${PN} += "\
+    ${datadir}/ti/examples/linalg/* \
+"
+
+FILES_${PN}-dbg += "\
+    ${datadir}/ti/examples/linalg/*/.debug \
+"
+
+INSANE_SKIP_${PN} = "arch ldflags textrel"
+
+CREATE_SRCIPK = "1"
+SRCIPK_INSTALL_DIR = "example-applications/${PN}-${PV}"
+SRCIPK_SRC_DIR = "${EXAMPLES_ROOT}"
-- 
1.9.1

[PATCH 6/8] arago-source-ipk: Enable linalg-examples-src

[Jacob Stiffler]

Signed-off-by: Jacob Stiffler <j-stiffler@ti.com>
---
 meta-arago-distro/conf/distro/arago-source-ipk.conf | 4 ++++
 1 file changed, 4 insertions(+)

diff --git a/meta-arago-distro/conf/distro/arago-source-ipk.conf b/meta-arago-distro/conf/distro/arago-source-ipk.conf
index 56a488f..9dca564 100644
--- a/meta-arago-distro/conf/distro/arago-source-ipk.conf
+++ b/meta-arago-distro/conf/distro/arago-source-ipk.conf
@@ -350,6 +350,10 @@ SRCIPK_INSTALL_DIR_pn-qt-opencv-opencl-opengl-multithreaded = "example-applicati
 CREATE_SRCIPK_pn-libarch-examples = "1"
 SRCIPK_INSTALL_DIR_pn-libarch-examples = "example-applications/${PN}-${PV}"
 
+CREATE_SRCIPK_pn-linalg-examples = "1"
+SRCIPK_INSTALL_DIR_pn-linalg-examples = "example-applications/${PN}-${PV}"
+SRCIPK_SRC_DIR_pn-linalg-examples = "${EXAMPLES_ROOT}"
+
 CREATE_SRCIPK_pn-boot-monitor = "1"
 SRCIPK_INSTALL_DIR_pn-boot-monitor = "board-support/${PN}-${PV}"
 
-- 
1.9.1

[PATCH 7/8] packagegroup-arago-tisdk-addons: k2hk-evm: Integrate linalg

[Jacob Stiffler]

* Add linalg-examples to the filesystem
* Add linalg-dev to teh devkit
* Add linalg-examples-src to the SDK

Signed-off-by: Jacob Stiffler <j-stiffler@ti.com>
---
 .../packagegroups/packagegroup-arago-tisdk-addons-sdk-host.bb          | 3 ++-
 .../packagegroups/packagegroup-arago-tisdk-addons-sdk-target.bb        | 3 ++-
 .../recipes-core/packagegroups/packagegroup-arago-tisdk-addons.bb      | 3 ++-
 3 files changed, 6 insertions(+), 3 deletions(-)

diff --git a/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-addons-sdk-host.bb b/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-addons-sdk-host.bb
index a7b90fd..0306c1b 100644
--- a/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-addons-sdk-host.bb
+++ b/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-addons-sdk-host.bb
@@ -1,6 +1,6 @@
 DESCRIPTION = "Task to install sources for additional utilities/demos for SDKs"
 LICENSE = "MIT"
-PR = "r19"
+PR = "r20"
 
 PACKAGE_ARCH = "${MACHINE_ARCH}"
 
@@ -39,6 +39,7 @@ UTILS_append_dra7xx = " \
 UTILS_append_k2hk-evm = " \
     opencl-examples-src \
     openmpacc-examples-src \
+    linalg-examples-src \
 "
 
 UTILS_append_k2l-evm = " \
diff --git a/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-addons-sdk-target.bb b/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-addons-sdk-target.bb
index 6931150..062e8ce 100644
--- a/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-addons-sdk-target.bb
+++ b/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-addons-sdk-target.bb
@@ -1,6 +1,6 @@
 DESCRIPTION = "Task to install headers and libraries related to addons into the SDK"
 LICENSE = "MIT"
-PR = "r24"
+PR = "r25"
 
 PACKAGE_ARCH = "${MACHINE_ARCH}"
 
@@ -127,6 +127,7 @@ UTILS_append_dra7xx = " canutils-dev \
 "
 UTILS_append_k2hk-evm = " opencl-staticdev \
                           openmpacc-dev \
+                          linalg-dev \
 "
 UTILS_append_k2l-evm = " opencl-staticdev \
                          openmpacc-dev \
diff --git a/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-addons.bb b/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-addons.bb
index 8af7fcc..dc0a927 100644
--- a/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-addons.bb
+++ b/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-addons.bb
@@ -1,6 +1,6 @@
 DESCRIPTION = "Task to install additional utilities/demos for SDKs"
 LICENSE = "MIT"
-PR = "r42"
+PR = "r43"
 
 PACKAGE_ARCH = "${MACHINE_ARCH}"
 
@@ -111,6 +111,7 @@ EXTRA_PACKAGES_append_k2hk-evm = " \
     opencl-staticdev \
     opencl-examples-dev \
     openmpacc-examples-dev \
+    linalg-examples \
 "
 EXTRA_PACKAGES_append_k2l-evm = " \
     opencl-staticdev \
-- 
1.9.1

[PATCH 8/8] ti-tisdk-makefile: Add linalg-examples target

[Jacob Stiffler]

Signed-off-by: Jacob Stiffler <j-stiffler@ti.com>
---
 .../ti-tisdk-makefile/Makefile_linalg-examples     | 39 ++++++++++++++++++++++
 .../ti-tisdk-makefile/ti-tisdk-makefile_1.0.bb     |  4 ++-
 2 files changed, 42 insertions(+), 1 deletion(-)
 create mode 100644 meta-arago-distro/recipes-tisdk/ti-tisdk-makefile/ti-tisdk-makefile/Makefile_linalg-examples

diff --git a/meta-arago-distro/recipes-tisdk/ti-tisdk-makefile/ti-tisdk-makefile/Makefile_linalg-examples b/meta-arago-distro/recipes-tisdk/ti-tisdk-makefile/ti-tisdk-makefile/Makefile_linalg-examples
new file mode 100644
index 0000000..19c182f
--- /dev/null
+++ b/meta-arago-distro/recipes-tisdk/ti-tisdk-makefile/ti-tisdk-makefile/Makefile_linalg-examples
@@ -0,0 +1,39 @@
+linalg-examples:
+	@echo =====================================
+	@echo     Building the Linalg Examples
+	@echo =====================================
+	@cd example-applications; \
+	cd `find . -name "*linalg-examples*"`; \
+	. $(ENV_SETUP); \
+	make TARGET_ROOTDIR=$(SDK_PATH_TARGET) \
+		TI_OCL_CGT_INSTALL=$(SDK_PATH_TARGET)/usr/share/ti/cgt-c6x \
+		LINALG_DIR=$(SDK_PATH_TARGET)/usr/share/ti/ti-linalg-tree
+
+linalg-examples_install:
+	@echo =======================================
+	@echo     Installing the Linalg Examples
+	@echo =======================================
+	@if [ ! -d $(DESTDIR) ] ; then \
+		echo "The extracted target filesystem directory doesn't exist."; \
+		echo "Please run setup.sh in the SDK's root directory and then try again."; \
+		exit 1; \
+	fi
+	@cd example-applications; \
+	cd `find . -name "*linalg-examples*"`; \
+	for example in `find . -executable -not \( -type d -o -iname 'make*' \)`; do \
+		install -d $(DESTDIR)/usr/share/ti/examples/linalg/`dirname $${example}` ; \
+		install -m 755 $${example} $(DESTDIR)/usr/share/ti/examples/linalg/`dirname $${example}` ; \
+		if [ -f `dirname $${example}`/*.out ]; then \
+			install -m 755 `dirname $${example}`/*.out $(DESTDIR)/usr/share/ti/examples/linalg/`dirname $${example}` ; \
+		fi \
+	done
+
+linalg-examples_clean:
+	@echo =======================================
+	@echo     Cleaning the Linalg Examples
+	@echo =======================================
+	@cd example-applications; \
+	cd `find . -name "*linalg-examples*"`; \
+	. $(ENV_SETUP); \
+	make TARGET_ROOTDIR=$(SDK_PATH_TARGET) clean
+
diff --git a/meta-arago-distro/recipes-tisdk/ti-tisdk-makefile/ti-tisdk-makefile_1.0.bb b/meta-arago-distro/recipes-tisdk/ti-tisdk-makefile/ti-tisdk-makefile_1.0.bb
index a487fe4..a65918e 100644
--- a/meta-arago-distro/recipes-tisdk/ti-tisdk-makefile/ti-tisdk-makefile_1.0.bb
+++ b/meta-arago-distro/recipes-tisdk/ti-tisdk-makefile/ti-tisdk-makefile_1.0.bb
@@ -45,9 +45,10 @@ SRC_URI = "\
     file://Makefile_qt-opencv-opencl-opengl-multithreaded \
     file://Makefile_ipsecmgr-mod \
     file://Makefile_openmpacc-examples \
+    file://Makefile_linalg-examples \
 "
 
-PR = "r69"
+PR = "r70"
 
 MAKEFILES_MATRIX_GUI = "matrix-gui-browser \
                         refresh-screen \
@@ -133,6 +134,7 @@ MAKEFILES_append_k2hk-evm = " opencl-examples \
                               gdbserverproxy-module-drv \
                               debugss-module-drv \
                               openmpacc-examples \
+                              linalg-examples \
 "
 
 MAKEFILES_append_k2l-evm = " opencl-examples \
-- 
1.9.1

Re: [PATCH 0/8] Add LibArch and LinAlg

[Jacob Stiffler]

Denys,

What are the chances of this making it into the 2015.03 release?

Thank you,
Jake

On 3/15/2016 3:54 PM, Jacob Stiffler wrote:
> Integrate Library Architecture and Framework (LibArch)
> and TI Linear Algebra Library (LinAlg)
>
> Jacob Stiffler (8):
>    libarch: Add version 1.0.0.0
>    libarch-examples: Add examples for libarch version 1.0.0.0
>    arago-source-ipk: Enable libarch-examples-src
>    linalg: Add Linear Algebra Library version 1.2.0.0
>    linalg-examples: And Linear Algebra Library examples
>    arago-source-ipk: Enable linalg-examples-src
>    packagegroup-arago-tisdk-addons: k2hk-evm: Integrate linalg
>    ti-tisdk-makefile: Add linalg-examples target
>
>   .../conf/distro/arago-source-ipk.conf              |  7 ++
>   .../packagegroup-arago-tisdk-addons-sdk-host.bb    |  3 +-
>   .../packagegroup-arago-tisdk-addons-sdk-target.bb  |  3 +-
>   .../packagegroup-arago-tisdk-addons.bb             |  3 +-
>   .../ti-tisdk-makefile/Makefile_linalg-examples     | 39 ++++++++++++
>   .../ti-tisdk-makefile/ti-tisdk-makefile_1.0.bb     |  4 +-
>   .../recipes-ti/includes/arago-paths.inc            |  7 ++
>   .../recipes-ti/libarch/libarch-examples_git.bb     | 36 +++++++++++
>   meta-arago-extras/recipes-ti/libarch/libarch.inc   | 32 ++++++++++
>   .../recipes-ti/libarch/libarch_git.bb              | 25 ++++++++
>   .../recipes-ti/linalg/linalg-examples_git.bb       | 74 ++++++++++++++++++++++
>   meta-arago-extras/recipes-ti/linalg/linalg.inc     | 43 +++++++++++++
>   meta-arago-extras/recipes-ti/linalg/linalg_git.bb  | 23 +++++++
>   13 files changed, 295 insertions(+), 4 deletions(-)
>   create mode 100644 meta-arago-distro/recipes-tisdk/ti-tisdk-makefile/ti-tisdk-makefile/Makefile_linalg-examples
>   create mode 100644 meta-arago-extras/recipes-ti/includes/arago-paths.inc
>   create mode 100644 meta-arago-extras/recipes-ti/libarch/libarch-examples_git.bb
>   create mode 100644 meta-arago-extras/recipes-ti/libarch/libarch.inc
>   create mode 100644 meta-arago-extras/recipes-ti/libarch/libarch_git.bb
>   create mode 100644 meta-arago-extras/recipes-ti/linalg/linalg-examples_git.bb
>   create mode 100644 meta-arago-extras/recipes-ti/linalg/linalg.inc
>   create mode 100644 meta-arago-extras/recipes-ti/linalg/linalg_git.bb
>

Re: [PATCH 0/8] Add LibArch and LinAlg

[Denys Dmytriyenko]

Jake,

I was on the fence about this particular set. What are your requirement and 
priority here?

-- 
Denys


On Wed, Mar 16, 2016 at 02:21:00PM -0400, Jacob Stiffler wrote:
> Denys,
> 
> What are the chances of this making it into the 2015.03 release?
> 
> Thank you,
> Jake
> 
> On 3/15/2016 3:54 PM, Jacob Stiffler wrote:
> >Integrate Library Architecture and Framework (LibArch)
> >and TI Linear Algebra Library (LinAlg)
> >
> >Jacob Stiffler (8):
> >   libarch: Add version 1.0.0.0
> >   libarch-examples: Add examples for libarch version 1.0.0.0
> >   arago-source-ipk: Enable libarch-examples-src
> >   linalg: Add Linear Algebra Library version 1.2.0.0
> >   linalg-examples: And Linear Algebra Library examples
> >   arago-source-ipk: Enable linalg-examples-src
> >   packagegroup-arago-tisdk-addons: k2hk-evm: Integrate linalg
> >   ti-tisdk-makefile: Add linalg-examples target
> >
> >  .../conf/distro/arago-source-ipk.conf              |  7 ++
> >  .../packagegroup-arago-tisdk-addons-sdk-host.bb    |  3 +-
> >  .../packagegroup-arago-tisdk-addons-sdk-target.bb  |  3 +-
> >  .../packagegroup-arago-tisdk-addons.bb             |  3 +-
> >  .../ti-tisdk-makefile/Makefile_linalg-examples     | 39 ++++++++++++
> >  .../ti-tisdk-makefile/ti-tisdk-makefile_1.0.bb     |  4 +-
> >  .../recipes-ti/includes/arago-paths.inc            |  7 ++
> >  .../recipes-ti/libarch/libarch-examples_git.bb     | 36 +++++++++++
> >  meta-arago-extras/recipes-ti/libarch/libarch.inc   | 32 ++++++++++
> >  .../recipes-ti/libarch/libarch_git.bb              | 25 ++++++++
> >  .../recipes-ti/linalg/linalg-examples_git.bb       | 74 ++++++++++++++++++++++
> >  meta-arago-extras/recipes-ti/linalg/linalg.inc     | 43 +++++++++++++
> >  meta-arago-extras/recipes-ti/linalg/linalg_git.bb  | 23 +++++++
> >  13 files changed, 295 insertions(+), 4 deletions(-)
> >  create mode 100644 meta-arago-distro/recipes-tisdk/ti-tisdk-makefile/ti-tisdk-makefile/Makefile_linalg-examples
> >  create mode 100644 meta-arago-extras/recipes-ti/includes/arago-paths.inc
> >  create mode 100644 meta-arago-extras/recipes-ti/libarch/libarch-examples_git.bb
> >  create mode 100644 meta-arago-extras/recipes-ti/libarch/libarch.inc
> >  create mode 100644 meta-arago-extras/recipes-ti/libarch/libarch_git.bb
> >  create mode 100644 meta-arago-extras/recipes-ti/linalg/linalg-examples_git.bb
> >  create mode 100644 meta-arago-extras/recipes-ti/linalg/linalg.inc
> >  create mode 100644 meta-arago-extras/recipes-ti/linalg/linalg_git.bb
> >
> 
> _______________________________________________
> meta-arago mailing list
> meta-arago@arago-project.org
> http://arago-project.org/cgi-bin/mailman/listinfo/meta-arago

Re: [PATCH 0/8] Add LibArch and LinAlg

[Jacob Stiffler]

On 3/16/2016 2:25 PM, Denys Dmytriyenko wrote:
> Jake,
>
> I was on the fence about this particular set. What are your requirement and
> priority here?
>

I was really hoping to get this in sooner, but the sources were just 
pushed external.

This is a requirement for our next release, so if it does not make it 
in, then I will need to rework this for meta-processor-sdk.